Added Sync-related controls to Preferences pane under "Personal Stuff".

chrome/browser/cocoa/preferences_window_controller.mm

 // Copyright (c) 2009 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/cocoa/preferences_window_controller.h"
 
 #include <algorithm>
 #include "app/l10n_util.h"
+#include "app/l10n_util_mac.h"
 #include "base/mac_util.h"
+#include "base/string16.h"
 #include "base/string_util.h"
 #include "base/sys_string_conversions.h"
 #include "chrome/browser/browser.h"
 #include "chrome/browser/browser_list.h"
 #include "chrome/browser/browser_process.h"
 #import "chrome/browser/cocoa/clear_browsing_data_controller.h"
 #import "chrome/browser/cocoa/custom_home_pages_model.h"
 #import "chrome/browser/cocoa/keyword_editor_cocoa_controller.h"
 #import "chrome/browser/cocoa/search_engine_list_model.h"
 #include "chrome/browser/extensions/extensions_service.h"
 #include "chrome/browser/metrics/metrics_service.h"
 #include "chrome/browser/metrics/user_metrics.h"
 #include "chrome/browser/net/dns_global.h"
 #include "chrome/browser/net/url_fixer_upper.h"
 #include "chrome/browser/options_window.h"
 #include "chrome/browser/profile.h"
 #include "chrome/browser/safe_browsing/safe_browsing_service.h"
 #include "chrome/browser/session_startup_pref.h"
 #include "chrome/browser/shell_integration.h"
+#include "chrome/browser/sync/profile_sync_service.h"
+#include "chrome/browser/sync/sync_status_ui_helper.h"
 #include "chrome/browser/tab_contents/tab_contents.h"
 #include "chrome/common/notification_details.h"
 #include "chrome/common/notification_observer.h"
 #include "chrome/common/notification_type.h"
 #include "chrome/common/pref_names.h"
 #include "chrome/common/pref_service.h"
 #include "chrome/common/url_constants.h"
 #include "chrome/installer/util/google_update_settings.h"
 #include "grit/chromium_strings.h"
 #include "grit/generated_resources.h"
@@ skipping 203 matching lines @@
   CGFloat y1 = NSMinY([view1 frame]);
   CGFloat y2 = NSMinY([view2 frame]);
   if (y1 < y2)
     return NSOrderedAscending;
   else if (y1 > y2)
     return NSOrderedDescending;
   else
     return NSOrderedSame;
 }
 
-#if !defined(GOOGLE_CHROME_BUILD)
 // Helper to remove a view and move everything above it down to take over the
 // space.
 void RemoveViewFromView(NSView* view, NSView* toRemove) {
   // Sort bottom up so we can spin over what is above it.
   NSArray* views =
       [[view subviews] sortedArrayUsingFunction:CompareFrameY context:NULL];
 
   // Find where |toRemove| was.
   NSUInteger index = [views indexOfObject:toRemove];
   DCHECK_NE(index, NSNotFound);
   NSUInteger count = [views count];
-  if (index == (count - 1))
-    return;  // It was the top item, nothing to do (shouldn't happen).
+  CGFloat shrinkHeight = 0;
+  if (index < (count - 1)) {
+    // If we're not the topmost control, the amount to shift is the bottom of
+    // |toRemove| to the bottom of the view above it.
+    CGFloat shiftDown =
+        NSMinY([[views objectAtIndex:index + 1] frame]) -
+        NSMinY([toRemove frame]);
 
-  // The amount to shift is the bottom of |toRemove| to the bottom of the view
-  // above it.
-  CGFloat shiftDown =
-      NSMinY([[views objectAtIndex:index + 1] frame]) -
-      NSMinY([toRemove frame]);
+    // Now cycle over the views above it moving them down.
+    for (++index; index < count; ++index) {
+      NSView* view = [views objectAtIndex:index];
+      NSPoint origin = [view frame].origin;
+      origin.y -= shiftDown;
+      [view setFrameOrigin:origin];
+    }
 
-  // Now cycle over the views above it moving them down.
-  for (++index; index < count; ++index) {
-    NSView* view = [views objectAtIndex:index];
-    NSPoint origin = [view frame].origin;
-    origin.y -= shiftDown;
-    [view setFrameOrigin:origin];
+    shrinkHeight = shiftDown;
+  } else if (index > 0) {
+    // If we're the topmost control, there's nothing to shift but we want to
+    // shrink until the top edge of the second-topmost control, unless it is
+    // actually higher than the topmost control (since we're sorting by the
+    // bottom edge).
+    shrinkHeight = std::max(0.f,
+        NSMaxY([toRemove frame]) -
+        NSMaxY([[views objectAtIndex:index - 1] frame]));
   }
+  // If we only have one control, don't do any resizing (for now).
 
   // Remove |toRemove|.
   [toRemove removeFromSuperview];
 
-  // Resize the view.
   [GTMUILocalizerAndLayoutTweaker
       resizeViewWithoutAutoResizingSubViews:view
-                                      delta:NSMakeSize(0, -shiftDown)];
+                                      delta:NSMakeSize(0, -shrinkHeight)];
 }
