[Mac] Update the warnings UI for malicious downloads.

chrome/browser/ui/cocoa/download/download_item_controller.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/download/download_item_controller.h"
 
 #include "base/mac/bundle_locations.h"
 #include "base/mac/mac_util.h"
 #include "base/metrics/histogram.h"
 #include "base/strings/string16.h"
 #include "base/strings/string_util.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/strings/utf_string_conversions.h"
 #include "chrome/browser/download/chrome_download_manager_delegate.h"
 #include "chrome/browser/download/download_item_model.h"
 #include "chrome/browser/download/download_shelf_context_menu.h"
 #import "chrome/browser/themes/theme_properties.h"
 #import "chrome/browser/themes/theme_service.h"
 #import "chrome/browser/ui/cocoa/download/download_item_button.h"
 #import "chrome/browser/ui/cocoa/download/download_item_cell.h"
 #include "chrome/browser/ui/cocoa/download/download_item_mac.h"
+#import "chrome/browser/ui/cocoa/download/download_shelf_context_menu_controller.h"
 #import "chrome/browser/ui/cocoa/download/download_shelf_controller.h"
 #import "chrome/browser/ui/cocoa/themed_window.h"
 #import "chrome/browser/ui/cocoa/ui_localizer.h"
 #include "content/public/browser/download_item.h"
 #include "content/public/browser/page_navigator.h"
 #include "grit/generated_resources.h"
 #include "grit/theme_resources.h"
 #include "third_party/GTM/AppKit/GTMUILocalizerAndLayoutTweaker.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 #include "ui/base/resource/resource_bundle.h"
@@ skipping 86 matching lines @@
 - (void)dealloc {
   [[NSNotificationCenter defaultCenter] removeObserver:self];
   [progressView_ setController:nil];
   [[self view] removeFromSuperview];
   [super dealloc];
 }
 
 - (void)awakeFromNib {
   [progressView_ setController:self];
 
-  [self setStateFromDownload:bridge_->download_model()];
-
   GTMUILocalizerAndLayoutTweaker* localizerAndLayoutTweaker =
       [[[GTMUILocalizerAndLayoutTweaker alloc] init] autorelease];
   [localizerAndLayoutTweaker applyLocalizer:localizer_ tweakingUI:[self view]];
 
-  // The strings are based on the download item's name, sizing tweaks have to be
-  // manually done.
-  DCHECK(buttonTweaker_ != nil);
-  CGFloat widthChange = [buttonTweaker_ changedWidth];
-  // If it's a dangerous download, size the two lines so the text/filename
-  // is always visible.
-  if ([self isDangerousMode]) {
-    widthChange +=
-        [GTMUILocalizerAndLayoutTweaker
-          sizeToFitFixedHeightTextField:dangerousDownloadLabel_
-                               minWidth:kTextWidth];
-  }
-  // Grow the parent views
-  WidenView([self view], widthChange);
-  WidenView(dangerousDownloadView_, widthChange);
-  // Slide the two buttons over.
-  NSPoint frameOrigin = [buttonTweaker_ frame].origin;
-  frameOrigin.x += widthChange;
-  [buttonTweaker_ setFrameOrigin:frameOrigin];
+  [self setStateFromDownload:bridge_->download_model()];
 
   bridge_->LoadIcon();
   [self updateToolTip];
 }
 
