[Mac] Password generation: Make "saved passwords" a hyperlink.

chrome/browser/ui/cocoa/autofill/password_generation_popup_view_cocoa.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/autofill/password_generation_popup_view_cocoa.h"
 
 #include "base/logging.h"
 #include "base/strings/sys_string_conversions.h"
 #include "chrome/browser/ui/autofill/autofill_popup_controller.h"
 #include "chrome/browser/ui/autofill/autofill_popup_view.h"
 #include "chrome/browser/ui/autofill/popup_constants.h"
 #include "chrome/browser/ui/cocoa/autofill/password_generation_popup_view_bridge.h"
+#import "chrome/browser/ui/cocoa/hyperlink_text_view.h"
 #import "chrome/browser/ui/cocoa/l10n_util.h"
 #include "components/autofill/core/browser/popup_item_ids.h"
 #include "grit/ui_resources.h"
 #include "skia/ext/skia_utils_mac.h"
 #include "ui/base/resource/resource_bundle.h"
 #include "ui/gfx/font_list.h"
 #include "ui/gfx/image/image.h"
 #include "ui/gfx/point.h"
+#include "ui/gfx/range/range.h"
 #include "ui/gfx/rect.h"
 #include "ui/gfx/text_constants.h"
 
 using autofill::AutofillPopupView;
 using autofill::PasswordGenerationPopupView;
 using base::scoped_nsobject;
 
 namespace {
 
 NSColor* DividerColor() {
@@ skipping 20 matching lines @@
 - (id)initWithFrame:(NSRect)frame {
   NOTREACHED();
   return nil;
 }
 
 - (id)initWithController:
     (autofill::PasswordGenerationPopupController*)controller
                    frame:(NSRect)frame {
   if (self = [super initWithDelegate:controller frame:frame]) {
     controller_ = controller;
-    NSFont* font = controller_->font_list().GetPrimaryFont().GetNativeFont();
 
-    passwordField_ = [self textFieldWithText:controller_->password()
-                                    withFont:font
-                                       color:[self nameColor]
-                                   alignment:NSLeftTextAlignment];
-    [self addSubview:passwordField_];
+    passwordView_ = [self textViewWithText:controller_->password()

[groby-ooo-7-16, 2014/05/30 18:05:01]

I'm not clear why you're switching the password field to NSTextView? Why not
just change positionTextView:inRect: to take an NSView instead? (And call it
positionView:inRect)

[Patrick Dubroy, 2014/06/02 07:46:52]

It's not really necessary, I just thought NSTextView was slightly more
appropriate than NSTextField, and that future changes might be simpler if they
were all NSTextViews. But, I've reverted these changes.

+                                     color:[self nameColor]
+                                 alignment:NSLeftTextAlignment];
+    [self addSubview:passwordView_];
 
-    passwordSubtextField_ =
-        [self textFieldWithText:controller_->SuggestedText()
-                       withFont:font
-                          color:[self subtextColor]
-                      alignment:NSRightTextAlignment];
-    [self addSubview:passwordSubtextField_];
+    passwordSubtextView_ = [self textViewWithText:controller_->SuggestedText()
+                                            color:[self subtextColor]
+                                        alignment:NSRightTextAlignment];
+    [self addSubview:passwordSubtextView_];
 
-    helpTextField_ = [self textFieldWithText:controller_->HelpText()
-                                    withFont:font
-                                       color:HelpTextColor()
-                                   alignment:NSLeftTextAlignment];
-    [self addSubview:helpTextField_];
+    helpTextView_ =

[groby-ooo-7-16, 2014/05/30 18:05:01]

IIRC, we prefer scoped_nsobject over autoreleased objects.

[Patrick Dubroy, 2014/06/02 07:46:52]

Done. Though I'm not sure whether you meant that I should create a
scoped_nsobject as a local, or rather make the member a scoped_nsobject.

+        [[[HyperlinkTextView alloc] initWithFrame:NSZeroRect] autorelease];
+    [helpTextView_ setMessage:base::SysUTF16ToNSString(controller_->HelpText())
+                     withFont:[self textFont]
+                 messageColor:HelpTextColor()];
+    [helpTextView_ addLinkRange:controller_->HelpTextLinkRange().ToNSRange()
+                       withName:@""
+                      linkColor:[NSColor blueColor]];
+    [helpTextView_ setDelegate:self];
+    [[helpTextView_ textContainer] setLineFragmentPadding:0.0f];
+    [helpTextView_ setVerticallyResizable:YES];
+    [self addSubview:helpTextView_];
   }
 
   return self;
 }
 
 #pragma mark NSView implementation:
 
 - (void)drawRect:(NSRect)dirtyRect {
   // If the view is in the process of being destroyed, don't bother drawing.
   if (!controller_)
@@ skipping 17 matching lines @@
   [NSBezierPath fillRect:[self helpBounds]];
 
   // Render the divider.
   [DividerColor() set];
   [NSBezierPath fillRect:[self dividerBounds]];
 }
 
 #pragma mark Public API:
 
 - (void)updateBoundsAndRedrawPopup {
-  [self positionTextField:passwordField_ inRect:[self passwordBounds]];
-  [self positionTextField:passwordSubtextField_ inRect:[self passwordBounds]];
-  [self positionTextField:helpTextField_ inRect:[self helpBounds]];
+  [self positionTextView:passwordView_ inRect:[self passwordBounds]];
+  [self positionTextView:passwordSubtextView_ inRect:[self passwordBounds]];
+  [self positionTextView:helpTextView_ inRect:[self helpBounds]];
 
   [super updateBoundsAndRedrawPopup];
 }
 
 - (void)controllerDestroyed {
   controller_ = NULL;
   [super delegateDestroyed];
 }
 
+#pragma mark NSTextViewDelegate implementation:
+
+- (BOOL)textView:(NSTextView *)textView
+   clickedOnLink:(id)link
+         atIndex:(NSUInteger)charIndex {
+  controller_->OnSavedPasswordsLinkClicked();
+  return YES;
+}
+
 #pragma mark Private helpers:
 
-- (NSTextField*)textFieldWithText:(const base::string16&)text
-                         withFont:(NSFont*)font
-                            color:(NSColor*)color
-                        alignment:(NSTextAlignment)alignment {
+- (NSTextView*)textViewWithText:(const base::string16&)text
+                          color:(NSColor*)color
+                      alignment:(NSTextAlignment)alignment {
   scoped_nsobject<NSMutableParagraphStyle> paragraphStyle(
       [[NSMutableParagraphStyle alloc] init]);
   [paragraphStyle setAlignment:alignment];
 
   NSDictionary* textAttributes = @{
-    NSFontAttributeName : font,
+    NSFontAttributeName : [self textFont],
     NSForegroundColorAttributeName : color,
     NSParagraphStyleAttributeName : paragraphStyle
   };
 
   scoped_nsobject<NSAttributedString> attributedString(
       [[NSAttributedString alloc]
           initWithString:base::SysUTF16ToNSString(text)
               attributes:textAttributes]);
 
-  NSTextField* textField =
-      [[[NSTextField alloc] initWithFrame:NSZeroRect] autorelease];
-  [textField setAttributedStringValue:attributedString];
-  [textField setEditable:NO];
-  [textField setSelectable:NO];
-  [textField setDrawsBackground:NO];
-  [textField setBezeled:NO];
-
-  return textField;
+  NSTextView* textView =
+      [[[NSTextView alloc] initWithFrame:NSZeroRect] autorelease];
+  [[textView textStorage] setAttributedString:attributedString];
+  [[textView textContainer] setLineFragmentPadding:0.0f];
+  [textView setSelectable:NO];
+  [textView setDrawsBackground:NO];
+  return textView;
 }
 
-- (void)positionTextField:(NSTextField*)textField inRect:(NSRect)bounds {
+- (void)positionTextView:(NSTextView*)textView inRect:(NSRect)bounds {
   NSRect frame = NSInsetRect(bounds, controller_->kHorizontalPadding, 0);
-  [textField setFrame:frame];
+  [textView setFrame:frame];
 
   // Center the text vertically within the bounds.
-  NSSize delta = cocoa_l10n_util::WrapOrSizeToFit(textField);
-  [textField setFrameOrigin:
+  NSSize delta = cocoa_l10n_util::WrapOrSizeToFit(textView);
+  [textView setFrameOrigin:
       NSInsetRect(frame, 0, floor(-delta.height/2)).origin];
 }
 
 - (NSRect)passwordBounds {
   return NSRectFromCGRect(controller_->password_bounds().ToCGRect());
 }
 
 - (NSRect)helpBounds {
   return NSRectFromCGRect(controller_->help_bounds().ToCGRect());
 }
 
 - (NSRect)dividerBounds {
   return NSRectFromCGRect(controller_->divider_bounds().ToCGRect());
 }
 
+- (NSFont*)textFont {
+  return controller_->font_list().GetPrimaryFont().GetNativeFont();
+}
+
 @end