Add ManagePasswordsBubbleController and unit tests.

chrome/browser/ui/cocoa/passwords/manage_passwords_bubble_controller.mm

+// Copyright 2014 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "chrome/browser/ui/cocoa/passwords/manage_passwords_bubble_controller.h"
+
+#include "base/mac/scoped_nsobject.h"
+#import "chrome/browser/ui/cocoa/browser_window_controller.h"
+#import "chrome/browser/ui/cocoa/info_bubble_view.h"
+#import "chrome/browser/ui/cocoa/info_bubble_window.h"
+#include "chrome/browser/ui/cocoa/location_bar/location_bar_view_mac.h"
+#include "ui/base/cocoa/window_size_constants.h"
+
+@interface ManagePasswordsBubbleController ()
+// Updates the content view controller according to the current state.
+- (void)updateState;
+// Updates the content view controller and lays out the window.
+- (void)refresh;
+@end
+
+@implementation ManagePasswordsBubbleController
+- (id)initWithParentWindow:(NSWindow*)parentWindow
+                     model:(ManagePasswordsBubbleModel*)model {
+  NSRect contentRect = ui::kWindowSizeDeterminedLater;
+  base::scoped_nsobject<InfoBubbleWindow> window(
+      [[InfoBubbleWindow alloc] initWithContentRect:contentRect
+                                          styleMask:NSBorderlessWindowMask
+                                            backing:NSBackingStoreBuffered
+                                              defer:NO]);
+  if ((self = [super initWithWindow:window
+                       parentWindow:parentWindow
+                         anchoredAt:NSZeroPoint])) {
+    model_ = model;
+    neverSave_ = NO;
+    [self refresh];
+  }
+  return self;
+}
+
+- (void)showWindow:(id)sender {
+  [self performLayout];
+  [super showWindow:sender];
+}
+
+- (void)updateState {
+  // Find the next view controller.
+  // TODO(dconnelly): Handle other states once they're implemented.
+  currentController_.reset();
+  if (password_manager::ui::IsPendingState(model_->state()) && !neverSave_) {

[Scott Hess - ex-Googler, 2014/08/20 20:04:40]

I have had complaints in the past about things like double-negative conditions
(!neverSave_).  Is there an alternative naming which was a positive condition
without being insanely wordy?

Also, is there any possibility that this could be called when already in the
indicated state?

[dconnelly, 2014/08/21 08:47:59]

Nope. And to address that and the first comment I've managed to eliminate the
member variable completely. In the CL that adds the NeverSave view the delegate
method can just update the controller directly.

+    currentController_.reset([[ManagePasswordsBubblePendingViewController alloc]
+        initWithModel:model_
+             delegate:self]);
+  }
+}
+
+- (void)performLayout {
+  if (!currentController_)
+    return;
+
+  // Update the window.
+  NSWindow* window = [self window];
+  [[window contentView] setSubviews:@[ [currentController_ view] ]];
+
+  // Update the anchor.
+  BrowserWindowController* controller = [BrowserWindowController
+      browserWindowControllerForWindow:[self parentWindow]];
+  NSPoint anchorPoint =
+      [controller locationBarBridge]->GetManagePasswordsBubblePoint();
+  anchorPoint = [[self parentWindow] convertBaseToScreen:anchorPoint];
+  [self setAnchorPoint:anchorPoint];
+
+  // Update the frame.
+  CGFloat height = NSHeight([[currentController_ view] frame]) +
+                   info_bubble::kBubbleArrowHeight;
+  CGFloat width = NSWidth([[currentController_ view] frame]);
+  CGFloat x = anchorPoint.x - width +
+              info_bubble::kBubbleArrowXOffset +
+              (0.5 * info_bubble::kBubbleArrowWidth);
+  CGFloat y = anchorPoint.y - height;
+  [window setFrame:NSMakeRect(x, y, width, height)
+           display:YES
+           animate:[window isVisible]];
+}
+
+- (void)refresh {
+  [self updateState];
+  [self performLayout];

[Scott Hess - ex-Googler, 2014/08/20 20:04:40]

Is there a case where -updateState shouldn't lead to -performLayout?

[dconnelly, 2014/08/21 08:47:59]

Nope. Removed.

+}
+
+// ManagePasswordsBubbleContentViewDelegate

[Scott Hess - ex-Googler, 2014/08/20 20:04:40]

Generally this is indicated by:

#pragma mark ManagePasswordsBubbleContentViewDelegate

Personally I don't care, but apparently it integrates with Xcode or something,
and it covers what the comment is doing too.

[dconnelly, 2014/08/21 08:47:59]

Done.

+
+- (void)viewShouldDismiss {
+  [self close];
+}
+
+// ManagePasswordsBubblePendingViewDelegate
+
+- (void)passwordShouldNeverBeSavedOnSiteWithExistingPasswords {
+  neverSave_ = YES;
+  [self performLayout];
+}
+
+@end
+
+@implementation ManagePasswordsBubbleController (Testing)
+
+- (NSViewController*)currentController {
+  return currentController_.get();
+}
+
+@end