-#endif  // !defined(GOOGLE_CHROME_BUILD)
+
+// Simply removes all the views in |toRemove|.
+void RemoveGroupFromView(NSView* view, NSArray* toRemove) {
+  for (NSView* viewToRemove in toRemove) {
+    RemoveViewFromView(view, viewToRemove);
+  }
+}
 
 // Helper to tweak the layout of the "Under the Hood" content by autosizing all
 // the views and moving things up vertically.  Special case the two controls for
 // download location as they are horizontal, and should fill the row.
 CGFloat AutoSizeUnderTheHoodContent(NSView* view,
                                     NSPathControl* downloadLocationControl,
                                     NSButton* downloadLocationButton) {
   CGFloat verticalShift = 0.0;
 
   // Loop bottom up through the views sizing and shifting.
@@ skipping 25 matching lines @@
 }
 
 }  // namespace
 
 //-------------------------------------------------------------------------
 
 @interface PreferencesWindowController(Private)
 // Callback when preferences are changed. |prefName| is the name of the
 // pref that has changed.
 - (void)prefChanged:(std::wstring*)prefName;
+// Callback when sync state has changed.  syncService_ needs to be
+// queried to find out what happened.
+- (void)syncStateChanged;
 // Record the user performed a certain action and save the preferences.
 - (void)recordUserAction:(const wchar_t*)action;
 - (void)registerPrefObservers;
 - (void)unregisterPrefObservers;
 
 - (void)customHomePagesChanged;
 
 // KVC setter methods.
 - (void)setNewTabPageIsHomePageIndex:(NSInteger)val;
 - (void)setHomepageURL:(NSString*)urlString;
 - (void)setRestoreOnStartupIndex:(NSInteger)type;
 - (void)setShowHomeButton:(BOOL)value;
 - (void)setShowPageOptionsButtons:(BOOL)value;
 - (void)setPasswordManagerEnabledIndex:(NSInteger)value;
 - (void)setFormAutofillEnabledIndex:(NSInteger)value;
 - (void)setIsUsingDefaultTheme:(BOOL)value;
 - (void)setShowAlternateErrorPages:(BOOL)value;
 - (void)setUseSuggest:(BOOL)value;
 - (void)setDnsPrefetch:(BOOL)value;
 - (void)setSafeBrowsing:(BOOL)value;
 - (void)setMetricsRecording:(BOOL)value;
 - (void)setCookieBehavior:(NSInteger)value;
 - (void)setAskForSaveLocation:(BOOL)value;
 - (void)displayPreferenceViewForToolbarItem:(NSToolbarItem*)toolbarItem
                                     animate:(BOOL)animate;
 @end
 
 // A C++ class registered for changes in preferences. Bridges the
 // notification back to the PWC.
