[ObjC ARC] Converts ios/chrome/browser/passwords:passwords to ARC.

ios/chrome/browser/passwords/password_generation_agent.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/passwords/password_generation_agent.h"
 
 #include <stddef.h>
 
-#import "base/ios/weak_nsobject.h"
 #include "base/mac/foundation_util.h"
 #include "base/mac/scoped_block.h"
-#include "base/mac/scoped_nsobject.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/strings/utf_string_conversions.h"
 #include "components/autofill/core/browser/password_generator.h"
 #include "components/autofill/core/common/form_data.h"
 #include "components/autofill/core/common/password_form.h"
 #include "components/autofill/core/common/password_generation_util.h"
 #import "components/autofill/ios/browser/js_suggestion_manager.h"
 #include "components/password_manager/core/browser/password_manager.h"
 #include "google_apis/gaia/gaia_urls.h"
 #import "ios/chrome/browser/autofill/form_input_accessory_view_controller.h"
 #include "ios/chrome/browser/experimental_flags.h"
 #import "ios/chrome/browser/passwords/js_password_manager.h"
 #import "ios/chrome/browser/passwords/password_generation_edit_view.h"
 #import "ios/chrome/browser/ui/commands/generic_chrome_command.h"
 #include "ios/chrome/browser/ui/commands/ios_command_ids.h"
 #include "ios/web/public/url_scheme_util.h"
 #import "ios/web/public/web_state/js/crw_js_injection_receiver.h"
 #include "ios/web/public/web_state/web_state.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "url/gurl.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 
 // Target length of generated passwords.
 const int kGeneratedPasswordLength = 20;
 
 // The minimum number of text fields that a form needs to be considered as
 // an account creation form.
 const size_t kMinimumTextFieldsForAccountCreation = 3;
 
 // Returns true if |urls| contains |url|.
@@ skipping 82 matching lines @@
   // Stores the account creation form we detected on the page.
   std::unique_ptr<autofill::PasswordForm> _possibleAccountCreationForm;
 
   // Password fields found in |_possibleAccountCreationForm|.
   std::vector<autofill::FormFieldData> _passwordFields;
 
   // The password field that triggers the password generation UI.
   std::unique_ptr<autofill::FormFieldData> _passwordGenerationField;
 
   // Wrapper for suggestion JavaScript. Used for form navigation.
-  base::scoped_nsobject<JsSuggestionManager> _JSSuggestionManager;
+  JsSuggestionManager* _JSSuggestionManager;
 
   // Wrapper for passwords JavaScript. Used for form filling.
-  base::scoped_nsobject<JsPasswordManager> _JSPasswordManager;
+  JsPasswordManager* _JSPasswordManager;
 
   // Driver that is passed to PasswordManager when a password is generated.
   password_manager::PasswordManagerDriver* _passwordManagerDriver;
 
   // PasswordManager to inform when a password is generated.
   password_manager::PasswordManager* _passwordManager;
 
   // Callback to update the custom keyboard accessory view. Will be non-nil when
   // this PasswordGenerationAgent controls the keyboard accessory view.
-  base::mac::ScopedBlock<AccessoryViewReadyCompletion>
-      _accessoryViewReadyCompletion;
+  AccessoryViewReadyCompletion _accessoryViewReadyCompletion;
 
   // The delegate for controlling the password generation UI.
-  base::scoped_nsprotocol<id<PasswordsUiDelegate>> _passwords_ui_delegate;
+  id<PasswordsUiDelegate> _passwords_ui_delegate;
 
   // The password that was generated and accepted by the user.
-  base::scoped_nsobject<NSString> _generatedPassword;
+  NSString* _generatedPassword;
 }
 
 - (instancetype)init {
   NOTREACHED();
   return nil;
 }
 
 - (instancetype)
          initWithWebState:(web::WebState*)webState
           passwordManager:(password_manager::PasswordManager*)passwordManager
