[ObjC ARC] Converts ios/chrome/browser/ui/stack_view:stack_view to ARC.

ios/chrome/browser/ui/stack_view/card_view.mm

 // Copyright 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 // For performance reasons, the composition of the card frame is broken up into
 // four pieces.  The overall structure of the CardView is:
 // - CardView
 //   - Snapshot (UIImageView)
 //   - FrameTop (UIImageView)
 //   - FrameLeft (UIImageView)
 //   - FrameRight (UIImageView)
 //   - FrameBottom (UIImageView)
 //   - CardTabView (UIView::DrawRect)
 //
 // While it would be simpler to put the frame in one transparent UIImageView,
 // that would make the entire snapshot area needlessly color-blended.  Instead
 // the frame is broken up into four pieces, top, left, bottom, right.
 //
 // The frame's tab gets its own view above everything else (CardTabView) so that
 // it can be animated out. It's also transparent since the tab has a curve and
 // a shadow.
 
 #import "ios/chrome/browser/ui/stack_view/card_view.h"
 
 #import <QuartzCore/QuartzCore.h>
 #include <algorithm>
 
 #import "base/mac/foundation_util.h"
-#import "base/mac/objc_property_releaser.h"
-#import "base/mac/scoped_nsobject.h"
+
 #include "components/strings/grit/components_strings.h"
 #import "ios/chrome/browser/ui/animation_util.h"
 #import "ios/chrome/browser/ui/reversed_animation.h"
 #import "ios/chrome/browser/ui/rtl_geometry.h"
 #import "ios/chrome/browser/ui/stack_view/close_button.h"
 #import "ios/chrome/browser/ui/stack_view/title_label.h"
 #import "ios/chrome/browser/ui/ui_util.h"
 #import "ios/chrome/common/material_timing.h"
 #import "ios/third_party/material_components_ios/src/components/Typography/src/MaterialTypography.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "ui/base/resource/resource_bundle.h"
 #include "ui/gfx/favicon_size.h"
 #include "ui/gfx/image/image.h"
 #import "ui/gfx/ios/uikit_util.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 using ios::material::TimingFunction;
 
 const UIEdgeInsets kCardImageInsets = {48.0, 4.0, 4.0, 4.0};
 const CGFloat kCardFrameInset = 1.0;
 const CGFloat kCardShadowThickness = 16.0;
 const CGFloat kCardFrameCornerRadius = 4.0;
 const CGFloat kCardTabTopInset = 4;
 const CGFloat kCardFrameBackgroundBrightness = 242.0 / 255.0;
 const CGFloat kCardFrameBackgroundBrightnessIncognito = 80.0 / 255.0;
 const CGFloat kCardFrameImageSnapshotOverlap = 1.0;
@@ skipping 22 matching lines @@
   return [UIImage imageNamed:name];
 }
 
 }  // namespace
 
 #pragma mark -
 
 @interface CardTabView : UIView
 
 @property(nonatomic, assign) CardCloseButtonSide closeButtonSide;
-@property(nonatomic, retain) UIImageView* favIconView;
-@property(nonatomic, retain) UIImage* favicon;
-@property(nonatomic, retain) CloseButton* closeButton;
-@property(nonatomic, retain) TitleLabel* titleLabel;
+@property(nonatomic, strong) UIImageView* favIconView;
+@property(nonatomic, strong) UIImage* favicon;
+@property(nonatomic, strong) CloseButton* closeButton;
+@property(nonatomic, strong) TitleLabel* titleLabel;
 @property(nonatomic, assign) BOOL isIncognito;
 
 // Layout helper selectors that calculate the frames for subviews given the
 // bounds of the card tab.  Note that the frames returned by these selectors
 // will be different depending on the value of the |displaySide| property.
 - (LayoutRect)faviconLayoutForBounds:(CGRect)bounds;
 - (CGRect)faviconFrameForBounds:(CGRect)bounds;
 - (LayoutRect)titleLabelLayoutForBounds:(CGRect)bounds;
 - (CGRect)titleLabelFrameForBounds:(CGRect)bounds;
 - (LayoutRect)closeButtonLayoutForBounds:(CGRect)bounds;
@@ skipping 15 matching lines @@
 - (void)cleanUpAnimations;
 
 // Initialize a CardTabView with |frame| and |isIncognito| state.
 - (instancetype)initWithFrame:(CGRect)frame
                   isIncognito:(BOOL)isIncognito NS_DESIGNATED_INITIALIZER;
 
 - (instancetype)initWithCoder:(NSCoder*)aDecoder NS_UNAVAILABLE;
 
 @end
 