-class PrefObserverBridge : public NotificationObserver {
+class PrefObserverBridge : public NotificationObserver,
+                           public ProfileSyncServiceObserver {
  public:
   PrefObserverBridge(PreferencesWindowController* controller)
-      : controller_(controller) { }
+      : controller_(controller) {}
+
+  virtual ~PrefObserverBridge() {}
+
   // Overridden from NotificationObserver:
   virtual void Observe(NotificationType type,
                        const NotificationSource& source,
                        const NotificationDetails& details) {
     if (type == NotificationType::PREF_CHANGED)
       [controller_ prefChanged:Details<std::wstring>(details).ptr()];
   }
+
+  // Overridden from ProfileSyncServiceObserver.
+  virtual void OnStateChanged() {
+    [controller_ syncStateChanged];
+  }
+
  private:
   PreferencesWindowController* controller_;  // weak, owns us
 };
 
 @implementation PreferencesWindowController
 
 - (id)initWithProfile:(Profile*)profile {
   DCHECK(profile);
   // Use initWithWindowNibPath:: instead of initWithWindowNibName: so we
   // can override it in a unit test.
@@ skipping 42 matching lines @@
     // Use one animation so we can stop it if the user clicks quickly, and
     // start the new animation.
     animation_.reset([[NSViewAnimation alloc] init]);
     // Make this the delegate so it can remove the old view at the end of the
     // animation (once it is faded out).
     [animation_ setDelegate:self];
     // The default duration is 0.5s, which actually feels slow in here, so speed
     // it up a bit.
     [animation_ gtm_setDuration:0.2];
     [animation_ setAnimationBlockingMode:NSAnimationNonblocking];
+
+    // TODO(akalin): handle incognito profiles?  The windows version of this
+    // (in chrome/browser/views/options/content_page_view.cc) just does what
+    // we do below.
+    syncService_ = profile_->GetProfileSyncService();
   }
   return self;
 }
 
 - (void)awakeFromNib {
 
   // Validate some assumptions in debug builds.
 
   // "Basics", "Personal Stuff", and "Under the Hood" views should be the same
   // width.  They should be the same width so they are laid out to look as good
@@ skipping 10 matching lines @@
       << "The Under the Hood content should be narrower than the content "
          "of the scroller it goes into";
 
 #if !defined(GOOGLE_CHROME_BUILD)
   // "Enable logging" (breakpad and stats) is only in Google Chrome builds,
   // remove the checkbox and slide everything above it down.
   RemoveViewFromView(underTheHoodContentView_, enableLoggingCheckbox_);
 #endif  // !defined(GOOGLE_CHROME_BUILD)
 
   // There are three problem children within the groups:
-  //   Bascis - Default Browser
+  //   Basics - Default Browser
   //   Personal Stuff - Themes
   //   Personal Stuff - Browser Data
   // These three have buttons that with some localizations are wider then the
   // view.  So the three get manually laid out before doing the general work so
   // the views/window can be made wide enough to fit them.  The layout in the
   // general pass is a noop for these buttons (since they are already sized).
 
   // Size the default browser button.
   const NSUInteger kDefaultBrowserGroupCount = 3;
   const NSUInteger kDefaultBrowserButtonIndex = 1;
@@ skipping 74 matching lines @@
                                  verticalShift);
   verticalShift += AutoSizeGroup(personalStuffGroupBrowserData_,
                                  kAutoSizeGroupBehaviorVerticalToFit,
                                  verticalShift);
   verticalShift += AutoSizeGroup(personalStuffGroupAutofill_,
                                  kAutoSizeGroupBehaviorVerticalToFit,
                                  verticalShift);
   verticalShift += AutoSizeGroup(personalStuffGroupPasswords_,
                                  kAutoSizeGroupBehaviorVerticalToFit,
                                  verticalShift);
+  // We want to autosize the sync button but not the text field, so we use
+  // VerticalFirstToFit.
+  verticalShift += AutoSizeGroup(personalStuffGroupSync_,
+                                 kAutoSizeGroupBehaviorVerticalFirstToFit,
+                                 verticalShift);
   [GTMUILocalizerAndLayoutTweaker
       resizeViewWithoutAutoResizingSubViews:personalStuffView_
                                       delta:NSMakeSize(0.0, verticalShift)];
 
+  if (syncService_) {
+    syncService_->AddObserver(observer_.get());
+    // Update the controls according to the initial state.
+    [self syncStateChanged];
+  } else {
+    // If sync is disabled we don't want to show the sync controls at all.
+    RemoveGroupFromView(personalStuffView_, personalStuffGroupSync_);
+  }
+
   // Make the window as wide as the views.
   NSWindow* prefsWindow = [self window];
   NSRect frame = [prefsWindow frame];
   frame.size.width = newWidth;
   [prefsWindow setFrame:frame display:NO];
 
   // The Under the Hood prefs is a scroller, it shouldn't get any border, so it
   // gets resized to the as wide as the window ended up.
   NSSize underTheHoodSize = [underTheHoodView_ frame].size;
   underTheHoodSize.width = newWidth;
@@ skipping 30 matching lines @@
     pageIndex = 0;
   NSToolbarItem* firstItem = [[toolbar_ items] objectAtIndex:pageIndex];
   [self displayPreferenceViewForToolbarItem:firstItem animate:NO];
   [toolbar_ setSelectedItemIdentifier:[firstItem itemIdentifier]];
 
   // TODO(pinkerton): save/restore position based on prefs.
   [[self window] center];
 }
 
 - (void)dealloc {
+  if (syncService_) {
+    syncService_->RemoveObserver(observer_.get());
+  }
   [customPagesSource_ removeObserver:self forKeyPath:@"customHomePages"];
   [[NSNotificationCenter defaultCenter] removeObserver:self];
   [self unregisterPrefObservers];
   [super dealloc];
 }
 
 // Xcode 3.1.x version of Interface Builder doesn't do a lot for editing
 // toolbars in XIB.  So the toolbar's delegate is set to the controller so it
 // can tell the toolbar what items are selectable.
 - (NSArray*)toolbarSelectableItemIdentifiers:(NSToolbar*)toolbar {
@@ skipping 500 matching lines @@
     browser->OpenURL(
         GURL(l10n_util::GetStringUTF8(IDS_THEMES_GALLERY_URL)),
         GURL(), NEW_WINDOW, PageTransition::LINK);
   } else {
     browser->OpenURL(
         GURL(l10n_util::GetStringUTF8(IDS_THEMES_GALLERY_URL)),
         GURL(), NEW_FOREGROUND_TAB, PageTransition::LINK);
   }
 }
 
