GN: blink_platform test targets

Source/platform/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/ui.gni")
 import("//third_party/WebKit/Source/build/scripts/scripts.gni")
 import("//third_party/WebKit/Source/config.gni")
 
 platform_gypi = exec_script(
     "//build/gypi_to_gn.py",
     [ rebase_path("blink_platform.gypi") ],
     "scope",
     [ "blink_platform.gypi" ])
+heap_gypi = exec_script(
+    "//build/gypi_to_gn.py",
+    [ rebase_path("heap/blink_heap.gypi") ],
+    "scope",
+    [ "blink_heap.gypi" ])

[brettw, 2014/06/04 05:01:15]

This should match the other one (so "heap/blink_heap.gypi"). This tells GN to
add a dependency on this file for rebuilding the ninja files.

[jamesr, 2014/06/04 05:27:00]

oooh, that's what that line does. fixed

 blink_platform_neon_files = [
   "graphics/cpu/arm/WebGLImageConversionNEON.h",
   "graphics/cpu/arm/filters/FEBlendNEON.h",
   "graphics/cpu/arm/filters/FECompositeArithmeticNEON.h",
   "graphics/cpu/arm/filters/FEGaussianBlurNEON.h",
   "graphics/cpu/arm/filters/FELightingNEON.h",
   "graphics/cpu/arm/filters/NEONHelpers.h",
 ]
 
 # blink_common in blink_platform.gyp
@@ skipping 301 matching lines @@
     # TODO(GYP)
     #deps += [ "//third_party/ffmpeg" ]
   }
   if (use_openmax_dl_fft) {
     include_dirs += [ "//third_party/openmax_dl" ]
     # TODO(GYP)
     # deps += [ "//third_party/openmax_dl/dl" ]
   }
 }
 
+source_set("heap_run_all_tests") {
+  sources = [
+    "heap/RunAllTests.cpp"
+  ]
+
+  configs += [
+    "//third_party/WebKit/Source/wtf:wtf_config",
+    "//third_party/WebKit/Source:config",
+    "//third_party/WebKit/Source:non_test_config",
+  ]
+
+  deps = [
+    "//base/test:test_support",
+    "//testing/gmock",
+    "//testing/gtest",
+    "//third_party/WebKit/Source/wtf",
+  ]
+}
+
+test("heap_unittests") {
+  output_name = "blink_heap_unittests"
+
+  sources = rebase_path(heap_gypi.platform_heap_test_files, ".", "heap")
+
+  configs += [
+    "//third_party/WebKit/Source:config",
+  ]
+
+  deps = [
+    ":platform",
+    ":heap_run_all_tests",
+    "//third_party/WebKit/Source/wtf",

[brettw, 2014/06/04 05:01:15]

Can you alphabetize these (colon ones at the top).

[jamesr, 2014/06/04 05:27:00]

Done.

+    "//third_party/WebKit/Source/wtf:unittest_helpers",
+    "//base",
+    "//base/allocator",
+    "//testing/gmock",
+    "//testing/gtest",
+  ]
+}
+
+source_set("platform_run_all_tests") {
+  sources = [
+    "testing/RunAllTests.cpp"
+  ]
+
+  configs += [
+    "//third_party/WebKit/Source/wtf:wtf_config",
+    "//third_party/WebKit/Source:config",
+    "//third_party/WebKit/Source:non_test_config",
+  ]
+
+  deps = [
+    "//base/test:test_support",
+    "//testing/gmock",
+    "//testing/gtest",
+    "//third_party/WebKit/Source/wtf",
+  ]
+}
+
+test("platform_unittests") {
+  output_name = "blink_platform_unittests"
+
+  sources = platform_gypi.platform_test_files
+
+  configs += [
+    "//third_party/WebKit/Source:config",
+  ]
+
+  deps = [
+    "//base",
+    "//base/allocator",
+    "//skia",
+    "//testing/gmock",
+    "//testing/gtest",
+    "//third_party/WebKit/Source/wtf",
+    "//third_party/WebKit/Source/wtf:unittest_helpers",
+    "//url",
+    ":blink_common",

[brettw, 2014/06/04 05:01:15]

Can you put the colon ones at the top?

[jamesr, 2014/06/04 05:27:00]

Done.

+    ":heap_run_all_tests",
+    ":platform",
+  ]
+
+  defines = [
+    "INSIDE_BLINK",
+  ]
+
+  include_dirs = [
+    "$root_gen_dir/blink",
+  ]
+}
+
+
 if (cpu_arch == "arm") {
   source_set("blink_arm_neon") {
     sources = blink_platform_neon_files
 
     # The *NEON.cpp files fail to compile when -mthumb is passed. Force
     # them to build in ARM mode.
     # See https://bugs.webkit.org/show_bug.cgi?id=62916.
     # TODO(GYP)
     #'cflags': ['-marm'],
     #    'conditions': [
     #      ['OS=="android"', {
     #        'cflags!': ['-mthumb'],
     #      }],
     #    ],
 
     deps = [ ":blink_common" ]
   }
 }
 
 # This config is a placeholder to set up the V8 include path while the V8 GN
 # build is being worked on.
 config("v8_stub_config") {
   include_dirs = [ "//v8/include" ]
 }