[ObjC ARC] Converts ios/chrome/browser/ui/ntp:ntp_internal to ARC.

ios/chrome/browser/ui/ntp/google_landing_view_controller.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/ntp/google_landing_view_controller.h"
 
 #include <algorithm>
 
 #include "base/mac/foundation_util.h"
 #include "base/metrics/user_metrics.h"
@@ skipping 17 matching lines @@
 #import "ios/chrome/browser/ui/url_loader.h"
 #include "ios/chrome/common/string_util.h"
 #include "ios/chrome/grit/ios_strings.h"
 #import "ios/third_party/material_components_ios/src/components/Snackbar/src/MaterialSnackbar.h"
 #import "ios/third_party/material_components_ios/src/components/Typography/src/MaterialTypography.h"
 #import "ios/web/public/web_state/context_menu_params.h"
 #import "net/base/mac/url_conversions.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "ui/base/page_transition_types.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 using base::UserMetricsAction;
 
 namespace {
 
 enum {
   SectionWithOmnibox,
   SectionWithMostVisited,
   NumberOfCollectionViewSections,
 };
 
 const UIEdgeInsets kSearchBoxStretchInsets = {3, 3, 3, 3};
 
 const CGFloat kHintLabelSidePadding = 12;
 const CGFloat kWhatsNewHeaderHiddenHeight = 8;
 const NSInteger kMaxNumMostVisitedFaviconRows = 2;
 const CGFloat kShiftTilesDownAnimationDuration = 0.2;
 
 }  // namespace
 
 @interface GoogleLandingViewController ()<OverscrollActionsControllerDelegate,
                                           UICollectionViewDataSource,
                                           UICollectionViewDelegate,
                                           UICollectionViewDelegateFlowLayout,
                                           UIGestureRecognizerDelegate,
                                           WhatsNewHeaderViewDelegate> {
   // Fake omnibox.
-  base::scoped_nsobject<UIButton> _searchTapTarget;
+  UIButton* _searchTapTarget;
 
   // A collection view for the most visited sites.
-  base::scoped_nsobject<UICollectionView> _mostVisitedView;
+  UICollectionView* _mostVisitedView;
 
   // The overscroll actions controller managing accelerators over the toolbar.
-  base::scoped_nsobject<OverscrollActionsController>
-      _overscrollActionsController;
+  OverscrollActionsController* _overscrollActionsController;
 
   // |YES| when notifications indicate the omnibox is focused.
   BOOL _omniboxFocused;
 
   // Tap and swipe gesture recognizers when the omnibox is focused.
-  base::scoped_nsobject<UITapGestureRecognizer> _tapGestureRecognizer;
-  base::scoped_nsobject<UISwipeGestureRecognizer> _swipeGestureRecognizer;
+  UITapGestureRecognizer* _tapGestureRecognizer;
+  UISwipeGestureRecognizer* _swipeGestureRecognizer;
 
   // Handles displaying the context menu for all form factors.
-  base::scoped_nsobject<ContextMenuCoordinator> _contextMenuCoordinator;
+  ContextMenuCoordinator* _contextMenuCoordinator;
 
   // URL of the last deleted most viewed entry. If present the UI to restore it
   // is shown.
-  base::scoped_nsobject<NSURL> _deletedUrl;
+  NSURL* _deletedUrl;
 
   // |YES| if the view has finished its first layout. This is useful when
   // determining if the view has sized itself for tablet.
   BOOL _viewLoaded;
 
   // |YES| if the fakebox header should be animated on scroll.
   BOOL _animateHeader;
 
   // |YES| if the collection scrollView is scrolled all the way to the top. Used
   // to lock this position in place on various frame changes.
   BOOL _scrolledToTop;
 
   // |YES| if this NTP panel is visible.  When set to |NO| various UI updates
   // are ignored.
   BOOL _isShowing;
 
   CFTimeInterval _shiftTilesDownStartTime;
   CGSize _mostVisitedCellSize;
-  base::scoped_nsobject<NSLayoutConstraint> _hintLabelLeadingConstraint;
-  base::scoped_nsobject<NSLayoutConstraint> _voiceTapTrailingConstraint;
-  base::scoped_nsobject<NSLayoutConstraint> _doodleHeightConstraint;
-  base::scoped_nsobject<NSLayoutConstraint> _doodleTopMarginConstraint;
-  base::scoped_nsobject<NSLayoutConstraint> _searchFieldWidthConstraint;
-  base::scoped_nsobject<NSLayoutConstraint> _searchFieldHeightConstraint;
-  base::scoped_nsobject<NSLayoutConstraint> _searchFieldTopMarginConstraint;
-  base::scoped_nsobject<NewTabPageHeaderView> _headerView;
-  base::scoped_nsobject<WhatsNewHeaderView> _promoHeaderView;
-  base::WeakNSProtocol<id<GoogleLandingDataSource>> _dataSource;
-  base::WeakNSProtocol<id<UrlLoader, OmniboxFocuser>> _dispatcher;
+  NSLayoutConstraint* _hintLabelLeadingConstraint;
+  NSLayoutConstraint* _voiceTapTrailingConstraint;
+  NSLayoutConstraint* _doodleHeightConstraint;
+  NSLayoutConstraint* _doodleTopMarginConstraint;
+  NSLayoutConstraint* _searchFieldWidthConstraint;
+  NSLayoutConstraint* _searchFieldHeightConstraint;
+  NSLayoutConstraint* _searchFieldTopMarginConstraint;
+  NewTabPageHeaderView* _headerView;
+  WhatsNewHeaderView* _promoHeaderView;
+  __weak id<GoogleLandingDataSource> _dataSource;
+  __weak id<UrlLoader, OmniboxFocuser> _dispatcher;
 }
 
 // Whether the Google logo or doodle is being shown.
 @property(nonatomic, assign) BOOL logoIsShowing;
 
 // Exposes view and methods to drive the doodle.