-@implementation CardTabView {
-  base::mac::ObjCPropertyReleaser _propertyReleaser_CardTabView;
-}
+@implementation CardTabView
 
 #pragma mark - Property Implementation
 
 @synthesize closeButtonSide = _closeButtonSide;
 @synthesize favIconView = _faviconView;
 @synthesize favicon = _favicon;
 @synthesize closeButton = _closeButton;
 @synthesize titleLabel = _titleLabel;
 @synthesize isIncognito = _isIncognito;
 
 - (instancetype)initWithFrame:(CGRect)frame {
   return [self initWithFrame:frame isIncognito:NO];
 }
 
 - (instancetype)initWithFrame:(CGRect)frame isIncognito:(BOOL)isIncognito {
   self = [super initWithFrame:frame];
   if (!self)
     return self;
 
-  _propertyReleaser_CardTabView.Init(self, [CardTabView class]);
   _isIncognito = isIncognito;
 
   UIImage* image = ImageWithName(@"default_favicon", _isIncognito);
   _faviconView = [[UIImageView alloc] initWithImage:image];
   [self addSubview:_faviconView];
 
   UIImage* normal = ImageWithName(@"card_close_button", _isIncognito);
   UIImage* pressed = ImageWithName(@"card_close_button_pressed", _isIncognito);
 
   _closeButton = [[CloseButton alloc] initWithFrame:CGRectZero];
@@ skipping 105 matching lines @@
 
 - (void)setTitle:(NSString*)title {
   [_titleLabel setText:title];
   [_closeButton setAccessibilityValue:title];
 
   [self setNeedsUpdateConstraints];
 }
 
 - (void)setFavicon:(UIImage*)favicon {
   if (favicon != _favicon) {
-    [favicon retain];
-    [_favicon release];
     _favicon = favicon;
     [self updateFaviconImage];
   }
 }
 
 - (void)updateTitleColors {
   UIColor* titleColor = [UIColor blackColor];
   if (_isIncognito)
     titleColor = [UIColor whiteColor];
 
@@ skipping 143 matching lines @@
   else if (element == _titleLabel)
     index = closeButtonLeading ? 1 : 0;
   return index;
 }
 
 @end
 
 #pragma mark -
 
 @interface CardView () {
-  base::scoped_nsobject<UIImageView> _contents;
-  base::scoped_nsobject<CardTabView> _tab;
-  id _cardCloseTarget;  // weak
+  UIImageView* _contents;
+  CardTabView* _tab;
+  __weak id _cardCloseTarget;
   SEL _cardCloseAction;
-  id _accessibilityTarget;  // weak
+  __weak id _accessibilityTarget;
   SEL _accessibilityAction;
 
   BOOL _isIncognito;  // YES if the card should use the incognito styling.
 
   // Pieces of the card frame, split into four UIViews.
-  base::scoped_nsobject<UIImageView> _frameLeft;
-  base::scoped_nsobject<UIImageView> _frameRight;
-  base::scoped_nsobject<UIImageView> _frameTop;
-  base::scoped_nsobject<UIImageView> _frameBottom;
-  base::scoped_nsobject<UIImageView> _frameShadowImageView;
-  base::scoped_nsobject<CALayer> _shadowMask;
+  UIImageView* _frameLeft;
+  UIImageView* _frameRight;
+  UIImageView* _frameTop;
+  UIImageView* _frameBottom;
+  UIImageView* _frameShadowImageView;
+  CALayer* _shadowMask;
 }
 
 // The LayoutRect for the CardTabView.
 - (LayoutRect)tabLayout;
 
 // Sends |_cardCloseAction| to |_cardCloseTarget| with |self| as the sender.
 - (void)closeButtonWasTapped:(id)sender;
 
 // Resizes/zooms the snapshot to avoid stretching given the card's current
 // bounds.
@@ skipping 38 matching lines @@
   if (!self)
     return self;
 
   _isIncognito = isIncognito;
   CGRect bounds = self.bounds;
 
   self.opaque = NO;
   self.contentMode = UIViewContentModeRedraw;
 
   CGRect shadowFrame = UIEdgeInsetsInsetRect(bounds, kCardShadowLayoutOutsets);
-  _frameShadowImageView.reset([[UIImageView alloc] initWithFrame:shadowFrame]);
+  _frameShadowImageView = [[UIImageView alloc] initWithFrame:shadowFrame];
   [_frameShadowImageView
       setAutoresizingMask:(UIViewAutoresizingFlexibleWidth |
                            UIViewAutoresizingFlexibleHeight)];
   [self addSubview:_frameShadowImageView];
 
   // Calling properties for side-effects.
   self.shouldShowShadow = YES;
   self.shouldMaskShadow = YES;
 
   UIImage* image = [UIImage imageNamed:kCardShadowImageName];
   image = [image resizableImageWithCapInsets:kShadowStretchInsets];
   [_frameShadowImageView setImage:image];
 
   CGRect snapshotFrame = UIEdgeInsetsInsetRect(bounds, kCardImageInsets);
-  _contents.reset([[UIImageView alloc] initWithFrame:snapshotFrame]);
+  _contents = [[UIImageView alloc] initWithFrame:snapshotFrame];
   [_contents setClipsToBounds:YES];
   [_contents setContentMode:UIViewContentModeScaleAspectFill];
   [_contents setFrame:snapshotFrame];
   [_contents setAutoresizingMask:UIViewAutoresizingFlexibleWidth |
                                  UIViewAutoresizingFlexibleHeight];
   [self addSubview:_contents];
 
   image = [UIImage imageNamed:isIncognito ? @"border_frame_incognito_left"
                                           : @"border_frame_left"];
   UIEdgeInsets imageStretchInsets = UIEdgeInsetsMake(
       0.5 * image.size.height, 0.0, 0.5 * image.size.height, 0.0);
   image = [image resizableImageWithCapInsets:imageStretchInsets];
-  _frameLeft.reset([[UIImageView alloc] initWithImage:image]);
+  _frameLeft = [[UIImageView alloc] initWithImage:image];
   [self addSubview:_frameLeft];
 
   image = [UIImage imageNamed:isIncognito ? @"border_frame_incognito_right"
                                           : @"border_frame_right"];
   imageStretchInsets = UIEdgeInsetsMake(0.5 * image.size.height, 0.0,
                                         0.5 * image.size.height, 0.0);
   image = [image resizableImageWithCapInsets:imageStretchInsets];
-  _frameRight.reset([[UIImageView alloc] initWithImage:image]);
+  _frameRight = [[UIImageView alloc] initWithImage:image];
   [self addSubview:_frameRight];
 
   image = [UIImage imageNamed:isIncognito ? @"border_frame_incognito_top"
                                           : @"border_frame_top"];
   imageStretchInsets = UIEdgeInsetsMake(0.0, 0.5 * image.size.width, 0.0,
                                         0.5 * image.size.width);
   image = [image resizableImageWithCapInsets:imageStretchInsets];
-  _frameTop.reset([[UIImageView alloc] initWithImage:image]);
+  _frameTop = [[UIImageView alloc] initWithImage:image];
   [self addSubview:_frameTop];
 
   image = [UIImage imageNamed:isIncognito ? @"border_frame_incognito_bottom"
                                           : @"border_frame_bottom"];
   imageStretchInsets = UIEdgeInsetsMake(0.0, 0.5 * image.size.width, 0.0,
                                         0.5 * image.size.width);
   image = [image resizableImageWithCapInsets:imageStretchInsets];
-  _frameBottom.reset([[UIImageView alloc] initWithImage:image]);
+  _frameBottom = [[UIImageView alloc] initWithImage:image];
   [self addSubview:_frameBottom];
 
-  _tab.reset([[CardTabView alloc]
-      initWithFrame:LayoutRectGetRect([self tabLayout])
-        isIncognito:_isIncognito]);
+  _tab = [[CardTabView alloc] initWithFrame:LayoutRectGetRect([self tabLayout])
+                                isIncognito:_isIncognito];
   [_tab setCloseButtonSide:IsPortrait() ? CardCloseButtonSide::TRAILING
                                         : CardCloseButtonSide::LEADING];
   [[_tab closeButton] addTarget:self
                          action:@selector(closeButtonWasTapped:)
                forControlEvents:UIControlEventTouchUpInside];
   [[_tab closeButton]
       addAccessibilityElementFocusedTarget:self
                                     action:@selector(elementDidBecomeFocused:)];
   [_tab closeButton].accessibilityIdentifier = [self closeButtonId];
 
@@ skipping 58 matching lines @@
 
 - (TitleLabel*)titleLabel {
   return [_tab titleLabel];
 }
 
 - (void)setFavicon:(UIImage*)favicon {
   [_tab setFavicon:favicon];
 }
 
 - (void)closeButtonWasTapped:(id)sender {
+#pragma clang diagnostic push
+#pragma clang diagnostic ignored "-Warc-performSelector-leaks"
   [_cardCloseTarget performSelector:_cardCloseAction withObject:self];
+#pragma clang diagnostic pop
   // Disable the tab's close button to prevent touch handling from the button
   // while it's animating closed.
   [_tab closeButton].enabled = NO;
 }
 
 - (void)addCardCloseTarget:(id)target action:(SEL)action {
   DCHECK(!target || [target respondsToSelector:action]);
   _cardCloseTarget = target;
   _cardCloseAction = action;
 }
@@ skipping 11 matching lines @@
   CGRect cardBounds = {CGPointZero, cardSize};
   CGSize viewSize = UIEdgeInsetsInsetRect(cardBounds, kCardImageInsets).size;
   CGSize imageSize = [_contents image].size;
   CGFloat zoomRatio = std::max(viewSize.height / imageSize.height,
                                viewSize.width / imageSize.width);
   return CGRectMake(0.0, 0.0, viewSize.width / (zoomRatio * imageSize.width),
                     viewSize.height / (zoomRatio * imageSize.height));
 }
 
 - (void)updateImageBoundsAndZoom {
-  UIImageView* imageView = _contents.get();
+  UIImageView* imageView = _contents;
   DCHECK(!CGRectEqualToRect(self.bounds, CGRectZero));
 
   imageView.frame = UIEdgeInsetsInsetRect(self.bounds, kCardImageInsets);
   if (imageView.image) {
     // Zoom the image to fill the available space.
     imageView.layer.contentsRect =
         [self imageContentsRectForCardSize:self.bounds.size];
   }
 }
 
 - (void)updateSnapshotAnimations {
   CAAnimation* snapshotAnimation =
       [[_contents layer] animationForKey:kCardViewAnimationKey];
   if (!snapshotAnimation)
     return;
 
   // Create copy of animation (animations become immutable after they're added
   // to the layer).
-  base::scoped_nsobject<CAAnimationGroup> updatedAnimation(
-      static_cast<CAAnimationGroup*>([snapshotAnimation copy]));
+  CAAnimationGroup* updatedAnimation = [snapshotAnimation copy];
   // Extract begin and end sizes of the card.
   CAAnimation* cardAnimation =
       [self.layer animationForKey:kCardViewAnimationKey];
   CABasicAnimation* cardBoundsAnimation =
       FindAnimationForKeyPath(@"bounds", cardAnimation);
   CGSize beginCardSize = [cardBoundsAnimation.fromValue CGRectValue].size;
   CGSize endCardSize = [cardBoundsAnimation.toValue CGRectValue].size;
   // Update the contentsRect animation.
   CABasicAnimation* contentsRectAnimation =
       FindAnimationForKeyPath(@"contentsRect", updatedAnimation);
@@ skipping 26 matching lines @@
   }
   return LayoutRectGetRect(maskLayout);
 }
 
 - (void)updateShadowMask {
   if (!self.shouldShowShadow)
     return;
 
   if (self.shouldMaskShadow) {
     if (!_shadowMask) {
-      _shadowMask.reset([[CALayer alloc] init]);
+      _shadowMask = [[CALayer alloc] init];
       [_shadowMask setBackgroundColor:[UIColor blackColor].CGColor];
     }
     [_frameShadowImageView layer].mask = _shadowMask;
     [_shadowMask setFrame:[self shadowMaskFrameForBounds:self.bounds]];
   } else {
     [_frameShadowImageView layer].mask = nil;
   }
 }
 
 - (LayoutRect)tabLayout {
@@ skipping 185 matching lines @@
     frameAnimation = FrameAnimationMake(
         [_frameShadowImageView layer],
         UIEdgeInsetsInsetRect(beginBounds, kCardShadowLayoutOutsets),
         UIEdgeInsetsInsetRect(endBounds, kCardShadowLayoutOutsets));
     frameAnimation.duration = frameDuration;
     frameAnimation.timingFunction = frameTiming;
     [[_frameShadowImageView layer] addAnimation:frameAnimation
                                          forKey:kCardViewAnimationKey];
     if (self.shouldMaskShadow) {
       frameAnimation = FrameAnimationMake(
-          _shadowMask.get(), [self shadowMaskFrameForBounds:beginBounds],
+          _shadowMask, [self shadowMaskFrameForBounds:beginBounds],
           [self shadowMaskFrameForBounds:endBounds]);
       frameAnimation.duration = frameDuration;
       frameAnimation.timingFunction = frameTiming;
       [_shadowMask addAnimation:frameAnimation forKey:kCardViewAnimationKey];
     }
   }
 
   // Update content snapshot
   CGRect beginContentFrame =
       UIEdgeInsetsInsetRect(beginBounds, kCardImageInsets);
@@ skipping 56 matching lines @@
                                   [_tab titleLabel]);
 }
 
 - (void)addAccessibilityTarget:(id)target action:(SEL)action {
   DCHECK(!target || [target respondsToSelector:action]);
   _accessibilityTarget = target;
   _accessibilityAction = action;
 }
 
 - (void)elementDidBecomeFocused:(id)sender {
+#pragma clang diagnostic push
+#pragma clang diagnostic ignored "-Warc-performSelector-leaks"
   [_accessibilityTarget performSelector:_accessibilityAction withObject:sender];
+#pragma clang diagnostic pop
 }
 
 @end