[ObjC ARC] Converts ios/chrome/browser/ui:unit_tests to ARC.

ios/chrome/browser/ui/browser_view_controller_unittest.mm

 // Copyright 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import <Foundation/Foundation.h>
 #import <PassKit/PassKit.h>
 
 #include <memory>
 
 #include "base/command_line.h"
 #include "base/files/file_path.h"
 #include "base/files/file_util.h"
-#include "base/mac/scoped_nsautorelease_pool.h"
-#include "base/mac/scoped_nsobject.h"
 #include "base/memory/ptr_util.h"
 #include "base/path_service.h"
 #include "base/strings/sys_string_conversions.h"
 #include "components/bookmarks/test/bookmark_test_helpers.h"
 #include "components/prefs/testing_pref_service.h"
 #include "components/search_engines/template_url_service.h"
 #include "components/sessions/core/tab_restore_service.h"
 #include "components/toolbar/test_toolbar_model.h"
 #include "ios/chrome/browser/bookmarks/bookmark_model_factory.h"
 #import "ios/chrome/browser/browser_state/test_chrome_browser_state.h"
@@ skipping 35 matching lines @@
 #include "net/url_request/url_request_test_util.h"
 #include "testing/gmock/include/gmock/gmock.h"
 #include "testing/gtest/include/gtest/gtest.h"
 #include "testing/gtest_mac.h"
 #import "third_party/ocmock/OCMock/OCMock.h"
 #include "third_party/ocmock/gtest_support.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 #include "ui/base/test/ios/ui_image_test_utils.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 using web::NavigationManagerImpl;
 using web::WebStateImpl;
 
 // Private methods in BrowserViewController to test.
 @interface BrowserViewController (
     Testing)<CRWNativeContentProvider, PassKitDialogProvider, ShareToDelegate>
 - (void)pageLoadStarted:(NSNotification*)notification;
 - (void)pageLoadComplete:(NSNotification*)notification;
 - (void)tabSelected:(Tab*)tab;
 - (void)tabDeselected:(NSNotification*)notification;
@@ skipping 92 matching lines @@
         ios::TemplateURLServiceFactory::GetInstance(),
         ios::TemplateURLServiceFactory::GetDefaultFactory());
     chrome_browser_state_ = test_cbs_builder.Build();
     chrome_browser_state_->CreateBookmarkModel(false);
     bookmarks::BookmarkModel* bookmark_model =
         ios::BookmarkModelFactory::GetForBrowserState(
             chrome_browser_state_.get());
     bookmarks::test::WaitForBookmarkModelToLoad(bookmark_model);
 
     // Set up mock TabModel, Tab, and CRWWebController.
-    base::scoped_nsobject<id> tabModel([[BVCTestTabModel alloc] init]);
-    base::scoped_nsobject<id> currentTab([[BVCTestTabMock alloc]
-        initWithRepresentedObject:[OCMockObject niceMockForClass:[Tab class]]]);
+    id tabModel = [[BVCTestTabModel alloc] init];
+    id currentTab = [[BVCTestTabMock alloc]
+        initWithRepresentedObject:[OCMockObject niceMockForClass:[Tab class]]];
     id webControllerMock =
         [OCMockObject niceMockForClass:[CRWWebController class]];
 
     // Stub methods for TabModel.
     NSUInteger tabCount = 1;
     [[[tabModel stub] andReturnValue:OCMOCK_VALUE(tabCount)] count];
     BOOL enabled = YES;
     [[[tabModel stub] andReturnValue:OCMOCK_VALUE(enabled)] webUsageEnabled];
     [[[tabModel stub] andReturn:currentTab] currentTab];
     [[[tabModel stub] andReturn:currentTab] tabAtIndex:0];
     [[tabModel stub] addObserver:[OCMArg any]];
     [[tabModel stub] removeObserver:[OCMArg any]];
     [[tabModel stub] saveSessionImmediately:NO];
     [[tabModel stub] setCurrentTab:[OCMArg any]];
     [[tabModel stub] closeAllTabs];
 
     // Stub methods for Tab.
-    UIView* dummyView = [[[UIView alloc] initWithFrame:CGRectZero] autorelease];
+    UIView* dummyView = [[UIView alloc] initWithFrame:CGRectZero];
     [[[currentTab stub] andReturn:dummyView] view];
     [[[currentTab stub] andReturn:webControllerMock] webController];
 
     web::WebState::CreateParams params(chrome_browser_state_.get());
     std::unique_ptr<web::WebState> webState = web::WebState::Create(params);
     webStateImpl_.reset(static_cast<web::WebStateImpl*>(webState.release()));
     [currentTab setWebState:webStateImpl_.get()];
     webStateImpl_->SetWebController(webControllerMock);
 
     // Set up mock ShareController.
     id shareController =
         [OCMockObject niceMockForProtocol:@protocol(ShareProtocol)];