-@property(nonatomic, assign) id<LogoVendor> logoVendor;
+@property(nonatomic, weak) id<LogoVendor> logoVendor;
 
 // |YES| if this consumer is has voice search enabled.
 @property(nonatomic, assign) BOOL voiceSearchIsEnabled;
 
 // Gets the maximum number of sites shown.
 @property(nonatomic, assign) NSUInteger maximumMostVisitedSitesShown;
 
 // Gets the text of a what's new promo.
-@property(nonatomic, retain) NSString* promoText;
+@property(nonatomic, strong) NSString* promoText;
 
 // Gets the icon of a what's new promo.
 // TODO(crbug.com/694750): This should not be WhatsNewIcon.
 @property(nonatomic, assign) WhatsNewIcon promoIcon;
 
 // |YES| if a what's new promo can be displayed.
 @property(nonatomic, assign) BOOL promoCanShow;
 
 // The number of tabs to show in the google landing fake toolbar.
 @property(nonatomic, assign) int tabCount;
@@ skipping 80 matching lines @@
                                  UIViewAutoresizingFlexibleWidth];
 
   // Initialise |shiftTilesDownStartTime| to a sentinel value to indicate that
   // the animation has not yet started.
   _shiftTilesDownStartTime = -1;
   _mostVisitedCellSize = [self mostVisitedCellSize];
   _isShowing = YES;
   _scrolledToTop = NO;
   _animateHeader = YES;
 
-  _tapGestureRecognizer.reset([[UITapGestureRecognizer alloc]
-      initWithTarget:self
-              action:@selector(blurOmnibox)]);
+  _tapGestureRecognizer =
+      [[UITapGestureRecognizer alloc] initWithTarget:self
+                                              action:@selector(blurOmnibox)];
   [_tapGestureRecognizer setDelegate:self];
