Implementing sign-in promo histograms for bookmark

ios/chrome/browser/ui/authentication/signin_promo_view_mediator.mm

 // Copyright 2017 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/authentication/signin_promo_view_mediator.h"
 
 #include "base/memory/ptr_util.h"
+#include "base/metrics/histogram_macros.h"
 #include "base/metrics/user_metrics.h"
 #include "base/metrics/user_metrics_action.h"
 #include "base/strings/sys_string_conversions.h"
+#include "components/prefs/pref_service.h"
+#include "ios/chrome/browser/browser_state/chrome_browser_state.h"
+#include "ios/chrome/browser/pref_names.h"
 #include "ios/chrome/browser/signin/chrome_identity_service_observer_bridge.h"
 #import "ios/chrome/browser/ui/authentication/signin_promo_view_configurator.h"
 #import "ios/chrome/browser/ui/authentication/signin_promo_view_consumer.h"
 #import "ios/chrome/browser/ui/commands/UIKit+ChromeExecuteCommand.h"
 #import "ios/chrome/browser/ui/commands/show_signin_command.h"
 #include "ios/chrome/grit/ios_strings.h"
 #import "ios/public/provider/chrome/browser/chrome_browser_provider.h"
 #import "ios/public/provider/chrome/browser/signin/chrome_identity.h"
 #import "ios/public/provider/chrome/browser/signin/signin_resources_provider.h"
 #import "ios/third_party/material_components_ios/src/components/Buttons/src/MaterialButtons.h"
 #include "ui/base/l10n/l10n_util.h"
 
 #if !defined(__has_feature) || !__has_feature(objc_arc)
 #error "This file requires ARC support."
 #endif
 
 namespace {
+const int kAutomaticSigninPromoViewDismissCount = 20;
+
 void RecordSigninUserActionForAccessPoint(
     signin_metrics::AccessPoint access_point) {
   switch (access_point) {
     case signin_metrics::AccessPoint::ACCESS_POINT_BOOKMARK_MANAGER:
       base::RecordAction(
           base::UserMetricsAction("Signin_Signin_FromBookmarkManager"));
       break;
     case signin_metrics::AccessPoint::ACCESS_POINT_RECENT_TABS:
       base::RecordAction(
           base::UserMetricsAction("Signin_Signin_FromRecentTabs"));
@@ skipping 51 matching lines @@
     case signin_metrics::AccessPoint::ACCESS_POINT_RECENT_TABS:
       base::RecordAction(
           base::UserMetricsAction("Signin_SigninNewAccount_FromRecentTabs"));
       break;
     default:
       NOTREACHED() << "Unexpected value for access point "
                    << static_cast<int>(access_point);
       break;
   }
 }
+
+enum class SigninPromoViewState {
+  Unused = 0,
+  Visible,
+  Hidden,
+  SigninStarted,
+  Dismissed,
+};
 }  // namespace
 
 @interface SigninPromoViewMediator ()<ChromeIdentityServiceObserver>
 @end
 
 @implementation SigninPromoViewMediator {
+  ios::ChromeBrowserState* _browserState;
   std::unique_ptr<ChromeIdentityServiceObserverBridge> _identityServiceObserver;
   UIImage* _identityAvatar;
+  SigninPromoViewState _signinPromoViewState;
 }
 
 @synthesize consumer = _consumer;
 @synthesize defaultIdentity = _defaultIdentity;
 @synthesize accessPoint = _accessPoint;
+@synthesize displayedCountPreferenceKey = _displayedCountPreferenceKey;
+@synthesize alreadySeenSigninViewPreferenceKey =
+    _alreadySeenSigninViewPreferenceKey;
+@synthesize dismissalCountHistogramName = _dismissalCountHistogramName;
+@synthesize countTilSigninHistogramName = _countTilSigninHistogramName;
+@synthesize countTilXHistogramName = _countTilXHistogramName;
 
