First cut at run_mksnapshot action for gn

BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # TODO(jochen): These will need to be user-settable to support standalone V8
 # builds.
 v8_compress_startup_data = "off"
 v8_deprecation_warnings = false
 v8_enable_disassembler = false
 v8_enable_gdbjit = false
 v8_enable_handle_zapping = true
 v8_enable_i18n_support = true
 v8_enable_verify_heap = false
 v8_interpreted_regexp = false
 v8_object_print = false
 v8_postmortem_support = false
 v8_use_default_platform = true
-#v8_use_snapshot = true
+v8_use_snapshot = true
 v8_enable_extra_checks = is_debug
 v8_target_arch = cpu_arch
+v8_random_seed = "314159265"
 
 
 ###############################################################################
 # Configurations
 #
 config("internal_config") {
   visibility = ":*"  # Only targets in this file can depend on this.
 
   include_dirs = [ "src" ]
 
@@ skipping 217 matching lines @@
 
   outputs = [
     "$target_gen_dir/debug-support.cc"
   ]
 
   args =
     rebase_path(outputs, root_build_dir) +
     rebase_path(sources, root_build_dir)
 }
 
+action("run_mksnapshot") {
+  visibility = ":*"  # Only targets in this file can depend on this.
+
+  deps = [ ":mksnapshot($host_toolchain)" ]
+
+  script = "tools/run.py"
+
+  outputs = [
+    "$target_gen_dir/snapshot.cc"
+  ]
+
+  args = [
+    "./" + rebase_path(get_label_info(":mksnapshot($host_toolchain)", 
+                                      "root_out_dir") + "/mksnapshot",
+                       root_build_dir),
+    "--log-snapshot-positions",
+    "--logfile", rebase_path("$target_gen_dir/snapshot.log", root_build_dir)
+  ]
+
+  if (v8_random_seed != "0") {
+    args += [ "--random-seed", v8_random_seed ]
+  }
+
+  args += rebase_path(outputs, root_build_dir)
+}
+
+
 ###############################################################################
 # Source Sets (aka static libraries)
 #
 
 source_set("v8_nosnapshot") {
   visibility = ":*"  # Only targets in this file can depend on this.
 
   deps = [
     ":js2c",
     ":js2c_experimental",
     ":generate_trig_table",
     ":v8_base",
   ]
 
   sources = [
     "$target_gen_dir/libraries.cc",
     "$target_gen_dir/experimental-libraries.cc",
     "$target_gen_dir/trig-table.cc",
     "src/snapshot-empty.cc",
   ]
 
   configs -= [ "//build/config/compiler:chromium_code" ]
   configs += [ "//build/config/compiler:no_chromium_code" ]
   configs += [ ":internal_config", ":features", ":toolchain" ]
 }
 
+source_set("v8_snapshot") {
+  visibility = ":*"  # Only targets in this file can depend on this.
+
+  deps = [
+    ":js2c",
+    ":js2c_experimental",
+    ":generate_trig_table",
+    ":run_mksnapshot",
+    ":v8_base",
+  ]
+
+  sources = [
+    "$target_gen_dir/libraries.cc",
+    "$target_gen_dir/experimental-libraries.cc",
+    "$target_gen_dir/trig-table.cc",
+    "$target_gen_dir/snapshot.cc",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [ "//build/config/compiler:no_chromium_code" ]
+  configs += [ ":internal_config", ":features", ":toolchain" ]
+}
+
 source_set("v8_base") {
   visibility = ":*"  # Only targets in this file can depend on this.
 
   sources = [
     "src/accessors.cc",
     "src/accessors.h",
     "src/allocation.cc",
     "src/allocation.h",
     "src/allocation-site-scopes.cc",
     "src/allocation-site-scopes.h",
@@ skipping 604 matching lines @@
 
   configs -= [ "//build/config/compiler:chromium_code" ]
   configs += [ "//build/config/compiler:no_chromium_code" ]
   configs += [ ":internal_config", ":features", ":toolchain" ]
 }
 
 ###############################################################################
 # Executables
 #
 
-if (current_toolchain != host_toolchain && is_android) {
+executable("mksnapshot") {
+  visibility = ":*"  # Only targets in this file can depend on this.
 
-source_set("mksnapshot") {
-  sources = [
-  ]
-}
-
-} else {
-
-executable("mksnapshot") {
   sources = [
     "src/mksnapshot.cc",
   ]
 
   configs -= [ "//build/config/compiler:chromium_code" ]
   configs += [ "//build/config/compiler:no_chromium_code" ]
   configs += [ ":internal_config", ":features", ":toolchain" ]
 
   deps = [
     ":v8_base",
     ":v8_nosnapshot",
   ]
 
   if (v8_compress_startup_data == "bz2") {
     libs = [ "bz2" ]
   }
 }
 
+###############################################################################
+# Public targets
+#
+
+if (component_mode == "shared_library") {
+
+component("v8") {

[brettw, 2014/05/27 21:26:23]

CAn you indent the stuff inside the if?

+  sources = [
+    "src/v8dll-main.cc",
+  ]
+
+  if (v8_use_snapshot) {
+    deps = [
+      ":v8_base",
+      ":v8_snapshot",
+    ]
+  } else {
+    deps = [
+      ":v8_base",
+      ":v8_nosnapshot",
+    ]
+  }
+
+  if (is_android && current_toolchain != host_toolchain) {
+    libs = [ "log" ]
+  }
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [ "//build/config/compiler:no_chromium_code" ]
+  configs += [ ":internal_config", ":features", ":toolchain" ]
+
+  # TODO(jochen): Support direct dependent configs.
 }
+
+} else {
+
+group("v8") {
+  if (v8_use_snapshot) {
+    deps = [
+      ":v8_base",
+      ":v8_snapshot",
+    ]
+  } else {
+    deps = [
+      ":v8_base",
+      ":v8_nosnapshot",
+    ]
+  }
+  # TODO(jochen): Support direct dependent configs.
+}
+
+}