@@ skipping 21 matching lines @@
         JSPasswordManager:(JsPasswordManager*)JSPasswordManager
       JSSuggestionManager:(JsSuggestionManager*)JSSuggestionManager
       passwordsUiDelegate:(id<PasswordsUiDelegate>)UIDelegate {
   DCHECK([NSThread isMainThread]);
   DCHECK(webState);
   DCHECK_EQ([self class], [PasswordGenerationAgent class]);
   self = [super init];
   if (self) {
     _passwordManager = passwordManager;
     _passwordManagerDriver = driver;
-    _JSPasswordManager.reset([JSPasswordManager retain]);

[vabr (Chromium), 2017/06/13 15:23:52]

For my own education -- what does the "retain" message do to a class? I know
that for objects it would move the ownership of that object to the caller. But I
don't have any idea what it does on a class, and why it is equivalent to
resetting the pointer in ARC.

[marq (ping after 24h), 2017/06/13 17:39:04]

These aren't classes (where there typically isn't a defined +retain); they're
badly-named parameters, which I will fix.

-    _JSSuggestionManager.reset([JSSuggestionManager retain]);
+    _JSPasswordManager = nil;
+    _JSSuggestionManager = nil;
     _webStateObserverBridge.reset(
         new web::WebStateObserverBridge(webState, self));
-    _passwords_ui_delegate.reset([UIDelegate retain]);
+    _passwords_ui_delegate = nil;
   }
   return self;
 }
 
 - (void)dealloc {
   DCHECK([NSThread isMainThread]);
-  [super dealloc];
+  ;

[vabr (Chromium), 2017/06/13 15:23:52]

nit: Remove this line.

[marq (ping after 24h), 2017/06/13 17:39:04]

Done.

 }
 
 - (autofill::PasswordForm*)possibleAccountCreationForm {
   return _possibleAccountCreationForm.get();
 }
 
 - (const std::vector<autofill::FormFieldData>&)passwordFields {
   return _passwordFields;
 }
 
 - (autofill::FormFieldData*)passwordGenerationField {
   return _passwordGenerationField.get();
 }
 
 - (void)clearState {
   [self hideAlert];
   _allowedGenerationFormOrigins.clear();
   _possibleAccountCreationForm.reset();
   _passwordFields.clear();
   _passwordGenerationField.reset();
-  _generatedPassword.reset();
+  _generatedPassword = nil;
 }
 
 - (BOOL)formHasGAIARealm:(const autofill::PasswordForm&)form {
   // Do not generate password for GAIA since it is used to retrieve the
   // generated paswords.
   return GURL(form.signon_realm) ==
          GaiaUrls::GetInstance()->gaia_login_form_realm();
 }
 
 - (BOOL)formHasEnoughTextFieldsForAccountCreation:
@@ skipping 77 matching lines @@
 - (NSString*)passwordGenerationFormName {
   return base::SysUTF16ToNSString(_possibleAccountCreationForm->form_data.name);
 }
 
 - (void)hideAlert {
   [_passwords_ui_delegate hideGenerationAlert];
 }
 
 - (UIView*)currentAccessoryView {
   return [_generatedPassword length] > 0
-             ? [[[PasswordGenerationEditView alloc]
-                   initWithPassword:_generatedPassword] autorelease]
-             : [[[PasswordGenerationOfferView alloc] initWithDelegate:self]
-                   autorelease];
+             ? [[PasswordGenerationEditView alloc]
+                   initWithPassword:_generatedPassword]
+             : [[PasswordGenerationOfferView alloc] initWithDelegate:self];
 }
 
 #pragma mark -
 #pragma mark CRWWebStateObserver
 
 - (void)webState:(web::WebState*)webState didLoadPageWithSuccess:(BOOL)success {
   [self clearState];
 }
 
 - (void)webStateDestroyed:(web::WebState*)webState {
   [self clearState];
   _webStateObserverBridge.reset();
 }
 
 #pragma mark -
 #pragma mark PasswordGenerationPromptDelegate
 
 - (void)acceptPasswordGeneration:(id)sender {
   [self hideAlert];
-  base::WeakNSObject<PasswordGenerationAgent> weakSelf(self);
+  __weak PasswordGenerationAgent* weakSelf = self;
   id completionHandler = ^(BOOL success) {
     if (!success)
       return;
-    base::scoped_nsobject<PasswordGenerationAgent> strongSelf(
-        [weakSelf retain]);
+    PasswordGenerationAgent* strongSelf = weakSelf;
     if (!strongSelf)
       return;
-    if (strongSelf.get()->_passwordManager) {
+    if (strongSelf->_passwordManager) {
       // Might be null in tests.
-      strongSelf.get()->_passwordManager->SetHasGeneratedPasswordForForm(
-          strongSelf.get()->_passwordManagerDriver,
-          *strongSelf.get()->_possibleAccountCreationForm, true);
+      strongSelf->_passwordManager->SetHasGeneratedPasswordForForm(
+          strongSelf->_passwordManagerDriver,
+          *strongSelf->_possibleAccountCreationForm, true);
     }
-    if (strongSelf.get()->_accessoryViewReadyCompletion) {
-      strongSelf.get()->_accessoryViewReadyCompletion.get()(
+    if (strongSelf->_accessoryViewReadyCompletion) {
+      strongSelf->_accessoryViewReadyCompletion(
           [strongSelf currentAccessoryView], strongSelf);
     }
   };
   [_JSPasswordManager fillPasswordForm:[self passwordGenerationFormName]
                  withGeneratedPassword:_generatedPassword
                      completionHandler:completionHandler];
 }
 
 - (void)showSavedPasswords:(id)sender {
   [self hideAlert];
-  base::scoped_nsobject<GenericChromeCommand> command(
-      [[GenericChromeCommand alloc]
-          initWithTag:IDC_SHOW_SAVE_PASSWORDS_SETTINGS]);
+  GenericChromeCommand* command = [[GenericChromeCommand alloc]
+      initWithTag:IDC_SHOW_SAVE_PASSWORDS_SETTINGS];
   [command executeOnMainWindow];
 }
 
 #pragma mark -
 #pragma mark PasswordGenerationOfferDelegate
 
 - (void)generatePassword {
-  _generatedPassword.reset([base::SysUTF8ToNSString(
-      autofill::PasswordGenerator(kGeneratedPasswordLength).Generate()) copy]);
+  _generatedPassword = [base::SysUTF8ToNSString(
+      autofill::PasswordGenerator(kGeneratedPasswordLength).Generate()) copy];
   [_passwords_ui_delegate showGenerationAlertWithPassword:_generatedPassword
                                         andPromptDelegate:self];
 }
 
 #pragma mark -
 #pragma mark FormInputAccessoryViewProvider
 
 - (id<FormInputAccessoryViewDelegate>)accessoryViewDelegate {
   return nil;
 }
@@ skipping 17 matching lines @@
 
 - (void)retrieveAccessoryViewForFormNamed:(const std::string&)formName
                                 fieldName:(const std::string&)fieldName
                                     value:(const std::string&)value
                                      type:(const std::string&)type
                                  webState:(web::WebState*)webState
                  accessoryViewUpdateBlock:
                      (AccessoryViewReadyCompletion)accessoryViewUpdateBlock {
   DCHECK(!_accessoryViewReadyCompletion);
   if ([_generatedPassword length] > 0)
-    _generatedPassword.reset([base::SysUTF8ToNSString(value) copy]);
+    _generatedPassword = [base::SysUTF8ToNSString(value) copy];
   accessoryViewUpdateBlock([self currentAccessoryView], self);
-  _accessoryViewReadyCompletion.reset([accessoryViewUpdateBlock copy]);
+  _accessoryViewReadyCompletion = [accessoryViewUpdateBlock copy];
 }
 
 - (void)inputAccessoryViewControllerDidReset:
     (FormInputAccessoryViewController*)controller {
   [self hideAlert];
   DCHECK(_accessoryViewReadyCompletion);
-  _accessoryViewReadyCompletion.reset();
+  _accessoryViewReadyCompletion = nil;
 }
 
 - (void)resizeAccessoryView {
   DCHECK(_accessoryViewReadyCompletion);
-  _accessoryViewReadyCompletion.get()([self currentAccessoryView], self);
+  _accessoryViewReadyCompletion([self currentAccessoryView], self);
 }
 
 - (BOOL)getLogKeyboardAccessoryMetrics {
   // Only store metrics for regular Autofill, not passwords.
   return NO;
 }
 
 @end