-    shareController_.reset([shareController retain]);
+    shareController_ = shareController;
 
     id passKitController =
         [OCMockObject niceMockForClass:[PKAddPassesViewController class]];
-    passKitViewController_.reset([passKitController retain]);
+    passKitViewController_ = passKitController;
 
     // Set up a fake toolbar model for the dependency factory to return.
     // It will be owned (and destroyed) by the BVC.
     toolbarModelIOS_ = new TestToolbarModelIOS();
 
     // Set up a stub dependency factory.
     id factory = [OCMockObject
         mockForClass:[BrowserViewControllerDependencyFactory class]];
     [[[factory stub] andReturn:nil]
         newTabStripControllerWithTabModel:[OCMArg any]];
     [[[factory stub] andReturn:nil] newPreloadController];
     [[[factory stub] andReturnValue:OCMOCK_VALUE(toolbarModelIOS_)]
         newToolbarModelIOSWithDelegate:static_cast<ToolbarModelDelegateIOS*>(
                                            [OCMArg anyPointer])];
     [[[factory stub] andReturn:nil]
         newWebToolbarControllerWithDelegate:[OCMArg any]
                                   urlLoader:[OCMArg any]
                             preloadProvider:[OCMArg any]];
-    [[[factory stub] andReturn:shareController_.get()] shareControllerInstance];
-    [[[factory stub] andReturn:passKitViewController_.get()]
+    [[[factory stub] andReturn:shareController_] shareControllerInstance];
+    [[[factory stub] andReturn:passKitViewController_]
         newPassKitViewControllerForPass:nil];
     [[[factory stub] andReturn:nil] showPassKitErrorInfoBarForManager:nil];
 
-    webController_.reset([webControllerMock retain]);
-    tabModel_.reset([tabModel retain]);
-    tab_.reset([currentTab retain]);
-    dependencyFactory_.reset([factory retain]);
-    bvc_.reset([[BrowserViewController alloc]
+    webController_ = webControllerMock;
+    tabModel_ = tabModel;
+    tab_ = currentTab;
+    dependencyFactory_ = factory;
+    bvc_ = [[BrowserViewController alloc]
          initWithTabModel:tabModel_
              browserState:chrome_browser_state_.get()
-        dependencyFactory:factory]);
+        dependencyFactory:factory];
 
     // Load TemplateURLService.
     TemplateURLService* template_url_service =
         ios::TemplateURLServiceFactory::GetForBrowserState(
             chrome_browser_state_.get());
     template_url_service->Load();
 
     // Force the view to load.
     UIWindow* window = [[UIWindow alloc] initWithFrame:CGRectZero];
     [window addSubview:[bvc_ view]];
-    window_.reset(window);
+    window_ = window;
   }
 
   void TearDown() override {
     [[bvc_ view] removeFromSuperview];
     BlockCleanupTest::TearDown();
   }
 
