MacViews: Implement Set/Get*Bounds for NativeWidgetMac

ui/views/widget/native_widget_mac.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "ui/views/widget/native_widget_mac.h"
 
 #import <Cocoa/Cocoa.h>
 
 #include "base/mac/foundation_util.h"
 #include "base/mac/scoped_nsobject.h"
 #include "ui/gfx/font_list.h"
+#include "ui/gfx/mac/point_utils.h"
 #include "ui/native_theme/native_theme.h"
 #import "ui/views/cocoa/bridged_content_view.h"
 #import "ui/views/cocoa/bridged_native_widget.h"
 #import "ui/views/cocoa/views_nswindow_delegate.h"
 
 namespace views {
+namespace {
+
+NSInteger StyleMaskForParams(const Widget::InitParams& params) {
+  // TODO(tapted): Determine better masks when there are use cases for it.
+  if (params.type == Widget::InitParams::TYPE_WINDOW) {
+    return NSTitledWindowMask | NSClosableWindowMask |
+           NSMiniaturizableWindowMask | NSResizableWindowMask;
+  }
+  return NSBorderlessWindowMask;
+}
+
+NSRect ValidateContentRect(NSRect content_rect) {
+  // A contentRect with zero width or height is a banned practice in Chrome, due
+  // to unpredictable OSX treatment. For now, silently give a minimum dimension.
+  // TODO(tapted): Add a DCHECK, or add emulation logic (e.g. to auto-hide).
+  if (NSWidth(content_rect) == 0)
+    content_rect.size.width = 1;
+
+  if (NSHeight(content_rect) == 0)
+    content_rect.size.height = 1;
+
+  return content_rect;
+}
+
+}  // namespace
 
 ////////////////////////////////////////////////////////////////////////////////
 // NativeWidgetMac, public:
 
 NativeWidgetMac::NativeWidgetMac(internal::NativeWidgetDelegate* delegate)
     : delegate_(delegate),
       bridge_(new BridgedNativeWidget(this)),
       ownership_(Widget::InitParams::NATIVE_WIDGET_OWNS_WIDGET) {
 }
 
@@ skipping 13 matching lines @@
   if (ownership_ == Widget::InitParams::NATIVE_WIDGET_OWNS_WIDGET)
     delete this;
 }
 
 ////////////////////////////////////////////////////////////////////////////////
 // NativeWidgetMac, internal::NativeWidgetPrivate implementation:
 
 void NativeWidgetMac::InitNativeWidget(const Widget::InitParams& params) {
   ownership_ = params.ownership;
 
-  // TODO(tapted): Convert position into Cocoa's flipped coordinate space.
-  NSRect content_rect =
-      NSMakeRect(0, 0, params.bounds.width(), params.bounds.height());
-  // TODO(tapted): Determine a good initial style mask from |params|.
-  NSInteger style_mask = NSTitledWindowMask | NSClosableWindowMask |
-                         NSMiniaturizableWindowMask | NSResizableWindowMask;
+  NSInteger style_mask = StyleMaskForParams(params);
+  NSRect content_rect = ValidateContentRect(
+      [NSWindow contentRectForFrameRect:gfx::ScreenRectToNSRect(params.bounds)
+                              styleMask:style_mask]);
+
   base::scoped_nsobject<NSWindow> window(
       [[NSWindow alloc] initWithContentRect:content_rect
                                   styleMask:style_mask
                                     backing:NSBackingStoreBuffered
                                       defer:NO]);
   [window setReleasedWhenClosed:NO];  // Owned by scoped_nsobject.
   bridge_->Init(window, params);
 
   delegate_->OnNativeWidgetCreated(true);
 }
