Be explicit about target type in platform_util::OpenItem()

chrome/browser/platform_util_mac.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/browser/platform_util.h"
 
 #include <Carbon/Carbon.h>
 #import <Cocoa/Cocoa.h>
 #include <CoreServices/CoreServices.h>
 
+#include "base/bind.h"
+#include "base/files/file_util.h"
 #include "base/files/file_path.h"
 #include "base/logging.h"
 #include "base/mac/mac_logging.h"
 #import "base/mac/mac_util.h"
 #import "base/mac/sdk_forward_declarations.h"
 #include "base/mac/scoped_aedesc.h"
 #include "base/strings/sys_string_conversions.h"
+#include "chrome/browser/platform_util_internal.h"
+#include "content/public/browser/browser_thread.h"
 #include "url/gurl.h"
 
 namespace platform_util {
 
 void ShowItemInFolder(Profile* profile, const base::FilePath& full_path) {
   DCHECK([NSThread isMainThread]);
   NSString* path_string = base::SysUTF8ToNSString(full_path.value());
   if (!path_string || ![[NSWorkspace sharedWorkspace] selectFile:path_string
                                         inFileViewerRootedAtPath:nil])
     LOG(WARNING) << "NSWorkspace failed to select file " << full_path.value();
 }
 
-void OpenItem(Profile* profile, const base::FilePath& full_path) {
+// This function opens a file.  This doesn't use LaunchServices or NSWorkspace

[Robert Sesek, 2015/02/05 00:52:29]

This comment isn't accurate anymore (c.f. lines 47-50), so you can remove it. (I
think it was a holdover from before I made the change below).

[asanka, 2015/02/05 18:07:25]

Comment removed.

+// because of two bugs:
+//  1. Incorrect app activation with com.apple.quarantine:
+//     http://crbug.com/32921
+//  2. Silent no-op for unassociated file types: http://crbug.com/50263
+// Instead, an AppleEvent is constructed to tell the Finder to open the
+// document.
+void OpenFileOnMainThread(const base::FilePath& full_path) {
   DCHECK([NSThread isMainThread]);
   NSString* path_string = base::SysUTF8ToNSString(full_path.value());
   if (!path_string)
     return;
 
   // On Mavericks or later, NSWorkspaceLaunchWithErrorPresentation will
   // properly handle Finder activation for quarantined files
   // (http://crbug.com/32921) and unassociated file types
   // (http://crbug.com/50263).
   if (base::mac::IsOSMavericksOrLater()) {
@@ skipping 16 matching lines @@
   // instruct the Finder to open the file.
 
   // Create the target of this AppleEvent, the Finder.
   base::mac::ScopedAEDesc<AEAddressDesc> address;
   const OSType finderCreatorCode = 'MACS';
   OSErr status = AECreateDesc(typeApplSignature,  // type
                               &finderCreatorCode,  // data
                               sizeof(finderCreatorCode),  // dataSize
                               address.OutPointer());  // result
   if (status != noErr) {
-    OSSTATUS_LOG(WARNING, status) << "Could not create OpenItem() AE target";
+    OSSTATUS_LOG(WARNING, status) << "Could not create OpenFile() AE target";
     return;
   }
 
   // Build the AppleEvent data structure that instructs Finder to open files.
   base::mac::ScopedAEDesc<AppleEvent> theEvent;
   status = AECreateAppleEvent(kCoreEventClass,  // theAEEventClass
                               kAEOpenDocuments,  // theAEEventID
                               address,  // target
                               kAutoGenerateReturnID,  // returnID
                               kAnyTransactionID,  // transactionID
                               theEvent.OutPointer());  // result
   if (status != noErr) {
-    OSSTATUS_LOG(WARNING, status) << "Could not create OpenItem() AE event";
+    OSSTATUS_LOG(WARNING, status) << "Could not create OpenFile() AE event";
     return;
   }
 
   // Create the list of files (only ever one) to open.
   base::mac::ScopedAEDesc<AEDescList> fileList;
   status = AECreateList(NULL,  // factoringPtr
                         0,  // factoredSize
                         false,  // isRecord
                         fileList.OutPointer());  // resultList
   if (status != noErr) {
-    OSSTATUS_LOG(WARNING, status) << "Could not create OpenItem() AE file list";
+    OSSTATUS_LOG(WARNING, status) << "Could not create OpenFile() AE file list";
     return;
   }
 
   // Add the single path to the file list.  C-style cast to avoid both a
   // static_cast and a const_cast to get across the toll-free bridge.
   CFURLRef pathURLRef = (CFURLRef)[NSURL fileURLWithPath:path_string];
   FSRef pathRef;
   if (CFURLGetFSRef(pathURLRef, &pathRef)) {
     status = AEPutPtr(fileList.OutPointer(),  // theAEDescList
                       0,  // index
                       typeFSRef,  // typeCode
                       &pathRef,  // dataPtr
                       sizeof(pathRef));  // dataSize
     if (status != noErr) {
       OSSTATUS_LOG(WARNING, status)
-          << "Could not add file path to AE list in OpenItem()";
+          << "Could not add file path to AE list in OpenFile()";
       return;
     }
   } else {
-    LOG(WARNING) << "Could not get FSRef for path URL in OpenItem()";
+    LOG(WARNING) << "Could not get FSRef for path URL in OpenFile()";
     return;
   }
 
   // Attach the file list to the AppleEvent.
   status = AEPutParamDesc(theEvent.OutPointer(),  // theAppleEvent
                           keyDirectObject,  // theAEKeyword
                           fileList);  // theAEDesc
   if (status != noErr) {
     OSSTATUS_LOG(WARNING, status)
-        << "Could not put the AE file list the path in OpenItem()";
+        << "Could not put the AE file list the path in OpenFile()";
     return;
   }
 
   // Send the actual event.  Do not care about the reply.
   base::mac::ScopedAEDesc<AppleEvent> reply;
   status = AESend(theEvent,  // theAppleEvent
                   reply.OutPointer(),  // reply
                   kAENoReply + kAEAlwaysInteract,  // sendMode
                   kAENormalPriority,  // sendPriority
                   kAEDefaultTimeout,  // timeOutInTicks
                   NULL, // idleProc
                   NULL);  // filterProc
   if (status != noErr) {
     OSSTATUS_LOG(WARNING, status)
-        << "Could not send AE to Finder in OpenItem()";
+        << "Could not send AE to Finder in OpenFile()";
   }
 }
 
+namespace internal {
+
+void PlatformOpenVerifiedItem(const base::FilePath& path, OpenItemType type) {
+  switch (type) {
+    case OPEN_FILE:
+      content::BrowserThread::PostTask(content::BrowserThread::UI, FROM_HERE,
+                                       base::Bind(&OpenFileOnMainThread, path));
+      return;
+    case OPEN_FOLDER:
+      NSString* path_string = base::SysUTF8ToNSString(path.value());
+      if (!path_string)
+        return;
+      [[NSWorkspace sharedWorkspace] openFile:path_string

[Robert Sesek, 2015/02/05 00:52:29]

Does:

  NSURL* url = [NSURL fileURLWithPath:path_string];
  [[NSWorkspace sharedWorkspace] activateFileViewerSelectingURLs:
      @[ url ]];

work? Users can technically have Finder alternatives installed.

[asanka, 2015/02/05 18:07:25]

I tried this, but it doesn't have the intended effect. This causes the
containing folder to the opened in Finder with the target folder item selected.
Using "/target/path/." also doesn't help.

By the way is this method considered canonical for opening a finder and
selecting an item? I can update ShowItemInFolder() above while I'm here since
the behavior matches what's expected there.

[Robert Sesek, 2015/02/05 23:37:55]

I think the only difference between this method and the current implementation
is selecting a single vs. multiple files, and based on URL vs file path.
Otherwise, I think they're equivalent.

For here, though, if you remove the withApplication:@"Finder" does this still
work as expected? Specifically, has |path| been validated to be a directory, or
is Finder explicitly being called out here to handle that?

+                              withApplication:@"Finder"];
+      return;
+  }
+}
+}

[Robert Sesek, 2015/02/05 00:52:29]

nit: blank line before, and "  // namespace internal"

[asanka, 2015/02/05 18:07:25]

Done.

+
 void OpenExternal(Profile* profile, const GURL& url) {
   DCHECK([NSThread isMainThread]);
   NSString* url_string = base::SysUTF8ToNSString(url.spec());
   NSURL* ns_url = [NSURL URLWithString:url_string];
   if (!ns_url || ![[NSWorkspace sharedWorkspace] openURL:ns_url])
     LOG(WARNING) << "NSWorkspace failed to open URL " << url;
 }
 
 gfx::NativeWindow GetTopLevel(gfx::NativeView view) {
   return [view window];
@@ skipping 25 matching lines @@
           [[view window] isVisible]);
 }
 
 bool IsSwipeTrackingFromScrollEventsEnabled() {
   SEL selector = @selector(isSwipeTrackingFromScrollEventsEnabled);
   return [NSEvent respondsToSelector:selector]
       && [NSEvent performSelector:selector];
 }
 
 }  // namespace platform_util