Add ui/display, message_center, webview to GN build.

ui/display/BUILD.gn

Index: ui/display/BUILD.gn
diff --git a/ui/display/BUILD.gn b/ui/display/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..d9fa8ec4efd9a8bc3152f4fd55e2f104931cb7f4
--- /dev/null
+++ b/ui/display/BUILD.gn
@@ -0,0 +1,106 @@
+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/ui.gni")
+
+component("display") {
+  sources = [
+    "chromeos/display_configurator.cc",
+    "chromeos/display_configurator.h",
+    "chromeos/touchscreen_delegate_impl.cc",
+    "chromeos/touchscreen_delegate_impl.h",
+    "chromeos/ozone/display_configurator_ozone.cc",
+    "chromeos/x11/display_configurator_x11.cc",
+    "chromeos/x11/display_mode_x11.cc",
+    "chromeos/x11/display_mode_x11.h",
+    "chromeos/x11/display_snapshot_x11.cc",
+    "chromeos/x11/display_snapshot_x11.h",
+    "chromeos/x11/display_util_x11.cc",
+    "chromeos/x11/display_util_x11.h",
+    "chromeos/x11/native_display_delegate_x11.cc",
+    "chromeos/x11/native_display_delegate_x11.h",
+    "chromeos/x11/native_display_event_dispatcher_x11.cc",
+    "chromeos/x11/native_display_event_dispatcher_x11.h",
+    "chromeos/x11/touchscreen_device_manager_x11.cc",
+    "chromeos/x11/touchscreen_device_manager_x11.h",
+    "display_export.h",
+    "display_switches.cc",
+    "display_switches.h",
+  ]
+
+  defines = [ "DISPLAY_IMPLEMENTATION" ]
+
+  deps = [
+    "//base",
+    "//ui/display/util",
+    "//ui/gfx",
+    "//ui/gfx/geometry",
+  ]
+
+  if (use_x11) {
+    configs += [
+      "//build/config/linux:x11",
+      "//build/config/linux:xext",
+      "//build/config/linux:xi",
+      "//build/config/linux:xrandr",
+    ]
+    deps += [
+      "//ui/events/platform",
+    ]
+  }
+
+  if (is_chromeos) {
+    deps += [ "//ui/display/types" ]
+  }
+
+  if (use_ozone) {
+    deps += [ "//ui/ozone" ]
+  }
+}
+
+component("test_util") {
+  output_name = "display_test_util"
+  sources = [
+    "chromeos/test/test_display_snapshot.cc",
+    "chromeos/test/test_display_snapshot.h",
+  ]
+
+  defines = [ "DISPLAY_IMPLEMENTATION" ]
+
+  deps = [
+    "//base",
+    "//ui/gfx",
+    "//ui/gfx/geometry",
+  ]
+
+  if (is_chromeos) {
+    deps += [ "//ui/display/types" ]
+  }
+}
+
+test("display_unittests") {
+  sources = [
+    "chromeos/display_configurator_unittest.cc",
+    "chromeos/touchscreen_delegate_impl_unittest.cc",
+    "chromeos/x11/display_util_x11_unittest.cc",
+    "chromeos/x11/native_display_event_dispatcher_x11_unittest.cc",
+    "util/display_util_unittest.cc",
+    "util/edid_parser_unittest.cc",
+  ]
+
+  deps = [
+    "//base/test:run_all_unittests",
+    "//testing/gtest",
+    "//ui/display/util",
+    "//ui/gfx/geometry",
+  ]
+
+  if (is_chromeos) {
+    deps += [
+      ":display",
+      ":test_util",
+      "//ui/display/types",
+    ]
+  }
+}