+- (void)showDangerousWarning:(DownloadItemModel*)downloadModel {
+  // The transition from safe -> dangerous should only happen once. The code
+  // assumes that the danger type of the download doesn't change once it's set.
+  if ([self isDangerousMode])
+    return;
+
+  [self setState:kDangerous];
+
+  ui::ResourceBundle& rb = ui::ResourceBundle::GetSharedInstance();
+  NSImage* alertIcon;
+
+  NSString* dangerousWarning = base::SysUTF16ToNSString(
+      downloadModel->GetWarningText(*font_list_, kTextWidth));
+  DCHECK(dangerousWarning);
+  [dangerousDownloadLabel_ setStringValue:dangerousWarning];
+  CGFloat labelWidthChange =
+      [GTMUILocalizerAndLayoutTweaker
+        sizeToFitFixedHeightTextField:dangerousDownloadLabel_
+                             minWidth:kTextWidth];
+  CGFloat buttonWidthChange = 0.0;
+
+  if (downloadModel->MightBeMalicious()) {
+    alertIcon = rb.GetNativeImageNamed(IDR_SAFEBROWSING_WARNING).ToNSImage();
+    buttonWidthChange = [maliciousButtonTweaker_ changedWidth];
+
+    // Move the buttons to account for the change in label size.
+    NSPoint frameOrigin = [maliciousButtonTweaker_ frame].origin;
+    frameOrigin.x += labelWidthChange;
+    [maliciousButtonTweaker_ setFrameOrigin:frameOrigin];
+
+    [dangerousButtonTweaker_ setHidden:YES];
+    [maliciousButtonTweaker_ setHidden:NO];
+  } else {
+    alertIcon = rb.GetNativeImageNamed(IDR_WARNING).ToNSImage();
+    buttonWidthChange = [dangerousButtonTweaker_ changedWidth];
+
+    // The text on the confirm button can change depending on the type of the
+    // download.
+    NSString* confirmButtonTitle =
+        base::SysUTF16ToNSString(downloadModel->GetWarningConfirmButtonText());
+    DCHECK(confirmButtonTitle);
+    [dangerousDownloadConfirmButton_ setTitle:confirmButtonTitle];
+
+    // Move the button to account for the change in label size.
+    NSPoint frameOrigin = [dangerousButtonTweaker_ frame].origin;
+    frameOrigin.x += labelWidthChange;
+    [dangerousButtonTweaker_ setFrameOrigin:frameOrigin];
+
+    [dangerousButtonTweaker_ setHidden:NO];
+    [maliciousButtonTweaker_ setHidden:YES];
+  }
+  DCHECK(alertIcon);
+  [image_ setImage:alertIcon];
+
+  // Grow the parent views
+  WidenView([self view], labelWidthChange + buttonWidthChange);
+  WidenView(dangerousDownloadView_, labelWidthChange + buttonWidthChange);
+}
+
 - (void)setStateFromDownload:(DownloadItemModel*)downloadModel {
   DCHECK_EQ([self download], downloadModel->download());
 
   // Handle dangerous downloads.
   if (downloadModel->IsDangerous()) {
-    [self setState:kDangerous];
-
-    ui::ResourceBundle& rb = ui::ResourceBundle::GetSharedInstance();
-    NSString* dangerousWarning;
-    NSString* confirmButtonTitle;
-    NSImage* alertIcon;
-
-    dangerousWarning =
-        base::SysUTF16ToNSString(downloadModel->GetWarningText(
-            *font_list_, kTextWidth));
-    confirmButtonTitle =
-        base::SysUTF16ToNSString(downloadModel->GetWarningConfirmButtonText());
-    if (downloadModel->MightBeMalicious())
-      alertIcon = rb.GetNativeImageNamed(IDR_SAFEBROWSING_WARNING).ToNSImage();
-    else
-      alertIcon = rb.GetNativeImageNamed(IDR_WARNING).ToNSImage();
-    DCHECK(alertIcon);
-    [image_ setImage:alertIcon];
-    DCHECK(dangerousWarning);
-    [dangerousDownloadLabel_ setStringValue:dangerousWarning];
-    DCHECK(confirmButtonTitle);
-    [dangerousDownloadConfirmButton_ setTitle:confirmButtonTitle];
+    [self showDangerousWarning:downloadModel];
     return;
   }
 
   // Set path to draggable download on completion.
   if (downloadModel->download()->GetState() == DownloadItem::COMPLETE)
     [progressView_ setDownload:downloadModel->download()->GetTargetFilePath()];
 
   [cell_ setStateFromDownload:downloadModel];
 }
 
@@ skipping 105 matching lines @@
 }
 
 - (IBAction)discardDownload:(id)sender {
   UMA_HISTOGRAM_LONG_TIMES("clickjacking.discard_download",
                            base::Time::Now() - creationTime_);
   DownloadItem* download = bridge_->download_model()->download();
   download->Remove();
   // WARNING: we are deleted at this point.  Don't access 'this'.
 }
 
+- (IBAction)dismissMaliciousDownload:(id)sender {
+  [self remove];
+  // WARNING: we are deleted at this point.
+}
+
+- (IBAction)showContextMenu:(id)sender {
+  base::scoped_nsobject<DownloadShelfContextMenuController> menuController(
+      [[DownloadShelfContextMenuController alloc]
+        initWithItemController:self
+                  withDelegate:nil]);
+  [NSMenu popUpContextMenu:[menuController menu]
+                 withEvent:[NSApp currentEvent]
+                   forView:[self view]];

[Nico, 2013/11/02 00:13:51]

Does "forView:sender" make a visual difference? If not, this is fine.

[asanka, 2013/11/02 05:41:36]

The behavior with "[self view]" appeared correct. But I'll try it with "sender"
and see if there's a difference.

[asanka, 2013/11/04 16:53:47]

Tried both ways, and there was no difference.

+}
+
 @end