-  _swipeGestureRecognizer.reset([[UISwipeGestureRecognizer alloc]
-      initWithTarget:self
-              action:@selector(blurOmnibox)]);
+  _swipeGestureRecognizer =
+      [[UISwipeGestureRecognizer alloc] initWithTarget:self
+                                                action:@selector(blurOmnibox)];
   [_swipeGestureRecognizer setDirection:UISwipeGestureRecognizerDirectionDown];
 
   self.leftMargin =
       content_suggestions::centeredTilesMarginForWidth([self viewWidth]);
 
   [self addSearchField];
   [self addMostVisited];
   [self addOverscrollActions];
   [self reload];
   _viewLoaded = YES;
@@ skipping 48 matching lines @@
   // Invalidate layout to handle the cases where the layout is changed when the
   // NTP is not presented (e.g. tab backgrounded).
   [[_mostVisitedView collectionViewLayout] invalidateLayout];
 }
 
 - (void)dealloc {
   [[NSNotificationCenter defaultCenter] removeObserver:self];
   [_mostVisitedView setDelegate:nil];
   [_mostVisitedView setDataSource:nil];
   [_overscrollActionsController invalidate];
-  [super dealloc];
 }
 
 #pragma mark - Properties
 
 - (id<GoogleLandingDataSource>)dataSource {
   return _dataSource;
 }
 
 - (void)setDataSource:(id<GoogleLandingDataSource>)dataSource {
-  _dataSource.reset(dataSource);
+  _dataSource = dataSource;
 }
 
 - (id<UrlLoader, OmniboxFocuser>)dispatcher {
   return _dispatcher;
 }
 
 - (void)setDispatcher:(id<UrlLoader, OmniboxFocuser>)dispatcher {
-  _dispatcher.reset(dispatcher);
+  _dispatcher = dispatcher;
 }
 
 #pragma mark - Private
 
 - (CGSize)mostVisitedCellSize {
   if (IsIPadIdiom()) {
     // On iPads, split-screen and slide-over may require showing smaller cells.
     CGSize maximumCellSize = [MostVisitedCell maximumSize];
     CGSize viewSize = self.view.bounds.size;
     CGFloat smallestDimension =
@@ skipping 57 matching lines @@
       whatsNewFrame.origin.y = omniboxHeaderHeight;
       [_promoHeaderView setFrame:whatsNewFrame];
     }
     if (IsIPadIdiom())
       [_searchTapTarget setHidden:!self.logoIsShowing];
   }
 }
 
 // Initialize and add a search field tap target and a voice search button.
 - (void)addSearchField {
-  _searchTapTarget.reset([[UIButton alloc] init]);
+  _searchTapTarget = [[UIButton alloc] init];
   if (IsIPadIdiom()) {
     UIImage* searchBoxImage = [[UIImage imageNamed:@"ntp_google_search_box"]
         resizableImageWithCapInsets:kSearchBoxStretchInsets];
     [_searchTapTarget setBackgroundImage:searchBoxImage
                                 forState:UIControlStateNormal];
   }
   [_searchTapTarget setAdjustsImageWhenHighlighted:NO];
   [_searchTapTarget addTarget:self
                        action:@selector(searchFieldTapped:)
              forControlEvents:UIControlEventTouchUpInside];
   [_searchTapTarget
       setAccessibilityLabel:l10n_util::GetNSString(IDS_OMNIBOX_EMPTY_HINT)];
   // Set isAccessibilityElement to NO so that Voice Search button is accessible.
   [_searchTapTarget setIsAccessibilityElement:NO];
 
   // Set up fakebox hint label.
-  UILabel* searchHintLabel = [[[UILabel alloc] init] autorelease];
+  UILabel* searchHintLabel = [[UILabel alloc] init];
   content_suggestions::configureSearchHintLabel(searchHintLabel,
-                                                _searchTapTarget.get());
+                                                _searchTapTarget);
 
-  _hintLabelLeadingConstraint.reset([[searchHintLabel.leadingAnchor
+  _hintLabelLeadingConstraint = [searchHintLabel.leadingAnchor
       constraintEqualToAnchor:[_searchTapTarget leadingAnchor]
-                     constant:kHintLabelSidePadding] retain]);
+                     constant:kHintLabelSidePadding];
   [_hintLabelLeadingConstraint setActive:YES];
 
   // Add a voice search button.
