Implement GetAllDisplays() for the Mac screen backend

ui/gfx/screen_mac.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "ui/gfx/screen.h"
 
 #import <ApplicationServices/ApplicationServices.h>
 #import <Cocoa/Cocoa.h>
 
+#include <map>
+
 #include "base/logging.h"
 #include "base/mac/sdk_forward_declarations.h"
 #include "ui/gfx/display.h"
 
 namespace {
 
 gfx::Rect ConvertCoordinateSystem(NSRect ns_rect) {
   // Primary monitor is defined as the monitor with the menubar,
   // which is always at index 0.
   NSScreen* primary_screen = [[NSScreen screens] objectAtIndex:0];
@@ skipping 69 matching lines @@
     return gfx::NativeWindow();
   }
 
   virtual gfx::NativeWindow GetWindowAtScreenPoint(const gfx::Point& point)
       OVERRIDE {
     NOTIMPLEMENTED();
     return gfx::NativeWindow();
   }
 
   virtual int GetNumDisplays() const OVERRIDE {
-    // Don't just return the number of online displays.  It includes displays
-    // that mirror other displays, which are not desired in the count.  It's
+    return GetAllDisplays().size();
+
+  }
+
+  virtual std::vector<gfx::Display> GetAllDisplays() const OVERRIDE {
+    // Don't just return all online displays.  This would include displays
+    // that mirror other displays, which are not desired in this list.  It's
     // tempting to use the count returned by CGGetActiveDisplayList, but active
-    // displays exclude sleeping displays, and those are desired in the count.
+    // displays exclude sleeping displays, and those are desired.
 
     // It would be ridiculous to have this many displays connected, but
     // CGDirectDisplayID is just an integer, so supporting up to this many
     // doesn't hurt.
     CGDirectDisplayID online_displays[128];
     CGDisplayCount online_display_count = 0;
     if (CGGetOnlineDisplayList(arraysize(online_displays),
                               online_displays,
                               &online_display_count) != kCGErrorSuccess) {
-      // 1 is a reasonable assumption.
-      return 1;
+      return std::vector<gfx::Display>(1, GetPrimaryDisplay());
     }
 
-    int display_count = 0;
+    typedef std::map<int64, NSScreen*> screenIdsToScreensMap;

[Nico, 2013/10/25 18:16:49]

types start with capital letters in chromium style. (or don't use a typedef at
all)

+    screenIdsToScreensMap screenIdsToScreens;
+    for (NSScreen* screen in [NSScreen screens]) {
+      NSDictionary* screenDeviceDescription = [screen deviceDescription];
+      int64 screenId = [[screenDeviceDescription
+        objectForKey:@"NSScreenNumber"] unsignedIntValue];
+      screenIdsToScreens[screenId] = screen;
+    }
+
+    std::vector<gfx::Display> displays;
     for (CGDisplayCount online_display_index = 0;
         online_display_index < online_display_count;
         ++online_display_index) {
       CGDirectDisplayID online_display = online_displays[online_display_index];
       if (CGDisplayMirrorsDisplay(online_display) == kCGNullDirectDisplay) {
-        // If this display doesn't mirror any other, include it in the count.
+        // If this display doesn't mirror any other, include it in the list.
         // The primary display in a mirrored set will be counted, but those that
         // mirror it will not be.
-        ++display_count;
+        screenIdsToScreensMap::iterator foundScreen =
+          screenIdsToScreens.find(online_display);
+        if (!(foundScreen == screenIdsToScreens.end())) {

[Nico, 2013/10/25 18:16:49]

You can write !(a == b) as a != b

+            displays.push_back(GetDisplayForScreen(foundScreen->second, false));

[Nico, 2013/10/25 18:16:49]

Won't one of these be the primary display? (see GetDisplayNearestPoint() for
similar code which does check this)

+        }
       }
     }
 
-    return display_count;
-  }
+    if (!displays.size())
+      return std::vector<gfx::Display>(1, GetPrimaryDisplay());
 
-  virtual std::vector<gfx::Display> GetAllDisplays() const OVERRIDE {
-    NOTIMPLEMENTED();
-    return std::vector<gfx::Display>(1, GetPrimaryDisplay());
+    return displays;
   }
 
   virtual gfx::Display GetDisplayNearestWindow(
       gfx::NativeView view) const OVERRIDE {
     NSWindow* window = [view window];
     if (!window)
       return GetPrimaryDisplay();
     NSScreen* match_screen = [window screen];
     return GetDisplayForScreen(match_screen, false /* may not be primary */);
   }
@@ skipping 42 matching lines @@
 
 }  // namespace
 
 namespace gfx {
 
 Screen* CreateNativeScreen() {
   return new ScreenMac;
 }
 
 }