Implemented ShowOptionsWindow() for OS X (except the highlighting

chrome/browser/cocoa/preferences_window_controller.mm

 // Copyright (c) 2009 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/cocoa/preferences_window_controller.h"
 
 #include <algorithm>
 #include "app/l10n_util.h"
 #include "app/l10n_util_mac.h"
+#include "base/logging.h"
 #include "base/mac_util.h"
 #include "base/string16.h"
 #include "base/string_util.h"
 #include "base/sys_string_conversions.h"
 #include "chrome/browser/browser.h"
 #include "chrome/browser/browser_list.h"
 #include "chrome/browser/browser_process.h"
 #import "chrome/browser/cocoa/clear_browsing_data_controller.h"
 #import "chrome/browser/cocoa/custom_home_pages_model.h"
 #import "chrome/browser/cocoa/keyword_editor_cocoa_controller.h"
@@ skipping 350 matching lines @@
 - (void)setPasswordManagerEnabledIndex:(NSInteger)value;
 - (void)setFormAutofillEnabledIndex:(NSInteger)value;
 - (void)setIsUsingDefaultTheme:(BOOL)value;
 - (void)setShowAlternateErrorPages:(BOOL)value;
 - (void)setUseSuggest:(BOOL)value;
 - (void)setDnsPrefetch:(BOOL)value;
 - (void)setSafeBrowsing:(BOOL)value;
 - (void)setMetricsRecording:(BOOL)value;
 - (void)setCookieBehavior:(NSInteger)value;
 - (void)setAskForSaveLocation:(BOOL)value;
-- (void)displayPreferenceViewForToolbarItem:(NSToolbarItem*)toolbarItem
-                                    animate:(BOOL)animate;
+- (void)displayPreferenceViewForPage:(OptionsPage)page
+                             animate:(BOOL)animate;
 @end
 
 // A C++ class registered for changes in preferences. Bridges the
 // notification back to the PWC.
 class PrefObserverBridge : public NotificationObserver,
                            public ProfileSyncServiceObserver {
  public:
   PrefObserverBridge(PreferencesWindowController* controller)
       : controller_(controller) {}
 
@@ skipping 11 matching lines @@
   virtual void OnStateChanged() {
     [controller_ syncStateChanged];
   }
 
  private:
   PreferencesWindowController* controller_;  // weak, owns us
 };
 
 @implementation PreferencesWindowController
 
-- (id)initWithProfile:(Profile*)profile {
+- (id)initWithProfile:(Profile*)profile initialPage:(OptionsPage)initialPage {
   DCHECK(profile);
   // Use initWithWindowNibPath:: instead of initWithWindowNibName: so we
   // can override it in a unit test.
   NSString* nibPath = [mac_util::MainAppBundle()
                         pathForResource:@"Preferences"
                                  ofType:@"nib"];
   if ((self = [super initWithWindowNibPath:nibPath owner:self])) {
     profile_ = profile;
+    initialPage_ = initialPage;
     prefs_ = profile->GetPrefs();
     DCHECK(prefs_);
     observer_.reset(new PrefObserverBridge(self));
 
     // Set up the model for the custom home page table. The KVO observation
     // tells us when the number of items in the array changes. The normal
     // observation tells us when one of the URLs of an item changes.
     customPagesSource_.reset([[CustomHomePagesModel alloc]
                                 initWithProfile:profile_]);
     const SessionStartupPref startupPref =
@@ skipping 208 matching lines @@
       resizeViewWithoutAutoResizingSubViews:underTheHoodContentView_
                                       delta:NSMakeSize(0.0, verticalShift)];
   underTheHoodContentSize = [underTheHoodContentView_ frame].size;
 
   // Put the Under the Hood content view into the scroller and scroll it to the
   // top.
   [underTheHoodScroller_ setDocumentView:underTheHoodContentView_];
   [underTheHoodContentView_ scrollPoint:
       NSMakePoint(0, underTheHoodContentSize.height)];
 
-  // Get the last visited page from local state.
-  OptionsPage page = static_cast<OptionsPage>(lastSelectedPage_.GetValue());
-  if (page == OPTIONS_PAGE_DEFAULT)
-    page = OPTIONS_PAGE_GENERAL;
-
-  NSUInteger pageIndex = (NSUInteger)page;
-  if (pageIndex >= [[toolbar_ items] count])
-    pageIndex = 0;
-  NSToolbarItem* firstItem = [[toolbar_ items] objectAtIndex:pageIndex];
-  [self displayPreferenceViewForToolbarItem:firstItem animate:NO];
-  [toolbar_ setSelectedItemIdentifier:[firstItem itemIdentifier]];
+  [self switchToPage:initialPage_ animate:NO];
 
   // TODO(pinkerton): save/restore position based on prefs.
   [[self window] center];
 }
 
 - (void)dealloc {
   if (syncService_) {
     syncService_->RemoveObserver(observer_.get());
   }
   [customPagesSource_ removeObserver:self forKeyPath:@"customHomePages"];
@@ skipping 627 matching lines @@
 - (IBAction)privacyLearnMore:(id)sender {
   // We open a new browser window so the Options dialog doesn't get lost
   // behind other windows.
   Browser* browser = Browser::Create(profile_);
   browser->OpenURL(GURL(l10n_util::GetStringUTF16(IDS_LEARN_MORE_PRIVACY_URL)),
                    GURL(), NEW_WINDOW, PageTransition::LINK);
 }
 
 - (IBAction)toolbarButtonSelected:(id)sender {
   DCHECK([sender isKindOfClass:[NSToolbarItem class]]);
-  [self displayPreferenceViewForToolbarItem:sender
-                                    animate:YES];
+  OptionsPage page = [self getPageForToolbarItem:sender];
+  [self displayPreferenceViewForPage:page animate:YES];
 }
 
-// Helper to update the window to display a preferences view for a toolbaritem.
-- (void)displayPreferenceViewForToolbarItem:(NSToolbarItem*)toolbarItem
-                                    animate:(BOOL)animate {
-  NSView* prefsView = NULL;
-  OptionsPage page = OPTIONS_PAGE_DEFAULT;
-  // Tags are set in the nib file.
-  switch ([toolbarItem tag]) {
-    case 0:  // Basics
-      prefsView = basicsView_;
-      page = OPTIONS_PAGE_GENERAL;
-      break;
-    case 1:  // Personal Stuff
-      prefsView = personalStuffView_;
-      page = OPTIONS_PAGE_CONTENT;
-      break;
-    case 2:  // Under the Hood
-      prefsView = underTheHoodView_;
-      page = OPTIONS_PAGE_ADVANCED;
-      break;
-    default:
-      NOTIMPLEMENTED();
-  }
+// Helper to update the window to display a preferences view for a page.
+- (void)displayPreferenceViewForPage:(OptionsPage)page
+                             animate:(BOOL)animate {
+  NSWindow* prefsWindow = [self window];
 
-  NSWindow* prefsWindow = [self window];
+  // Needs to go *after* the call to [self window], which triggers
+  // awakeFromNib if necessary.
+  NSView* prefsView = [self getPrefsViewForPage:page];
   NSView* contentView = [prefsWindow contentView];
 
   // Normally there is only one view, but if the user clicks really quickly, the
   // animation could still been running, and the last view is the one that was
   // animating in.
   NSArray* subviews = [contentView subviews];
   NSView* currentPrefsView = nil;
   if ([subviews count]) {
     currentPrefsView = [subviews lastObject];
   }
@@ skipping 29 matching lines @@
     prefsViewFrame.origin.y =
         NSHeight(contentViewFrame) - NSHeight(prefsViewFrame);
   }
   [prefsView setFrame:prefsViewFrame];
 
   // Add the view.
   [contentView addSubview:prefsView];
   [prefsWindow setInitialFirstResponder:prefsView];
 
   // Update the window title.
+  NSToolbarItem* toolbarItem = [self getToolbarItemForPage:page];
   [prefsWindow setTitle:[toolbarItem label]];
 
   // Figure out the size of the window.
   NSRect windowFrame = [prefsWindow frame];
   CGFloat titleToolbarHeight =
       NSHeight(windowFrame) - NSHeight(contentViewFrame);
   windowFrame.size.height =
       NSHeight(prefsViewFrame) + titleToolbarHeight;
   DCHECK_GE(NSWidth(windowFrame), NSWidth(prefsViewFrame))
       << "Initial width set wasn't wide enough.";
@@ skipping 225 matching lines @@
   string16 statusLabel, linkLabel;
   SyncStatusUIHelper::GetLabels(syncService_, &statusLabel, &linkLabel);
   [syncStatus_ setStringValue:base::SysUTF16ToNSString(statusLabel)];
 }
 
 // Show the preferences window.
 - (IBAction)showPreferences:(id)sender {
   [self showWindow:sender];
 }
 
+- (void)switchToPage:(OptionsPage)page animate:(BOOL)animate {
+  [self displayPreferenceViewForPage:page animate:animate];
+  NSToolbarItem* toolbarItem = [self getToolbarItemForPage:page];
+  [toolbar_ setSelectedItemIdentifier:[toolbarItem itemIdentifier]];
+}
+
 // Called when the window is being closed. Send out a notification that the user
 // is done editing preferences. Make sure there are no pending field editors
 // by clearing the first responder.
 - (void)windowWillClose:(NSNotification*)notification {
   // Setting the first responder to the window ends any in-progress field
   // editor. This will update the model appropriately so there's nothing left
   // to do.
   if (![[self window] makeFirstResponder:[self window]]) {
     // We've hit a recalcitrant field editor, force it to go away.
     [[self window] endEditingFor:nil];
   }
 
   [[NSNotificationCenter defaultCenter]
       postNotificationName:kUserDoneEditingPrefsNotification
                     object:self];
 }
 
 - (void)controlTextDidEndEditing:(NSNotification*)notification {
   [customPagesSource_ validateURLs];
 }
 
 @end
+
+@implementation PreferencesWindowController(Testing)
+
+- (IntegerPrefMember*)lastSelectedPage {
+  return &lastSelectedPage_;
+}
+
+- (NSToolbar*)toolbar {
+  return toolbar_;
+}
+
+- (NSView*)basicsView {
+  return basicsView_;
+}
+
+- (NSView*)personalStuffView {
+  return personalStuffView_;
+}
+
+- (NSView*)underTheHoodView {
+  return underTheHoodView_;
+}
+
+- (OptionsPage)normalizePage:(OptionsPage)page {
+  if (page == OPTIONS_PAGE_DEFAULT) {
+    // Get the last visited page from local state.
+    page = static_cast<OptionsPage>(lastSelectedPage_.GetValue());
+    if (page == OPTIONS_PAGE_DEFAULT) {
+      page = OPTIONS_PAGE_GENERAL;
+    }
+  }
+  return page;
+}
+
+- (NSToolbarItem*)getToolbarItemForPage:(OptionsPage)page {
+  NSUInteger pageIndex = (NSUInteger)[self normalizePage:page];
+  NSArray* items = [toolbar_ items];
+  NSUInteger itemCount = [items count];
+  DCHECK_GE(pageIndex, 0U);
+  if (pageIndex >= itemCount) {
+    NOTIMPLEMENTED();
+    pageIndex = 0;
+  }
+  DCHECK_GT(itemCount, 0U);
+  return [items objectAtIndex:pageIndex];
+}
+
+- (OptionsPage)getPageForToolbarItem:(NSToolbarItem*)toolbarItem {
+  // Tags are set in the nib file.
+  switch ([toolbarItem tag]) {
+    case 0:  // Basics
+      return OPTIONS_PAGE_GENERAL;
+    case 1:  // Personal Stuff
+      return OPTIONS_PAGE_CONTENT;
+    case 2:  // Under the Hood
+      return OPTIONS_PAGE_ADVANCED;
+    default:
+      NOTIMPLEMENTED();
+      return OPTIONS_PAGE_GENERAL;
+  }
+}
+
+- (NSView*)getPrefsViewForPage:(OptionsPage)page {
+  // The views will be NULL if this is mistakenly called before awakeFromNib.
+  DCHECK(basicsView_);
+  DCHECK(personalStuffView_);
+  DCHECK(underTheHoodView_);
+  page = [self normalizePage:page];
+  switch (page) {
+    case OPTIONS_PAGE_GENERAL:
+      return basicsView_;
+    case OPTIONS_PAGE_CONTENT:
+      return personalStuffView_;
+    case OPTIONS_PAGE_ADVANCED:
+      return underTheHoodView_;
+    case OPTIONS_PAGE_DEFAULT:
+    case OPTIONS_PAGE_COUNT:
+      LOG(DFATAL) << "Invalid page value " << page;
+  }
+  return basicsView_;
+}
+
+@end