mac: [Yosemite] Fix bug where zoom button causes fullscreen mode.

chrome/browser/ui/cocoa/version_independent_window.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/version_independent_window.h"
 
 #include "base/logging.h"
 #include "base/mac/mac_util.h"
+#include "base/mac/scoped_nsobject.h"
+
+// This view always takes the size of its superview. It is intended to be used
+// as a NSWindow's contentView.  It is needed because NSWindow's implementation
+// explicitly resizes the contentView at inopportune times.
+@interface FullSizeContentView : NSView
+@end
+
+namespace {
+
+// Reorders the subviews of NSWindow's root view so that the contentView is
+// moved to the back, and the ordering of the other views is unchanged.
+// |context| should be an NSArray containing the subviews of the root view as
+// they were previously ordered.
+int ReorderContentViewToBack(id firstView, id secondView, void* context) {
+  NSView* contentView = [[firstView window] contentView];
+  NSArray* subviews = static_cast<NSArray*>(context);
+  if (firstView == contentView)
+    return NSOrderedAscending;
+  if (secondView == contentView)
+    return NSOrderedDescending;
+  NSUInteger index1 = [subviews indexOfObject:firstView];
+  NSUInteger index2 = [subviews indexOfObject:secondView];
+  return (index1 < index2) ? NSOrderedAscending : NSOrderedDescending;
+}
+
+}  // namespace
 
 @interface VersionIndependentWindow ()
 
 + (BOOL)shouldUseFullSizeContentViewForStyle:(NSUInteger)windowStyle;
 
 - (NSView*)chromeWindowView;
 
 @end
 
-// This view always takes the size of its superview. It is intended to be used
-// as a NSWindow's contentView.  It is needed because NSWindow's implementation
-// explicitly resizes the contentView at inopportune times.
-@interface FullSizeContentView : NSView
-@end
-
 @implementation FullSizeContentView
 
 // This method is directly called by NSWindow during a window resize on OSX
 // 10.10.0, beta 2. We must override it to prevent the content view from
 // shrinking.
 - (void)setFrameSize:(NSSize)size {
   if ([self superview])
     size = [[self superview] bounds].size;
   [super setFrameSize:size];
 }
@@ skipping 40 matching lines @@
                             backing:bufferingType
                               defer:deferCreation];
   if (self) {
     if ([VersionIndependentWindow
         shouldUseFullSizeContentViewForStyle:windowStyle]) {
       chromeWindowView_.reset([[FullSizeContentView alloc] init]);
       [chromeWindowView_
           setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
       [chromeWindowView_ setFrame:[[[self contentView] superview] bounds]];
       [self setContentView:chromeWindowView_];
+
+      // Move the content view to the back.
+      // In Yosemite, the content view takes up the full size of the window,
+      // and when it is in front of the zoom/fullscreen button, alt-clicking
+      // the button has the wrong effect.
+      // Adding subviews to the NSThemeFrame provokes a warning in Yosemite, so
+      // we sort the subviews in place.
+      // http://crbug.com/393808
+
+      NSView* superview = [[self contentView] superview];
+      base::scoped_nsobject<NSArray> subviews([[superview subviews] copy]);
+      [superview sortSubviewsUsingFunction:&ReorderContentViewToBack
+                                   context:subviews.get()];

[Scott Hess - ex-Googler, 2014/07/17 21:03:09]

Wow.

I'm assuming the comment refers to an attempt to just [superview
addSubview:contentView positioned:NSWindowBelow relativeTo:nil]?

Another possibility which sounds like it might reorder things more directly:
  scoped_nsobject<NSMutableArray> subviews([[superview subviews] mutableCopy]);
  [subviews removeObject:contentView];  // assumes a ref is held elsewhere
  [subviews insertObject:contentView atIndex:0];
  [superview setSubviews:subviews];
AFAICT it shouldn't call -addSubview: or -removeSubview: in this case, instead
it will just reorder to match.

[erikchen, 2014/07/17 21:17:08]

I tried out your suggestion. It works fine and doesn't raise any warnings.

That being said, given that Apple has cracked down on addSubview:, setting the
subviews property seems like the next obvious method to shut down, since that
allows addition/removal of views. In place sorting of subviews seems much less
likely to produce warnings from future releases of AppKit.

     }
   }
   return self;
 }
 
 #pragma mark - Private Methods
 
 + (BOOL)shouldUseFullSizeContentViewForStyle:(NSUInteger)windowStyle {
   return (windowStyle & NSTitledWindowMask) && base::mac::IsOSYosemiteOrLater();
 }
@@ skipping 46 matching lines @@
   return [super contentRectForFrameRect:fRect styleMask:aStyle];
 }
 
 - (NSRect)contentRectForFrameRect:(NSRect)frameRect {
   if (chromeWindowView_)
     return frameRect;
   return [super contentRectForFrameRect:frameRect];
 }
 
 @end