Adding ability to stream windows and inject events to them

remoting/host/single_window_input_injector_mac.mm

+// Copyright 2014 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "remoting/host/single_window_input_injector.h"
+
+#include <ApplicationServices/ApplicationServices.h>
+#include <Carbon/Carbon.h>
+
+#include "base/mac/scoped_cftyperef.h"
+#include "remoting/proto/internal.pb.h"

[Wez, 2014/08/06 04:10:16]

I think you want to include the event.pb.h header, rather than internal

[ronakvora do not use, 2014/08/06 20:56:19]

Done.

+#include "third_party/webrtc/modules/desktop_capture/mac/desktop_configuration.h"
+
+namespace remoting {
+
+using protocol::ClipboardEvent;
+using protocol::KeyEvent;
+using protocol::TextEvent;
+using protocol::MouseEvent;
+
+// A class to generate events to a window on Mac.

[Wez, 2014/08/06 04:10:16]

nit: Suggest:

"Implements InputInjector to direct input events to a specific window."

Also consider clarifying that clipboard injection will still be global.

This comment seems more appropriate on the SingleWindowInputInjector base class,
in the header, in fact.

[ronakvora do not use, 2014/08/06 20:56:19]

Done.

+class SingleWindowInputInjectorMac : public SingleWindowInputInjector {
+ public:
+  SingleWindowInputInjectorMac(
+      webrtc::WindowId window_id,
+      scoped_ptr<InputInjector> input_injector);
+  virtual ~SingleWindowInputInjectorMac();
+
+  // InputInjector interface.
+  virtual void Start(
+      scoped_ptr<protocol::ClipboardStub> client_clipboard) OVERRIDE;
+  virtual void InjectKeyEvent(const KeyEvent& event) OVERRIDE;
+  virtual void InjectTextEvent(const TextEvent& event) OVERRIDE;
+  virtual void InjectMouseEvent(const MouseEvent& event) OVERRIDE;
+  virtual void InjectClipboardEvent(const ClipboardEvent& event) OVERRIDE;
+
+ private:
+  CGRect FindCGRectOfWindow();
+
+  CGWindowID window_id_;
+  scoped_ptr<InputInjector> input_injector_;
+
+ DISALLOW_COPY_AND_ASSIGN(SingleWindowInputInjectorMac);
+};
+
+SingleWindowInputInjectorMac::SingleWindowInputInjectorMac(
+    webrtc::WindowId window_id,
+    scoped_ptr<InputInjector> input_injector):
+    window_id_((CGWindowID)window_id),
+    input_injector_(input_injector.Pass()) {
+}
+
+SingleWindowInputInjectorMac::~SingleWindowInputInjectorMac() {
+}
+
+void SingleWindowInputInjectorMac::Start(
+    scoped_ptr<protocol::ClipboardStub> client_clipboard) {
+  input_injector_->Start(client_clipboard.Pass());
+}
+
+void SingleWindowInputInjectorMac::InjectKeyEvent(const KeyEvent& event) {
+  input_injector_->InjectKeyEvent(event);
+}
+
+void SingleWindowInputInjectorMac::InjectTextEvent(const TextEvent& event) {
+  input_injector_->InjectTextEvent(event);
+}
+
+void SingleWindowInputInjectorMac::InjectMouseEvent(const MouseEvent& event) {
+  if (event.has_x() && event.has_y()) {
+    CGRect windowRect = FindCGRectOfWindow();
+    if (CGRectIsNull(windowRect)) {
+      LOG(ERROR) << "Failing silently and just forwarding event";

[Wez, 2014/08/06 04:10:16]

nit: Suggest "Window rect is null, so ignoring MouseEvent"

[ronakvora do not use, 2014/08/06 20:56:20]

Done.

+      input_injector_->InjectMouseEvent(event);
+      return;
+    }

[Wez, 2014/08/06 04:10:16]

nit: Blank line after this, to separate it from the next logical block of code.

[ronakvora do not use, 2014/08/06 20:56:19]

Done.

+    webrtc::MacDesktopConfiguration desktop_config =
+        webrtc::MacDesktopConfiguration::GetCurrent(
+            webrtc::MacDesktopConfiguration::TopLeftOrigin);
+
+    // Create a vector that has the origin of the window.
+    webrtc::DesktopVector mouse_pos(CGRectGetMinX(windowRect),

[Wez, 2014/08/06 04:10:16]

mouse_pos -> window_origin, then?

[ronakvora do not use, 2014/08/06 20:56:19]

Yep, you're right. We were doing it this way in our VNC server, so I just kept
that same style. This is more explicit though.

+                                    CGRectGetMinY(windowRect));
+
+    // Subtract coordinates that are already added in for multiple
+    // desktops. They get added in already in InputInjector.

[Wez, 2014/08/06 04:10:16]

Suggest: "The underlying InputInjector expects coordinates relative to the
top-left of the top-left-most monitor, so translate the window origin to that
coordinate scheme."

[ronakvora do not use, 2014/08/06 20:56:19]

Done.

+    mouse_pos.subtract(
+        webrtc::DesktopVector(desktop_config.pixel_bounds.left(),
+                              desktop_config.pixel_bounds.top()));
+
+    // Create a new event with coordinates that are in respect to the window.
+    // We must make sure we are taking into account the fact that when we
+    // find the window on the host it returns is coordinates in Density

[Lambros, 2014/08/05 22:47:25]

s/is/its
s/conver/convert

[ronakvora do not use, 2014/08/06 20:56:19]

Done.

+    // Independent coordinates. We have to conver to Density Dependent
+    // because InputInjector assumes Density Dependent coordinates in the
+    // MouseEvent.
+    MouseEvent modified_event(event);
+    modified_event.set_x(
+        event.x() + mouse_pos.x() * desktop_config.dip_to_pixel_scale);
+    modified_event.set_y(
+        event.y() + mouse_pos.y() * desktop_config.dip_to_pixel_scale);
+    input_injector_->InjectMouseEvent(modified_event);
+  } else {
+    input_injector_->InjectMouseEvent(event);
+  }
+}
+
+void SingleWindowInputInjectorMac::InjectClipboardEvent(
+    const ClipboardEvent& event) {
+  input_injector_->InjectClipboardEvent(event);
+}
+
+// This method is used if we are capturing a window instead of a screen.
+// It finds the rectangle of the window we are streaming using
+// |window_id_|. The InputInjector can then use this rectangle
+// to translate the input event to coordinates of the window rather
+// than the screen.
+CGRect SingleWindowInputInjectorMac::FindCGRectOfWindow() {
+  CGRect rect;
+  CGWindowID ids[1] = {window_id_};
+  base::ScopedCFTypeRef<CFArrayRef> window_id_array(
+      CFArrayCreate(NULL, reinterpret_cast<const void **>(&ids), 1, NULL));
+
+  base::ScopedCFTypeRef<CFArrayRef> window_array(
+      CGWindowListCreateDescriptionFromArray(window_id_array));
+
+  if (window_array == NULL || CFArrayGetCount(window_array) == 0) {
+    // Could not find the window. It might have been closed.
+    LOG(ERROR) << "Specified window to stream not found for id: "
+               << window_id_;
+    return CGRectNull;
+  }
+
+  // We don't use ScopedCFTypeRef for |window| because the

[Lambros, 2014/08/05 22:47:25]

I don't think this comment is needed.

[ronakvora do not use, 2014/08/06 20:56:19]

When I had a discussion with Wez, he asked me to document this.

+  // CFDictionaryRef returned by CFArrayGetValueAtIndex is owned by
+  // window_array. The same is true of the |bounds|.
+  CFDictionaryRef window =
+      reinterpret_cast<CFDictionaryRef>(
+          CFArrayGetValueAtIndex(window_array, 0));
+
+  if (CFDictionaryContainsKey(window, kCGWindowBounds)) {
+    CFDictionaryRef bounds =
+        reinterpret_cast<CFDictionaryRef>(
+            CFDictionaryGetValue(window, kCGWindowBounds));
+    if (bounds) {
+      CGRectMakeWithDictionaryRepresentation(bounds, &rect);
+    } else {
+      return CGRectNull;
+    }
+  } else {
+    return CGRectNull;
+  }
+
+  return rect;
+}
+
+scoped_ptr<InputInjector> SingleWindowInputInjector::Create(
+      webrtc::WindowId window_id,
+      scoped_ptr<InputInjector> input_injector) {
+  scoped_ptr<SingleWindowInputInjectorMac>injector(
+      new SingleWindowInputInjectorMac(window_id, input_injector.Pass()));
+  return injector.PassAs<InputInjector>();
+}
+
+
+
+}  // namespace remoting