-  UIButton* voiceTapTarget = [[[UIButton alloc] init] autorelease];
+  UIButton* voiceTapTarget = [[UIButton alloc] init];
   content_suggestions::configureVoiceSearchButton(voiceTapTarget,
-                                                  _searchTapTarget.get());
+                                                  _searchTapTarget);
 
-  _voiceTapTrailingConstraint.reset([[voiceTapTarget.trailingAnchor
-      constraintEqualToAnchor:[_searchTapTarget trailingAnchor]] retain]);
+  _voiceTapTrailingConstraint = [voiceTapTarget.trailingAnchor
+      constraintEqualToAnchor:[_searchTapTarget trailingAnchor]];
   [NSLayoutConstraint activateConstraints:@[
     [searchHintLabel.trailingAnchor
         constraintEqualToAnchor:voiceTapTarget.leadingAnchor],
     _voiceTapTrailingConstraint
   ]];
 
   if (self.voiceSearchIsEnabled) {
     [voiceTapTarget addTarget:self
                        action:@selector(loadVoiceSearch:)
              forControlEvents:UIControlEventTouchUpInside];
@@ skipping 12 matching lines @@
 }
 
 - (void)preloadVoiceSearch:(id)sender {
   DCHECK(self.voiceSearchIsEnabled);
   [sender removeTarget:self
                 action:@selector(preloadVoiceSearch:)
       forControlEvents:UIControlEventTouchDown];
 
   // Use a GenericChromeCommand because |sender| already has a tag set for a
   // different command.
-  base::scoped_nsobject<GenericChromeCommand> command(
-      [[GenericChromeCommand alloc] initWithTag:IDC_PRELOAD_VOICE_SEARCH]);
+  GenericChromeCommand* command =
+      [[GenericChromeCommand alloc] initWithTag:IDC_PRELOAD_VOICE_SEARCH];
   [sender chromeExecuteCommand:command];
 }
 
 // Initialize and add a panel with most visited sites.
 - (void)addMostVisited {
   CGRect mostVisitedFrame = [self.view bounds];
-  base::scoped_nsobject<UICollectionViewFlowLayout> flowLayout;
+  UICollectionViewFlowLayout* flowLayout;
   if (IsIPadIdiom())
-    flowLayout.reset([[UICollectionViewFlowLayout alloc] init]);
+    flowLayout = [[UICollectionViewFlowLayout alloc] init];
   else
-    flowLayout.reset([[MostVisitedLayout alloc] init]);
+    flowLayout = [[MostVisitedLayout alloc] init];
 
   [flowLayout setScrollDirection:UICollectionViewScrollDirectionVertical];
   [flowLayout setItemSize:_mostVisitedCellSize];
   [flowLayout setMinimumInteritemSpacing:8];
   [flowLayout setMinimumLineSpacing:content_suggestions::spacingBetweenTiles()];
   DCHECK(!_mostVisitedView);
-  _mostVisitedView.reset([[UICollectionView alloc]
-             initWithFrame:mostVisitedFrame
-      collectionViewLayout:flowLayout]);
+  _mostVisitedView = [[UICollectionView alloc] initWithFrame:mostVisitedFrame
+                                        collectionViewLayout:flowLayout];
   [_mostVisitedView setAutoresizingMask:UIViewAutoresizingFlexibleHeight |
                                         UIViewAutoresizingFlexibleWidth];
   [_mostVisitedView setDelegate:self];
   [_mostVisitedView setDataSource:self];
   [_mostVisitedView registerClass:[MostVisitedCell class]
        forCellWithReuseIdentifier:@"classCell"];
   [_mostVisitedView setBackgroundColor:[UIColor clearColor]];
   [_mostVisitedView setBounces:YES];
   [_mostVisitedView setShowsHorizontalScrollIndicator:NO];
   [_mostVisitedView setShowsVerticalScrollIndicator:NO];
@@ skipping 12 matching lines @@
   [_headerView updateSearchFieldWidth:_searchFieldWidthConstraint
                                height:_searchFieldHeightConstraint
                             topMargin:_searchFieldTopMarginConstraint
                    subviewConstraints:constraints
                         logoIsShowing:self.logoIsShowing
                             forOffset:[_mostVisitedView contentOffset].y];
 }
 
 - (void)addOverscrollActions {
   if (!IsIPadIdiom()) {
-    _overscrollActionsController.reset([[OverscrollActionsController alloc]
-        initWithScrollView:_mostVisitedView]);
+    _overscrollActionsController = [[OverscrollActionsController alloc]
+        initWithScrollView:_mostVisitedView];
     [_overscrollActionsController setStyle:OverscrollStyle::NTP_NON_INCOGNITO];
     [_overscrollActionsController setDelegate:self];
   }
 }
 
 // Check to see if the promo label should be hidden.
 - (void)hideWhatsNewIfNecessary {
   if (![_promoHeaderView isHidden] && !self.promoCanShow) {
     [_promoHeaderView setHidden:YES];
     [self.view setNeedsLayout];
@@ skipping 132 matching lines @@
   // -numberOfItems increases enough to add a new row and change the height
   // of _mostVisitedView.
   [_mostVisitedView reloadData];
   [[_mostVisitedView collectionViewLayout] invalidateLayout];
   [self.view setNeedsLayout];
 }
 
 - (void)addConstraintsForLogoView:(UIView*)logoView
                       searchField:(UIView*)searchField
                     andHeaderView:(UIView*)headerView {
-  _doodleTopMarginConstraint.reset([[logoView.topAnchor
+  _doodleTopMarginConstraint = [logoView.topAnchor
       constraintEqualToAnchor:headerView.topAnchor
-                     constant:content_suggestions::doodleTopMargin()] retain]);
-  _doodleHeightConstraint.reset([[logoView.heightAnchor
+                     constant:content_suggestions::doodleTopMargin()];
+  _doodleHeightConstraint = [logoView.heightAnchor
       constraintEqualToConstant:content_suggestions::doodleHeight(
-                                    self.logoIsShowing)] retain]);
-  _searchFieldWidthConstraint.reset([[searchField.widthAnchor
+                                    self.logoIsShowing)];
+  _searchFieldWidthConstraint = [searchField.widthAnchor
       constraintEqualToConstant:content_suggestions::searchFieldWidth(
-                                    [self viewWidth])] retain]);
-  _searchFieldHeightConstraint.reset([[searchField.heightAnchor
-      constraintEqualToConstant:content_suggestions::kSearchFieldHeight]
-      retain]);
-  _searchFieldTopMarginConstraint.reset([[searchField.topAnchor
+                                    [self viewWidth])];
+  _searchFieldHeightConstraint = [searchField.heightAnchor
+      constraintEqualToConstant:content_suggestions::kSearchFieldHeight];
+  _searchFieldTopMarginConstraint = [searchField.topAnchor
       constraintEqualToAnchor:logoView.bottomAnchor
-                     constant:content_suggestions::searchFieldTopMargin()]
-      retain]);
+                     constant:content_suggestions::searchFieldTopMargin()];
   [NSLayoutConstraint activateConstraints:@[
     _doodleTopMarginConstraint,
-    _doodleHeightConstraint.get(),
-    _searchFieldWidthConstraint.get(),
-    _searchFieldHeightConstraint.get(),
-    _searchFieldTopMarginConstraint.get(),
+    _doodleHeightConstraint,
+    _searchFieldWidthConstraint,
+    _searchFieldHeightConstraint,
+    _searchFieldTopMarginConstraint,
     [logoView.widthAnchor constraintEqualToAnchor:headerView.widthAnchor],
     [logoView.leadingAnchor constraintEqualToAnchor:headerView.leadingAnchor],
     [searchField.centerXAnchor
         constraintEqualToAnchor:headerView.centerXAnchor],
   ]];
 }
 
 - (void)updateConstraintsForWidth:(CGFloat)width {
   [_promoHeaderView
       setSideMargin:content_suggestions::centeredTilesMarginForWidth(width)
@@ skipping 54 matching lines @@
 - (void)collectionView:(UICollectionView*)collectionView
     didSelectItemAtIndexPath:(NSIndexPath*)indexPath {
   MostVisitedCell* cell =
       (MostVisitedCell*)[collectionView cellForItemAtIndexPath:indexPath];
 
   // Keep the UICollectionView alive for one second while the screen
   // reader does its thing.
   // TODO(jif): This needs a radar, since it is almost certainly a
   // UIKit accessibility bug. crbug.com/529271
   if (UIAccessibilityIsVoiceOverRunning()) {
-    UICollectionView* blockView = [_mostVisitedView retain];
+    __block UICollectionView* blockView = _mostVisitedView;
     dispatch_after(dispatch_time(DISPATCH_TIME_NOW,
                                  static_cast<int64_t>(1 * NSEC_PER_SEC)),
                    dispatch_get_main_queue(), ^{
-                     [blockView release];
+                     blockView = nil;
                    });
   }
 
   const NSUInteger visitedIndex = indexPath.row;
   [self blurOmnibox];
   DCHECK(visitedIndex < [self numberOfItems]);
   [self.dataSource logMostVisitedClick:visitedIndex tileType:cell.tileType];
   [self.dispatcher loadURL:[self urlForIndex:visitedIndex]
                   referrer:web::Referrer()
                 transition:ui::PAGE_TRANSITION_AUTO_BOOKMARK
          rendererInitiated:NO];
 }
 
 #pragma mark - UICollectionViewDataSource
 
 - (UICollectionReusableView*)collectionView:(UICollectionView*)collectionView
           viewForSupplementaryElementOfKind:(NSString*)kind
                                 atIndexPath:(NSIndexPath*)indexPath {
   DCHECK(kind == UICollectionElementKindSectionHeader);
 
   if (indexPath.section == SectionWithOmnibox) {
     UICollectionReusableView* reusableView =
         [collectionView dequeueReusableSupplementaryViewOfKind:
                             UICollectionElementKindSectionHeader
                                            withReuseIdentifier:@"header"
                                                   forIndexPath:indexPath];
     if (!_headerView) {
-      _headerView.reset([[NewTabPageHeaderView alloc] init]);
+      _headerView = [[NewTabPageHeaderView alloc] init];
       [_headerView addSubview:[self.logoVendor view]];
       [_headerView addSubview:_searchTapTarget];
       self.logoVendor.view.translatesAutoresizingMaskIntoConstraints = NO;
       [_searchTapTarget setTranslatesAutoresizingMaskIntoConstraints:NO];
 
       [self addConstraintsForLogoView:self.logoVendor.view
                           searchField:_searchTapTarget
                         andHeaderView:_headerView];
 
       [_headerView addViewsToSearchField:_searchTapTarget];
@@ skipping 16 matching lines @@
     return reusableView;
   }
 
   if (indexPath.section == SectionWithMostVisited) {
     UICollectionReusableView* reusableView =
         [collectionView dequeueReusableSupplementaryViewOfKind:
                             UICollectionElementKindSectionHeader
                                            withReuseIdentifier:@"header"
                                                   forIndexPath:indexPath];
     if (!_promoHeaderView) {
-      _promoHeaderView.reset([[WhatsNewHeaderView alloc] init]);
+      _promoHeaderView = [[WhatsNewHeaderView alloc] init];
       [_promoHeaderView
           setSideMargin:content_suggestions::centeredTilesMarginForWidth(
                             [self viewWidth])
                forWidth:[self viewWidth]];
       [_promoHeaderView setDelegate:self];
       if (self.promoCanShow) {
         [_promoHeaderView setText:self.promoText];
         [_promoHeaderView setIcon:self.promoIcon];
         [self.dataSource promoViewed];
       }
@@ skipping 46 matching lines @@
     }
     return cell;
   }
 
   const ntp_tiles::NTPTile& ntpTile =
       [self.dataSource mostVisitedAtIndex:indexPath.row];
   NSString* title = base::SysUTF16ToNSString(ntpTile.title);
 
   [cell setupWithURL:ntpTile.url title:title dataSource:self.dataSource];
 
-  base::scoped_nsobject<UILongPressGestureRecognizer> longPress(
+  UILongPressGestureRecognizer* longPress =
       [[UILongPressGestureRecognizer alloc]
           initWithTarget:self
-                  action:@selector(handleMostVisitedLongPress:)]);
+                  action:@selector(handleMostVisitedLongPress:)];
   [cell addGestureRecognizer:longPress];
 
   return cell;
 }
 
 #pragma mark - Context Menu
 
 // Called when a user does a long press on a most visited item.
 - (void)handleMostVisitedLongPress:(UILongPressGestureRecognizer*)sender {
   if (sender.state == UIGestureRecognizerStateBegan) {
     // Only one long press at a time.
     if ([_contextMenuCoordinator isVisible]) {
       return;
     }
 
     NSIndexPath* indexPath = [_mostVisitedView
         indexPathForCell:static_cast<UICollectionViewCell*>(sender.view)];
     const NSUInteger index = indexPath.row;
 
     // A long press occured on one of the most visited button. Popup a context
     // menu.
     DCHECK(index < [self numberOfItems]);
 
     web::ContextMenuParams params;
     // Get view coordinates in local space.
     params.location = [sender locationInView:self.view];
-    params.view.reset([self.view retain]);
+    params.view.reset(self.view);
 
     // Present sheet/popover using controller that is added to view hierarchy.
     UIViewController* topController = [params.view window].rootViewController;
     while (topController.presentedViewController)
       topController = topController.presentedViewController;
 
-    _contextMenuCoordinator.reset([[ContextMenuCoordinator alloc]
-        initWithBaseViewController:topController
-                            params:params]);
+    _contextMenuCoordinator =
+        [[ContextMenuCoordinator alloc] initWithBaseViewController:topController
+                                                            params:params];
 
     ProceduralBlock action;
 
     // Open In New Tab.
     GURL url = [self urlForIndex:index];
-    base::WeakNSObject<GoogleLandingViewController> weakSelf(self);
+    __weak GoogleLandingViewController* weakSelf = self;
     action = ^{
-      base::scoped_nsobject<GoogleLandingViewController> strongSelf(
-          [weakSelf retain]);
+      GoogleLandingViewController* strongSelf = weakSelf;
       if (!strongSelf)
         return;
       MostVisitedCell* cell = (MostVisitedCell*)sender.view;
       [[strongSelf dataSource] logMostVisitedClick:index
                                           tileType:cell.tileType];
       [[strongSelf dispatcher] webPageOrderedOpen:url
                                          referrer:web::Referrer()
                                      inBackground:YES
                                          appendTo:kCurrentTab];
     };
     [_contextMenuCoordinator
         addItemWithTitle:l10n_util::GetNSStringWithFixup(
                              IDS_IOS_CONTENT_CONTEXT_OPENLINKNEWTAB)
                   action:action];
 
     // Open in Incognito Tab.
     action = ^{
-      base::scoped_nsobject<GoogleLandingViewController> strongSelf(
-          [weakSelf retain]);
+      GoogleLandingViewController* strongSelf = weakSelf;
       if (!strongSelf)
         return;
       MostVisitedCell* cell = (MostVisitedCell*)sender.view;
       [[strongSelf dataSource] logMostVisitedClick:index
                                           tileType:cell.tileType];
       [[strongSelf dispatcher] webPageOrderedOpen:url
                                          referrer:web::Referrer()
                                       inIncognito:YES
                                      inBackground:NO
                                          appendTo:kCurrentTab];
     };
     [_contextMenuCoordinator
         addItemWithTitle:l10n_util::GetNSStringWithFixup(
                              IDS_IOS_CONTENT_CONTEXT_OPENLINKNEWINCOGNITOTAB)
                   action:action];
 
     // Remove the most visited url.
     NSString* title =
         l10n_util::GetNSStringWithFixup(IDS_BOOKMARK_BUBBLE_REMOVE_BOOKMARK);
     action = ^{
-      base::scoped_nsobject<GoogleLandingViewController> strongSelf(
-          [weakSelf retain]);
+      GoogleLandingViewController* strongSelf = weakSelf;
       // Early return if the controller has been deallocated.
       if (!strongSelf)
         return;
       base::RecordAction(UserMetricsAction("MostVisited_UrlBlacklisted"));
       [[strongSelf dataSource] addBlacklistedURL:url];
       [strongSelf showMostVisitedUndoForURL:net::NSURLWithGURL(url)];
     };
     [_contextMenuCoordinator addItemWithTitle:title action:action];
 
     [_contextMenuCoordinator start];
 
     if (IsIPadIdiom())
       [self blurOmnibox];
   }
 }
 
 - (void)showMostVisitedUndoForURL:(NSURL*)url {
-  _deletedUrl.reset([url retain]);
+  _deletedUrl = url;
 
-  MDCSnackbarMessageAction* action =
-      [[[MDCSnackbarMessageAction alloc] init] autorelease];
-  base::WeakNSObject<GoogleLandingViewController> weakSelf(self);
+  MDCSnackbarMessageAction* action = [[MDCSnackbarMessageAction alloc] init];
+  __weak GoogleLandingViewController* weakSelf = self;
   action.handler = ^{
-    base::scoped_nsobject<GoogleLandingViewController> strongSelf(
-        [weakSelf retain]);
+    GoogleLandingViewController* strongSelf = weakSelf;
     if (!strongSelf)
       return;
     [[strongSelf dataSource]
         removeBlacklistedURL:net::GURLWithNSURL(_deletedUrl)];
   };
   action.title = l10n_util::GetNSString(IDS_NEW_TAB_UNDO_THUMBNAIL_REMOVE);
   action.accessibilityIdentifier = @"Undo";
 
   TriggerHapticFeedbackForNotification(UINotificationFeedbackTypeSuccess);
   MDCSnackbarMessage* message = [MDCSnackbarMessage
@@ skipping 204 matching lines @@
 - (BOOL)animateHeader {
   return _animateHeader;
 }
 
 #pragma mark - OverscrollActionsControllerDelegate
 
 - (void)overscrollActionsController:(OverscrollActionsController*)controller
                    didTriggerAction:(OverscrollAction)action {
   switch (action) {
     case OverscrollAction::NEW_TAB: {
-      base::scoped_nsobject<GenericChromeCommand> command(
-          [[GenericChromeCommand alloc] initWithTag:IDC_NEW_TAB]);
+      GenericChromeCommand* command =
+          [[GenericChromeCommand alloc] initWithTag:IDC_NEW_TAB];
       [[self view] chromeExecuteCommand:command];
     } break;
     case OverscrollAction::CLOSE_TAB: {
-      base::scoped_nsobject<GenericChromeCommand> command(
-          [[GenericChromeCommand alloc] initWithTag:IDC_CLOSE_TAB]);
+      GenericChromeCommand* command =
+          [[GenericChromeCommand alloc] initWithTag:IDC_CLOSE_TAB];
       [[self view] chromeExecuteCommand:command];
     } break;
     case OverscrollAction::REFRESH:
       [self reload];
       break;
     case OverscrollAction::NONE:
       NOTREACHED();
       break;
   }
 }
@@ skipping 65 matching lines @@
 - (void)setCanGoForward:(BOOL)canGoForward {
   _canGoForward = canGoForward;
   [_headerView setCanGoForward:self.canGoForward];
 }
 
 - (void)setCanGoBack:(BOOL)canGoBack {
   _canGoBack = canGoBack;
   [_headerView setCanGoBack:self.canGoBack];
 }
 @end