-- (instancetype)init {
+- (instancetype)initWithBrowserState:(ios::ChromeBrowserState*)browserState {
   self = [super init];
   if (self) {
+    _browserState = browserState;
     NSArray* identities = ios::GetChromeBrowserProvider()
                               ->GetChromeIdentityService()
                               ->GetAllIdentitiesSortedForDisplay();
     if (identities.count != 0) {
       [self selectIdentity:identities[0]];
     }
     _identityServiceObserver =
         base::MakeUnique<ChromeIdentityServiceObserverBridge>(self);
   }
   return self;
 }
 
+- (void)dealloc {
+  if (!_displayedCountPreferenceKey.empty() &&
+      !_dismissalCountHistogramName.empty() &&
+      (_signinPromoViewState == SigninPromoViewState::Visible ||
+       _signinPromoViewState == SigninPromoViewState::Hidden)) {
+    PrefService* prefs = _browserState->GetPrefs();
+    int displayedCount = prefs->GetInteger(_displayedCountPreferenceKey);
+    UMA_HISTOGRAM_COUNTS_100(_dismissalCountHistogramName, displayedCount);
+  }
+}
+
 - (SigninPromoViewConfigurator*)createConfigurator {
   if (_defaultIdentity) {
     return [[SigninPromoViewConfigurator alloc]
         initWithUserEmail:_defaultIdentity.userEmail
              userFullName:_defaultIdentity.userFullName
                 userImage:_identityAvatar];
   }
   return [[SigninPromoViewConfigurator alloc] initWithUserEmail:nil
                                                    userFullName:nil
                                                       userImage:nil];
@@ skipping 20 matching lines @@
   _identityAvatar = identityAvatar;
   [self sendConsumerNotificationWithIdentityChanged:NO];
 }
 
 - (void)sendConsumerNotificationWithIdentityChanged:(BOOL)identityChanged {
   SigninPromoViewConfigurator* configurator = [self createConfigurator];
   [_consumer configureSigninPromoWithConfigurator:configurator
                                   identityChanged:identityChanged];
 }
 
+- (void)sendCountTillSigninHistogram {
+  DCHECK(_signinPromoViewState != SigninPromoViewState::Dismissed ||
+         _signinPromoViewState != SigninPromoViewState::Unused);
+  _signinPromoViewState = SigninPromoViewState::SigninStarted;
+  if (_displayedCountPreferenceKey.empty() ||
+      _countTilSigninHistogramName.empty())
+    return;
+  PrefService* prefs = _browserState->GetPrefs();
+  int displayedCount = prefs->GetInteger(_displayedCountPreferenceKey);
+  UMA_HISTOGRAM_COUNTS_100(_countTilSigninHistogramName, displayedCount);
+}
+
+- (void)signinPromoViewVisible {
+  DCHECK(_signinPromoViewState != SigninPromoViewState::Dismissed);
+  if (_signinPromoViewState == SigninPromoViewState::Visible)
+    return;
+  _signinPromoViewState = SigninPromoViewState::Visible;
+  if (_displayedCountPreferenceKey.empty())
+    return;
+  PrefService* prefs = _browserState->GetPrefs();
+  int displayedCount = prefs->GetInteger(_displayedCountPreferenceKey);
+  ++displayedCount;
+  prefs->SetInteger(_displayedCountPreferenceKey, displayedCount);
+  if (displayedCount >= kAutomaticSigninPromoViewDismissCount &&
+      !_alreadySeenSigninViewPreferenceKey.empty()) {
+    PrefService* prefs = _browserState->GetPrefs();
+    prefs->SetBoolean(prefs::kIosBookmarkPromoAlreadySeen, true);
+  }
+}
+
+- (void)signinPromoViewHidden {
+  DCHECK(_signinPromoViewState != SigninPromoViewState::Unused ||
+         _signinPromoViewState != SigninPromoViewState::Dismissed);
+  if (_signinPromoViewState != SigninPromoViewState::Visible)
+    return;
+  _signinPromoViewState = SigninPromoViewState::Hidden;
+}
+
+- (void)signinPromoViewDismissed {
+  DCHECK(_signinPromoViewState != SigninPromoViewState::Unused ||
+         _signinPromoViewState != SigninPromoViewState::Hidden);
+  _signinPromoViewState = SigninPromoViewState::Dismissed;
+  if (_displayedCountPreferenceKey.empty() || _countTilXHistogramName.empty())
+    return;
+  PrefService* prefs = _browserState->GetPrefs();
+  int displayedCount = prefs->GetInteger(_displayedCountPreferenceKey);
+  UMA_HISTOGRAM_COUNTS_100(_countTilXHistogramName, displayedCount);
+}
+
 #pragma mark - ChromeIdentityServiceObserver
 
 - (void)onIdentityListChanged {
   ChromeIdentity* newIdentity = nil;
   NSArray* identities = ios::GetChromeBrowserProvider()
                             ->GetChromeIdentityService()
                             ->GetAllIdentitiesSortedForDisplay();
   if (identities.count != 0) {
     newIdentity = identities[0];
   }
   if (newIdentity != _defaultIdentity) {
     [self selectIdentity:newIdentity];
     [self sendConsumerNotificationWithIdentityChanged:YES];
   }
 }
 
 - (void)onProfileUpdate:(ChromeIdentity*)identity {
   if (identity == _defaultIdentity) {
     [self sendConsumerNotificationWithIdentityChanged:NO];
   }
 }
 
 #pragma mark - SigninPromoViewDelegate
 
 - (void)signinPromoViewDidTapSigninWithNewAccount:
     (SigninPromoView*)signinPromoView {
   DCHECK(!_defaultIdentity);
+  [self sendCountTillSigninHistogram];
   RecordSigninUserActionForAccessPoint(_accessPoint);
   RecordSigninNewAccountUserActionForAccessPoint(_accessPoint);
   ShowSigninCommand* command = [[ShowSigninCommand alloc]
       initWithOperation:AUTHENTICATION_OPERATION_SIGNIN
             accessPoint:_accessPoint
             promoAction:signin_metrics::PromoAction::PROMO_ACTION_NEW_ACCOUNT];
   [signinPromoView chromeExecuteCommand:command];
 }
 
 - (void)signinPromoViewDidTapSigninWithDefaultAccount:
     (SigninPromoView*)signinPromoView {
   DCHECK(_defaultIdentity);
+  [self sendCountTillSigninHistogram];
   RecordSigninUserActionForAccessPoint(_accessPoint);
   RecordSigninDefaultUserActionForAccessPoint(_accessPoint);
   ShowSigninCommand* command = [[ShowSigninCommand alloc]
       initWithOperation:AUTHENTICATION_OPERATION_SIGNIN
                identity:_defaultIdentity
             accessPoint:_accessPoint
             promoAction:signin_metrics::PromoAction::PROMO_ACTION_WITH_DEFAULT
                callback:nil];
   [signinPromoView chromeExecuteCommand:command];
 }
 
 - (void)signinPromoViewDidTapSigninWithOtherAccount:
     (SigninPromoView*)signinPromoView {
   DCHECK(_defaultIdentity);
+  [self sendCountTillSigninHistogram];
   RecordSigninNotDefaultUserActionForAccessPoint(_accessPoint);
   RecordSigninUserActionForAccessPoint(_accessPoint);
   ShowSigninCommand* command = [[ShowSigninCommand alloc]
       initWithOperation:AUTHENTICATION_OPERATION_SIGNIN
             accessPoint:_accessPoint
             promoAction:signin_metrics::PromoAction::PROMO_ACTION_NOT_DEFAULT];
   [signinPromoView chromeExecuteCommand:command];
 }
 
 @end