-  base::scoped_nsobject<GenericChromeCommand> GetCommandWithTag(NSInteger tag) {
-    base::scoped_nsobject<GenericChromeCommand> command(
-        [[GenericChromeCommand alloc] initWithTag:tag]);
-    return command;
+  GenericChromeCommand* GetCommandWithTag(NSInteger tag) {
+    return [[GenericChromeCommand alloc] initWithTag:tag];
   }
 
   MOCK_METHOD0(OnCompletionCalled, void());
 
   web::TestWebThreadBundle thread_bundle_;
   IOSChromeScopedTestingLocalState local_state_;
   std::unique_ptr<TestChromeBrowserState> chrome_browser_state_;
   std::unique_ptr<WebStateImpl> webStateImpl_;
-  base::scoped_nsobject<CRWWebController> webController_;
-  base::scoped_nsobject<Tab> tab_;
-  base::scoped_nsobject<TabModel> tabModel_;
+  CRWWebController* webController_;
+  Tab* tab_;
+  TabModel* tabModel_;
   ToolbarModelIOS* toolbarModelIOS_;
-  base::scoped_nsprotocol<id<ShareProtocol>> shareController_;
-  base::scoped_nsobject<PKAddPassesViewController> passKitViewController_;
-  base::scoped_nsobject<OCMockObject> dependencyFactory_;
-  base::scoped_nsobject<BrowserViewController> bvc_;
-  base::scoped_nsobject<UIWindow> window_;
+  id<ShareProtocol> shareController_;
+  PKAddPassesViewController* passKitViewController_;
+  OCMockObject* dependencyFactory_;
+  BrowserViewController* bvc_;
+  UIWindow* window_;
 };
 
 // TODO(crbug.com/228714): These tests pretty much only tested that BVC passed
 // notifications on to the toolbar, and that the toolbar worked correctly. The
 // former should be an integration test, and the latter should be a toolbar
 // test.  Leaving DISABLED_ for now to remind us to move them to toolbar tests.
 TEST_F(BrowserViewControllerTest, DISABLED_TestPageLoadStarted) {
   NSDictionary* userInfoWithThisTab =
       [NSDictionary dictionaryWithObject:tab_ forKey:kTabModelTabKey];
   NSNotification* notification = [NSNotification
       notificationWithName:kTabModelTabWillStartLoadingNotification
                     object:nil
                   userInfo:userInfoWithThisTab];
   [bvc_ pageLoadStarted:notification];
   EXPECT_TRUE([bvc_ testing_isLoading]);
 }
 
 TEST_F(BrowserViewControllerTest, DISABLED_TestPageLoadComplete) {
   NSDictionary* userInfoWithThisTab =
       [NSDictionary dictionaryWithObject:tab_ forKey:kTabModelTabKey];
   NSNotification* notification = [NSNotification
       notificationWithName:kTabModelTabDidFinishLoadingNotification
                     object:nil
                   userInfo:userInfoWithThisTab];
   [bvc_ pageLoadComplete:notification];
   EXPECT_FALSE([bvc_ testing_isLoading]);
 }
 
 TEST_F(BrowserViewControllerTest, TestTabSelected) {
-  id tabMock = (id)tab_.get();
+  id tabMock = (id)tab_;
   [[tabMock expect] wasShown];
   [bvc_ tabSelected:tab_];
   EXPECT_EQ([[tab_ view] superview], static_cast<UIView*>([bvc_ contentArea]));
   EXPECT_OCMOCK_VERIFY(tabMock);
 }
 
 TEST_F(BrowserViewControllerTest, TestTabSelectedIsNewTab) {
-  base::scoped_nsobject<id> block([^{
+  id block = [^{
     return GURL(kChromeUINewTabURL);
-  } copy]);
-  id tabMock = (id)tab_.get();
+  } copy];
+  id tabMock = (id)tab_;
   [tabMock onSelector:@selector(url) callBlockExpectation:block];
   [[tabMock expect] wasShown];
   [bvc_ tabSelected:tab_];
   EXPECT_EQ([[tab_ view] superview], static_cast<UIView*>([bvc_ contentArea]));
   EXPECT_OCMOCK_VERIFY(tabMock);
 }
 
 TEST_F(BrowserViewControllerTest, TestTabDeselected) {
-  OCMockObject* tabMock = static_cast<OCMockObject*>(tab_.get());
+  OCMockObject* tabMock = static_cast<OCMockObject*>(tab_);
   [[tabMock expect] wasHidden];
   NSDictionary* userInfoWithThisTab =
       [NSDictionary dictionaryWithObject:tab_ forKey:kTabModelTabKey];
   NSNotification* notification =
       [NSNotification notificationWithName:kTabModelTabDeselectedNotification
                                     object:nil
                                   userInfo:userInfoWithThisTab];
   [bvc_ tabDeselected:notification];
   EXPECT_OCMOCK_VERIFY(tabMock);
 }
