[Mac] Cmd+W should close the User Manager

chrome/browser/ui/cocoa/profiles/user_manager_mac.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/browser/ui/cocoa/profiles/user_manager_mac.h"
 
+#include "chrome/app/chrome_command_ids.h"
 #include "chrome/browser/browser_process.h"
 #include "chrome/browser/profiles/profile_manager.h"
 #include "chrome/browser/ui/browser_dialogs.h"
+#import "chrome/browser/ui/cocoa/browser_window_utils.h"
+#include "chrome/browser/ui/cocoa/chrome_event_processing_window.h"
+#include "content/public/browser/native_web_keyboard_event.h"
 #include "content/public/browser/web_contents.h"
+#include "content/public/browser/web_contents_delegate.h"
 #include "grit/generated_resources.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 
 // Default window size. Taken from the views implementation in
 // chrome/browser/ui/views/user_manager_view.cc.
 // TODO(noms): Figure out if this size can be computed dynamically or adjusted
 // for smaller screens.
 const int kWindowWidth = 900;
 const int kWindowHeight = 700;
 
 namespace chrome {
 
 // Declared in browser_dialogs.h so others don't have to depend on this header.
 void ShowUserManager(const base::FilePath& profile_path_to_focus) {
   UserManagerMac::Show(
       profile_path_to_focus, profiles::USER_MANAGER_NO_TUTORIAL);
 }
 
 void ShowUserManagerWithTutorial(profiles::UserManagerTutorialMode tutorial) {
   UserManagerMac::Show(base::FilePath(), tutorial);
 }
 
 void HideUserManager() {
   UserManagerMac::Hide();
 }
 
 }  // namespace chrome
 
+// Custom WebContentsDelegate that allows handling of hotkeys.
+class UserManagerWebContentsDelegate : public content::WebContentsDelegate {
+ public:
+  UserManagerWebContentsDelegate(ChromeEventProcessingWindow* window)
+    : window_(window) {}
+
+  // WebContentsDelegate implementation. Forwards all unhandled keyboard events
+  // to the current window.
+  virtual void HandleKeyboardEvent(
+      content::WebContents* source,
+      const content::NativeWebKeyboardEvent& event) OVERRIDE {
+    if (![BrowserWindowUtils shouldHandleKeyboardEvent:event])
+      return;
+
+    int commandId = [BrowserWindowUtils getCommandId:event];
+
+    // Since the User Manager is a "top level" window, only handle close events.
+    if (commandId == IDC_CLOSE_WINDOW || commandId == IDC_EXIT) {
+      // Not invoking +[BrowserWindowUtils handleKeyboardEvent here], since the
+      // window in question is a ConstrainedWindowCustomWindow, not a
+      // BrowserWindow.
+      [window_ redispatchKeyEvent:event.os_event];
+    }
+  }
+
+ private:
+  ChromeEventProcessingWindow* window_;  // Used to redispatch key events.
+};
+
 // Window controller for the User Manager view.
 @interface UserManagerWindowController : NSWindowController <NSWindowDelegate> {
  @private
   scoped_ptr<content::WebContents> webContents_;
+  scoped_ptr<UserManagerWebContentsDelegate> webContentsDelegate_;
   UserManagerMac* userManagerObserver_;  // Weak.
 }
 - (void)windowWillClose:(NSNotification*)notification;
 - (void)dealloc;
 - (id)initWithProfile:(Profile*)profile
          withObserver:(UserManagerMac*)userManagerObserver;
 - (void)showURL:(const GURL&)url;
 - (void)show;
 - (void)close;
 - (BOOL)isVisible;
 @end
 
 @implementation UserManagerWindowController
 
 - (id)initWithProfile:(Profile*)profile
          withObserver:(UserManagerMac*)userManagerObserver {
 
   // Center the window on the primary screen.
   CGFloat screenHeight =
       [[[NSScreen screens] objectAtIndex:0] frame].size.height;
   CGFloat screenWidth =
       [[[NSScreen screens] objectAtIndex:0] frame].size.width;
 
   NSRect contentRect = NSMakeRect((screenWidth - kWindowWidth) / 2,
                                   (screenHeight - kWindowHeight) / 2,
                                   kWindowWidth, kWindowHeight);
-  NSWindow* window = [[NSWindow alloc]
+  ChromeEventProcessingWindow* window = [[ChromeEventProcessingWindow alloc]
       initWithContentRect:contentRect
                 styleMask:NSTitledWindowMask |
                           NSClosableWindowMask |
                           NSResizableWindowMask
                   backing:NSBackingStoreBuffered
                     defer:NO];
   [window setTitle:l10n_util::GetNSString(IDS_USER_MANAGER_SCREEN_TITLE)];
   [window setMinSize:NSMakeSize(kWindowWidth, kWindowHeight)];
 
   if ((self = [super initWithWindow:window])) {
     userManagerObserver_ = userManagerObserver;
 
     // Initialize the web view.
     webContents_.reset(content::WebContents::Create(
         content::WebContents::CreateParams(profile)));
     window.contentView = webContents_->GetNativeView();
+    webContentsDelegate_.reset(new UserManagerWebContentsDelegate(window));
+    webContents_->SetDelegate(webContentsDelegate_.get());
     DCHECK(window.contentView);
 
     [[NSNotificationCenter defaultCenter]
         addObserver:self
            selector:@selector(windowWillClose:)
                name:NSWindowWillCloseNotification
              object:self.window];
   }
   return self;
 }
@@ skipping 73 matching lines @@
 void UserManagerMac::OnGuestProfileCreated(Profile* guest_profile,
                                            const std::string& url) {
   instance_ = new UserManagerMac(guest_profile);
   [instance_->window_controller_ showURL:GURL(url)];
 }
 
 void UserManagerMac::WindowWasClosed() {
   instance_ = NULL;
   delete this;
 }