@@ skipping 117 matching lines @@
 void NativeWidgetMac::SetWindowIcons(const gfx::ImageSkia& window_icon,
                                      const gfx::ImageSkia& app_icon) {
   NOTIMPLEMENTED();
 }
 
 void NativeWidgetMac::InitModalType(ui::ModalType modal_type) {
   NOTIMPLEMENTED();
 }
 
 gfx::Rect NativeWidgetMac::GetWindowBoundsInScreen() const {
-  NOTIMPLEMENTED();
-  return gfx::Rect();
+  return gfx::ScreenRectFromNSRect([GetNativeWindow() frame]);
 }
 
 gfx::Rect NativeWidgetMac::GetClientAreaBoundsInScreen() const {
-  NOTIMPLEMENTED();
-  return gfx::Rect();
+  NSWindow* window = GetNativeWindow();
+  return gfx::ScreenRectFromNSRect(
+      [window contentRectForFrameRect:[window frame]]);
 }
 
 gfx::Rect NativeWidgetMac::GetRestoredBounds() const {
   NOTIMPLEMENTED();
   return gfx::Rect();
 }
 
 void NativeWidgetMac::SetBounds(const gfx::Rect& bounds) {
-  NOTIMPLEMENTED();
+  [GetNativeWindow() setFrame:gfx::ScreenRectToNSRect(bounds)
+                      display:YES
+                      animate:NO];
 }
 
 void NativeWidgetMac::SetSize(const gfx::Size& size) {
-  [GetNativeWindow() setContentSize:NSMakeSize(size.width(), size.height())];
+  NSWindow* window = GetNativeWindow();
+  NSRect frame_rect = NSMakeRect(0, 0, size.width(), size.height());
+  NSRect content_rect = [window contentRectForFrameRect:frame_rect];

[Andre, 2014/06/25 17:59:51]

Isn't this supposed to set the window's frame instead of the content view's
frame?

[tapted, 2014/06/26 08:44:32]

This part of it was OK -- there's no -[NSWindow setFrameSize] -- just
setContentSize, so I was converting it to use the available NSWindow "resize"
function. But!: turns out that function is no good anyway. To be consistent with
views we need to keep the top-left corner of a window in the same place when
resizing. But setContentSize will keep the bottom-left corner in the same place,
so it's not what we want.

So, I've gone with my suggestion from an earlier comment, below, and added more
checks in the test to ensure the gfx::Bounds() origin doesn't move when
resizing. Also a comment here about it.

+  [window setContentSize:content_rect.size];
 }

[tapted, 2014/06/25 10:55:56]

Not sure if calling -[NSWindow setContenSize:] is preferable to just

  SetBounds(gfx::Rect(GetWindowBoundsInScreen().origin(), size));

that alternative would result in more coordinate flipping, but it's "less" code
and might dovetail into an animated resize if we ever want that.

 
 void NativeWidgetMac::StackAbove(gfx::NativeView native_view) {
   NOTIMPLEMENTED();
 }
 
 void NativeWidgetMac::StackAtTop() {
   NOTIMPLEMENTED();
 }
 
 void NativeWidgetMac::StackBelow(gfx::NativeView native_view) {
   NOTIMPLEMENTED();
 }
 
 void NativeWidgetMac::SetShape(gfx::NativeRegion shape) {
   NOTIMPLEMENTED();
 }
 
 void NativeWidgetMac::Close() {
-  // Calling performClose: will momentarily highlight the close button.
-  [GetNativeWindow() performSelector:@selector(performClose:)
-                          withObject:nil
-                          afterDelay:0];
+  NSWindow* window = GetNativeWindow();
+  // Calling performClose: will momentarily highlight the close button, but
+  // AppKit will reject it if there is no close button.
+  SEL close_selector = ([window styleMask] & NSClosableWindowMask)
+                           ? @selector(performClose:)
+                           : @selector(close);
+  [window performSelector:close_selector withObject:nil afterDelay:0];
 }
 
 void NativeWidgetMac::CloseNow() {
   // Reset |bridge_| to NULL before destroying it.
   scoped_ptr<BridgedNativeWidget> bridge(bridge_.Pass());
 }
 
 void NativeWidgetMac::Show() {
   NOTIMPLEMENTED();
 }
@@ skipping 239 matching lines @@
 }
 
 // static
 gfx::FontList NativeWidgetPrivate::GetWindowTitleFontList() {
   NOTIMPLEMENTED();
   return gfx::FontList();
 }
 
 }  // namespace internal
 }  // namespace views