@@ skipping 39 matching lines @@
   EXPECT_FALSE([[bvc_ typingShield] isHidden]);
   [bvc_ shieldWasTapped:nil];
   EXPECT_TRUE([[bvc_ typingShield] superview] == nil);
   EXPECT_TRUE([[bvc_ typingShield] isHidden]);
 }
 
 // Verifies that editing the omnimbox while the page is loading will stop the
 // load on a handset, but not stop the load on a tablet.
 TEST_F(BrowserViewControllerTest,
        TestLocationBarBeganEdit_whenPageLoadIsInProgress) {
-  OCMockObject* tabMock = static_cast<OCMockObject*>(tab_.get());
+  OCMockObject* tabMock = static_cast<OCMockObject*>(tab_);
 
   // Have the TestToolbarModel indicate that a page load is in progress.
   static_cast<TestToolbarModelIOS*>(toolbarModelIOS_)->set_is_loading(true);
 
   // The tab should only stop loading on handsets.
   if (!IsIPadIdiom())
-    [[static_cast<OCMockObject*>(webController_.get()) expect] stopLoading];
+    [[static_cast<OCMockObject*>(webController_) expect] stopLoading];
   [bvc_ locationBarBeganEdit:nil];
 
-  EXPECT_OCMOCK_VERIFY(static_cast<OCMockObject*>(webController_.get()));
+  EXPECT_OCMOCK_VERIFY(static_cast<OCMockObject*>(webController_));
   EXPECT_OCMOCK_VERIFY(tabMock);
 }
 
 // Verifies that editing the omnibox when the page is not loading will not try
 // to stop the load on a handset or a tablet.
 TEST_F(BrowserViewControllerTest,
        TestLocationBarBeganEdit_whenPageLoadIsComplete) {
-  OCMockObject* tabMock = static_cast<OCMockObject*>(tab_.get());
+  OCMockObject* tabMock = static_cast<OCMockObject*>(tab_);
 
   // Have the TestToolbarModel indicate that the page load is complete.
   static_cast<TestToolbarModelIOS*>(toolbarModelIOS_)->set_is_loading(false);
 
   // Don't set any expectation for stopLoading to be called on the mock tab.
   [bvc_ locationBarBeganEdit:nil];
 
   EXPECT_OCMOCK_VERIFY(tabMock);
 }
 
 // Verifies that BVC invokes -shareURL on ShareController with the correct
 // parameters in response to the IDC_SHARE_PAGE command.
 TEST_F(BrowserViewControllerTest, TestSharePageCommandHandling) {
   GURL expectedUrl("http://www.testurl.net");
   NSString* expectedTitle = @"title";
-  static_cast<BVCTestTabMock*>(tab_.get()).lastCommittedURL = expectedUrl;
-  static_cast<BVCTestTabMock*>(tab_.get()).visibleURL = expectedUrl;
-  OCMockObject* tabMock = static_cast<OCMockObject*>(tab_.get());
+  static_cast<BVCTestTabMock*>(tab_).lastCommittedURL = expectedUrl;
+  static_cast<BVCTestTabMock*>(tab_).visibleURL = expectedUrl;
+  OCMockObject* tabMock = static_cast<OCMockObject*>(tab_);
   ios::ChromeBrowserState* ptr = chrome_browser_state_.get();
   [[[tabMock stub] andReturnValue:OCMOCK_VALUE(ptr)] browserState];
   [[[tabMock stub] andReturn:expectedTitle] title];
   [[[tabMock stub] andReturn:expectedTitle] originalTitle];
 
   UIImage* tabSnapshot = ui::test::uiimage_utils::UIImageWithSizeAndSolidColor(
       CGSizeMake(300, 400), [UIColor blueColor]);
   [[[tabMock stub] andReturn:tabSnapshot] generateSnapshotWithOverlay:NO
                                                      visibleFrameOnly:YES];
   OCMockObject* shareControllerMock =
-      static_cast<OCMockObject*>(shareController_.get());
+      static_cast<OCMockObject*>(shareController_);
   // Passing non zero/nil |fromRect| and |inView| parameters to satisfy protocol
   // requirements.
   BOOL (^shareDataChecker)
   (id value) = ^BOOL(id value) {
     if (![value isMemberOfClass:ShareToData.class])
       return NO;
     ShareToData* shareToData = static_cast<ShareToData*>(value);
     CGSize size = CGSizeMake(40, 40);
     BOOL thumbnailDataIsEqual = ui::test::uiimage_utils::UIImagesAreEqual(
         shareToData.thumbnailGenerator(size),
@@ skipping 15 matching lines @@
   [bvc_ chromeExecuteCommand:GetCommandWithTag(IDC_SHARE_PAGE)];
   EXPECT_OCMOCK_VERIFY(shareControllerMock);
 }
 
 // Verifies that BVC does not invoke -shareURL on ShareController in response
 // to the IDC_SHARE_PAGE command if tab is in the process of being closed.
 TEST_F(BrowserViewControllerTest, TestSharePageWhenClosing) {
   GURL expectedUrl("http://www.testurl.net");
   NSString* expectedTitle = @"title";
   // Sets WebState to nil because [tab close] clears the WebState.
-  static_cast<BVCTestTabMock*>(tab_.get()).webState = nil;
-  static_cast<BVCTestTabMock*>(tab_.get()).lastCommittedURL = expectedUrl;
-  static_cast<BVCTestTabMock*>(tab_.get()).visibleURL = expectedUrl;
-  OCMockObject* tabMock = static_cast<OCMockObject*>(tab_.get());
+  static_cast<BVCTestTabMock*>(tab_).webState = nil;
+  static_cast<BVCTestTabMock*>(tab_).lastCommittedURL = expectedUrl;
+  static_cast<BVCTestTabMock*>(tab_).visibleURL = expectedUrl;
+  OCMockObject* tabMock = static_cast<OCMockObject*>(tab_);
   [[[tabMock stub] andReturn:expectedTitle] title];
   [[[tabMock stub] andReturn:expectedTitle] originalTitle];
   // Explicitly disallow the execution of the ShareController.
   OCMockObject* shareControllerMock =
-      static_cast<OCMockObject*>(shareController_.get());
+      static_cast<OCMockObject*>(shareController_);
   [[shareControllerMock reject]
         shareWithData:[OCMArg any]
            controller:bvc_
          browserState:chrome_browser_state_.get()
       shareToDelegate:bvc_
              fromRect:[bvc_ testing_shareButtonAnchorRect]
                inView:[OCMArg any]];
   [bvc_ chromeExecuteCommand:GetCommandWithTag(IDC_SHARE_PAGE)];
   EXPECT_OCMOCK_VERIFY(shareControllerMock);
 }
 
 // Verifies that BVC instantiates a bubble to show the given success message on
 // receiving a -shareDidComplete callback for a successful share.
 TEST_F(BrowserViewControllerTest, TestShareDidCompleteWithSuccess) {
   NSString* completionMessage = @"Completion!";
   [[dependencyFactory_ expect] showSnackbarWithMessage:completionMessage];
 
   [bvc_ shareDidComplete:ShareTo::SHARE_SUCCESS
        completionMessage:completionMessage];
   EXPECT_OCMOCK_VERIFY(dependencyFactory_);
 }
 
 // Verifies that BVC shows an alert with the proper error message on
 // receiving a -shareDidComplete callback for a failed share.
 TEST_F(BrowserViewControllerTest, TestShareDidCompleteWithError) {
   [[dependencyFactory_ reject] showSnackbarWithMessage:OCMOCK_ANY];
-  base::scoped_nsobject<OCMockObject> mockCoordinator(
-      [[OCMockObject niceMockForClass:[AlertCoordinator class]] retain]);
+  OCMockObject* mockCoordinator =
+      [OCMockObject niceMockForClass:[AlertCoordinator class]];
   AlertCoordinator* alertCoordinator =
-      static_cast<AlertCoordinator*>(mockCoordinator.get());
+      static_cast<AlertCoordinator*>(mockCoordinator);
   NSString* errorTitle =
       l10n_util::GetNSString(IDS_IOS_SHARE_TO_ERROR_ALERT_TITLE);
   NSString* errorMessage = l10n_util::GetNSString(IDS_IOS_SHARE_TO_ERROR_ALERT);
   [[[dependencyFactory_ expect] andReturn:alertCoordinator]
       alertCoordinatorWithTitle:errorTitle
                         message:errorMessage
                  viewController:OCMOCK_ANY];
   [static_cast<AlertCoordinator*>([mockCoordinator expect]) start];
 
   [bvc_ shareDidComplete:ShareTo::SHARE_ERROR completionMessage:@"dummy"];
@@ skipping 34 matching lines @@
   NSData* badPassKitObject = [NSData
       dataWithContentsOfFile:base::SysUTF8ToNSString(bad_pass_path.value())];
   EXPECT_TRUE(badPassKitObject);
   [[dependencyFactory_ reject] newPassKitViewControllerForPass:OCMOCK_ANY];
   [bvc_ presentPassKitDialog:badPassKitObject];
   EXPECT_OCMOCK_VERIFY(dependencyFactory_);
 }
 
 TEST_F(BrowserViewControllerTest, TestClearPresentedState) {
   OCMockObject* shareControllerMock =
-      static_cast<OCMockObject*>(shareController_.get());
+      static_cast<OCMockObject*>(shareController_);
   [[shareControllerMock expect] cancelShareAnimated:NO];
   EXPECT_CALL(*this, OnCompletionCalled());
   [bvc_ clearPresentedStateWithCompletion:^{
     this->OnCompletionCalled();
   }];
   EXPECT_OCMOCK_VERIFY(shareControllerMock);
 }
 
 }  // namespace