+- (IBAction)doSyncAction:(id)sender {
+  DCHECK(syncService_);
+  if (syncService_->HasSyncSetupCompleted()) {
+    syncService_->DisableForUser();
+    ProfileSyncService::SyncEvent(ProfileSyncService::STOP_FROM_OPTIONS);
+    // TODO(akalin): Pop up a confirmation dialog before disabling syncing.
+  } else {
+    syncService_->EnableForUser();
+    ProfileSyncService::SyncEvent(ProfileSyncService::START_FROM_OPTIONS);
+  }
+}
+
 - (void)setPasswordManagerEnabledIndex:(NSInteger)value {
   if (value == kEnabledIndex)
     [self recordUserAction:L"Options_PasswordManager_Enable"];
   else
     [self recordUserAction:L"Options_PasswordManager_Disable"];
   askSavePasswords_.SetValue(value == kEnabledIndex ? true : false);
 }
 
 - (NSInteger)passwordManagerEnabledIndex {
   return askSavePasswords_.GetValue() ? kEnabledIndex : kDisabledIndex;
@@ skipping 373 matching lines @@
 // Callback when preferences are changed. |prefName| is the name of the
 // pref that has changed and should not be NULL.
 - (void)prefChanged:(std::wstring*)prefName {
   DCHECK(prefName);
   if (!prefName) return;
   [self basicsPrefChanged:prefName];
   [self userDataPrefChanged:prefName];
   [self underHoodPrefChanged:prefName];
 }
 
+// Callback when sync service state has changed.
+//
+// TODO(akalin): Decomp this out since a lot of it is copied from the
+// Windows version.
+// TODO(akalin): Actually have a control for the link.
+// TODO(akalin): Change the background of the status label/link on error.
+// TODO(akalin): Make sure selecting the "Sync my bookmarks..." menu item
+// pops up this preference pane if syncing has already been set up.
+- (void)syncStateChanged {
+  DCHECK(syncService_);
+
+  [syncButton_ setEnabled:!syncService_->WizardIsVisible()];
+  NSString* buttonLabel;
+  if (syncService_->HasSyncSetupCompleted()) {
+    buttonLabel = l10n_util::GetNSStringWithFixup(
+        IDS_SYNC_STOP_SYNCING_BUTTON_LABEL);
+  } else if (syncService_->SetupInProgress()) {
+    buttonLabel = l10n_util::GetNSStringWithFixup(
+        IDS_SYNC_NTP_SETUP_IN_PROGRESS);
+  } else {
+    buttonLabel = l10n_util::GetNSStringWithFixup(
+        IDS_SYNC_START_SYNC_BUTTON_LABEL);
+  }
+  [syncButton_ setTitle:buttonLabel];
+
+  string16 statusLabel, linkLabel;
+  SyncStatusUIHelper::GetLabels(syncService_, &statusLabel, &linkLabel);
+  [syncStatus_ setStringValue:base::SysUTF16ToNSString(statusLabel)];
+}
+
 // Show the preferences window.
 - (IBAction)showPreferences:(id)sender {
   [self showWindow:sender];
 }
 
 // Called when the window is being closed. Send out a notification that the user
 // is done editing preferences. Make sure there are no pending field editors
 // by clearing the first responder.
 - (void)windowWillClose:(NSNotification*)notification {
   // Setting the first responder to the window ends any in-progress field
   // editor. This will update the model appropriately so there's nothing left
   // to do.
   if (![[self window] makeFirstResponder:[self window]]) {
     // We've hit a recalcitrant field editor, force it to go away.
     [[self window] endEditingFor:nil];
   }
 
   [[NSNotificationCenter defaultCenter]
       postNotificationName:kUserDoneEditingPrefsNotification
                     object:self];
 }
 
 - (void)controlTextDidEndEditing:(NSNotification*)notification {
   [customPagesSource_ validateURLs];
 }
 
 @end