[Android][gn] Add android resources templates

build/config/android/internal_rules.gni

 import("config.gni")
 
+assert(is_android)
+
+
+rebased_android_sdk = rebase_path(android_sdk, root_build_dir)
+rebased_android_sdk_root = rebase_path(android_sdk_root, root_build_dir)
+rebased_android_sdk_build_tools = rebase_path(android_sdk_build_tools, root_build_dir)
+
+
 template("write_build_config") {
   assert(defined(invoker.type))
   assert(defined(invoker.base_path))
 
   base_path = invoker.base_path
   type = invoker.type
   build_config = base_path + ".build_config"
 
-  assert(type == "android_library" || type == "android_binary")
+  assert(type == "android_binary" || type == "android_library" || type == "android_resources")
 
   action(target_name) {
     script = "//build/android/gyp/write_build_config.py"
     depfile = "$target_gen_dir/$target_name.d"
 
     deps = []
     if (defined(invoker.deps)) {
       deps += invoker.deps
     }
 
@@ skipping 10 matching lines @@
       "--possible-deps-configs=$rebase_possible_deps_configs",
       "--build-config", rebase_path(build_config, root_build_dir),
     ]
 
     if (type == "android_library") {
       jar_path = base_path + ".jar"
       args += [
         "--jar-path", rebase_path(jar_path, root_build_dir),
       ]
     }
+
+    if (type == "android_resources") {
+      assert(defined(invoker.resources_zip))
+      args += [
+        "--resources-zip", rebase_path(invoker.resources_zip, root_build_dir),
+      ]
+      if (defined(invoker.srcjar)) {
+        args += [
+          "--srcjar", rebase_path(invoker.srcjar, root_build_dir)
+        ]
+      }
+    }
   }
 }
 
+
 # Creates a zip archive of the inputs.
 # If base_dir is provided, the archive paths will be relative to it.
 template("zip") {
   assert(defined(invoker.inputs))
   assert(defined(invoker.output))
 
   rebase_inputs = rebase_path(invoker.inputs, root_build_dir)
   rebase_output = rebase_path(invoker.output, root_build_dir)
   action(target_name) {
     script = "//build/android/gn/zip.py"
     depfile = "$target_gen_dir/$target_name.d"
     source_prereqs = invoker.inputs
     outputs = [depfile, invoker.output]
     args = [
       "--depfile", rebase_path(depfile, root_build_dir),
       "--inputs=$rebase_inputs",
       "--output=$rebase_output",
     ]
     if (defined(invoker.base_dir)) {
       args += [
         "--base-dir", rebase_path(invoker.base_dir, root_build_dir)
       ]
     }
   }
 }
 
-# Compiles and jars a set of java_files.
+
+# Compiles and jars a set of java files.
 #
 # Outputs:
 #  $jar_path.jar
 #  $jar_path.jar.TOC
 #
 # Variables
 #   java_files: List of .java files to compile.
 #   java_deps: List of java dependencies. These should all have a .jar output
 #     at "${target_gen_dir}/${target_name}.jar.
 #   chromium_code: If 1, enable extra warnings.
@@ skipping 53 matching lines @@
     rebase_system_jars = rebase_path(system_jars, root_build_dir)
     rebase_java_srcjars = rebase_path(java_srcjars, root_build_dir)
     rebase_build_config = rebase_path(build_config, root_build_dir)
     rebase_depfile = rebase_path(depfile, root_build_dir)
     args = [
       "--depfile=$rebase_depfile",
       "--classpath=$rebase_system_jars",
       "--classpath=@($rebase_build_config:javac:classpath)",
       "--jar-path=$rebase_jar_path",
       "--java-srcjars=$rebase_java_srcjars",
+      "--java-srcjars=@($rebase_build_config:javac:srcjars)",
       "--jar-excluded-classes=$jar_excluded_patterns",
     ]
     if (chromium_code) {
       args += ["--chromium-code"]
     }
 
     args += rebase_path(java_files, root_build_dir)
   }
 
   # TODO(cjhopman): proguard
@@ skipping 12 matching lines @@
   }
 
   group(target_name) {
     deps = [
       ":${target_name}__javac",
       ":${target_name}__jar_toc",
     ]
   }
 }
 
+
 # This adds Android-specific parts to the java_library template.
 #
 # Runs Android lint against the compiled java files.
 # Dexes the output jar for inclusion in an APK.
 template("android_java_library") {
   assert(defined(invoker.java_files))
 
   assert(defined(invoker.build_config))
   assert(defined(invoker.jar_path))
 
@@ skipping 12 matching lines @@
 
   # TODO(cjhopman): lint
   # TODO(cjhopman): dex
 
   group(target_name) {
     deps = [
       ":${target_name}__java_library"
     ]
   }
 }
+
+
+# Runs process_resources.py
+template("process_resources") {
+  zip_path = invoker.zip_path
+  srcjar_path = invoker.srcjar_path
+  build_config = invoker.build_config
+  resource_dirs = invoker.resource_dirs
+  android_manifest = invoker.android_manifest
+
+  action(target_name) {
+    script = "//build/android/gyp/process_resources.py"
+
+    depfile = "$target_gen_dir/$target_name.d"
+    outputs = [
+      depfile,
+      zip_path,
+      srcjar_path,
+    ]
+
+    sources_build_rel = exec_script(
+        "//build/android/gyp/find.py",
+        rebase_path(resource_dirs, root_build_dir),
+        "list lines"
+        )
+    sources = rebase_path(sources_build_rel, ".", root_build_dir)
+
+    source_prereqs = [
+      build_config,
+      android_manifest,
+    ]
+
+    rebase_resource_dirs = rebase_path(resource_dirs, root_build_dir)
+    rebase_build_config = rebase_path(build_config, root_build_dir)
+    args = [
+      "--depfile", rebase_path(depfile, root_build_dir),
+      "--android-sdk", rebase_path(android_sdk, root_build_dir),
+      "--android-sdk-tools", rebase_path(android_sdk_build_tools, root_build_dir),
+      "--non-constant-id",
+      "--android-manifest", rebase_path(android_manifest, root_build_dir),
+
+      "--resource-dirs=$rebase_resource_dirs",
+      "--srcjar-out", rebase_path(srcjar_path, root_build_dir),
+      "--resource-zip-out", rebase_path(zip_path, root_build_dir),
+
+      "--dependencies-res-zips=@($rebase_build_config:resources:dependency_zips)",
+    ]
+
+    if (defined(invoker.custom_package)) {
+      args += [
+        "--custom-package", invoker.custom_package,
+      ]
+    }
+
+    if (defined(invoker.v14_verify_only) && invoker.v14_verify_only) {
+      args += ["--v14-verify-only"]
+    }
+  }
+}