[ObjC ARC] Converts ios/chrome/browser/ui/overscroll_actions:overscroll_actions to ARC.

ios/chrome/browser/ui/overscroll_actions/overscroll_actions_controller.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/overscroll_actions/overscroll_actions_controller.h"
 
 #import <QuartzCore/QuartzCore.h>
 
 #include <algorithm>
 #include "base/logging.h"
-#include "base/mac/objc_property_releaser.h"
-#include "base/mac/scoped_nsobject.h"
 #include "base/metrics/histogram_macros.h"
 #import "ios/chrome/browser/ui/browser_view_controller.h"
 #import "ios/chrome/browser/ui/overscroll_actions/overscroll_actions_gesture_recognizer.h"
 #import "ios/chrome/browser/ui/overscroll_actions/overscroll_actions_view.h"
 #include "ios/chrome/browser/ui/rtl_geometry.h"
 #import "ios/chrome/browser/ui/toolbar/toolbar_controller.h"
 #import "ios/chrome/browser/ui/toolbar/web_toolbar_controller.h"
 #include "ios/chrome/browser/ui/uikit_ui_util.h"
 #import "ios/chrome/browser/ui/voice/voice_search_notification_names.h"
 #import "ios/web/public/web_state/ui/crw_web_view_proxy.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 // This enum is used to record the overscroll actions performed by the user on
 // the histogram named |OverscrollActions|.
 enum {
   // Records each time the user selects the new tab action.
   OVERSCROLL_ACTION_NEW_TAB,
   // Records each time the user selects the refresh action.
   OVERSCROLL_ACTION_REFRESH,
   // Records each time the user selects the close tab action.
   OVERSCROLL_ACTION_CLOSE_TAB,
@@ skipping 109 matching lines @@
   BOOL _allowPullingActions;
   // Records if a transition to the overscroll state ACTION_READY was made.
   // This is used to record a cancel gesture.
   BOOL _didTransitionToActionReady;
   // Records that the controller will be dismissed at the end of the current
   // animation. No new action should be started.
   BOOL _shouldInvalidate;
   // Store the set of notifications that did increment the overscroll actions
   // lock. It is used in order to enforce the fact that the lock should only be
   // incremented/decremented once for a given notification.
-  base::scoped_nsobject<NSMutableSet> _lockIncrementNotifications;
+  NSMutableSet* _lockIncrementNotifications;
   // Store the notification name counterpart of another notification name.
   // Overscroll actions locking and unlocking works by listening to balanced
   // notifications. One notification lock and it's counterpart unlock. This
   // dictionary is used to retrieve the notification name from it's notification
   // counterpart name. Exemple:
   // UIKeyboardWillShowNotification trigger a lock. Its counterpart notification
   // name is UIKeyboardWillHideNotification.
-  base::scoped_nsobject<NSDictionary> _lockNotificationsCounterparts;
+  NSDictionary* _lockNotificationsCounterparts;
   // A view used to catch touches on the webview.
-  base::scoped_nsobject<UIView> _dummyView;
+  UIView* _dummyView;
   // The proxy used to interact with the webview.
-  base::scoped_nsprotocol<id<CRWWebViewProxy>> _webViewProxy;
+  id<CRWWebViewProxy> _webViewProxy;
   // The proxy used to interact with the webview's scrollview.
-  base::scoped_nsobject<CRWWebViewScrollViewProxy> _webViewScrollViewProxy;
+  CRWWebViewScrollViewProxy* _webViewScrollViewProxy;
   // The scrollview driving the OverscrollActionsController when not using
   // the scrollview from the CRWWebControllerObserver.
-  base::scoped_nsobject<UIScrollView> _scrollview;
-  base::mac::ObjCPropertyReleaser _propertyReleaser_OverscrollActionsController;
+  UIScrollView* _scrollview;
 }
 
 // The view displayed over the header view holding the actions.
-@property(nonatomic, retain) OverscrollActionsView* overscrollActionView;
+@property(nonatomic, strong) OverscrollActionsView* overscrollActionView;
 // Initial top inset added to the scrollview for the header.
 // This property is set from the delegate headerInset and cached on first
 // call. The cached value is reset when the webview proxy is set.
 @property(nonatomic, readonly) CGFloat initialContentInset;
 // Initial top inset for the header.
 // This property is set from the delegate headerInset and cached on first
 // call. The cached value is reset when the webview proxy is set.
 @property(nonatomic, readonly) CGFloat initialHeaderInset;
 // Initial height of the header view.
 // This property is set from the delegate headerHeight and cached on first
 // call. The cached value is reset when the webview proxy is set.
 @property(nonatomic, readonly) CGFloat initialHeaderHeight;
 // Redefined to be read-write.
 @property(nonatomic, assign, readwrite) OverscrollState overscrollState;
 // Point where the horizontal gesture started when the state of the
 // overscroll controller is in OverscrollStateActionReady.
 @property(nonatomic, assign) CGPoint panPointScreenOrigin;
 // Pan gesture recognizer used to track horizontal touches.
-@property(nonatomic, retain) UIPanGestureRecognizer* panGestureRecognizer;
+@property(nonatomic, strong) UIPanGestureRecognizer* panGestureRecognizer;
 
 // Registers notifications to lock the overscroll actions on certain UI states.
 - (void)registerNotifications;
 // Setup/tearDown methods are used to register values when the delegate is set.
 - (void)tearDown;
 - (void)setup;
 // Resets scroll view's top content inset to |self.initialContentInset|.
 - (void)resetScrollViewTopContentInset;
 // Access the headerView from the delegate.
 - (UIView<RelaxedBoundsConstraintsHitTestSupport>*)headerView;
@@ skipping 34 matching lines @@
 @synthesize panPointScreenOrigin = _panPointScreenOrigin;
 @synthesize panGestureRecognizer = _panGestureRecognizer;
 
 - (instancetype)init {
   return [self initWithScrollView:nil];
 }
 
 - (instancetype)initWithScrollView:(UIScrollView*)scrollView {
   self = [super init];
   if (self) {
-    _propertyReleaser_OverscrollActionsController.Init(
-        self, [OverscrollActionsController class]);
     _overscrollActionView =
         [[OverscrollActionsView alloc] initWithFrame:CGRectZero];
     _overscrollActionView.delegate = self;
-    _scrollview.reset([scrollView retain]);
+    _scrollview = scrollView;
     if (_scrollview) {
       [self setup];
     }
-    _lockIncrementNotifications.reset([[NSMutableSet alloc] init]);
+    _lockIncrementNotifications = [[NSMutableSet alloc] init];
 
-    _lockNotificationsCounterparts.reset([@{
+    _lockNotificationsCounterparts = @{
       UIKeyboardWillHideNotification : UIKeyboardWillShowNotification,
       kMenuWillHideNotification : kMenuWillShowNotification,
       kTabHistoryPopupWillHideNotification :
           kTabHistoryPopupWillShowNotification,
       kVoiceSearchWillHideNotification : kVoiceSearchWillShowNotification,
       kVoiceSearchBarViewButtonDeselectedNotification :
           kVoiceSearchBarViewButtonSelectedNotification,
       ios_internal::kPageInfoWillHideNotification :
           ios_internal::kPageInfoWillShowNotification,
       ios_internal::kLocationBarResignsFirstResponderNotification :
           ios_internal::kLocationBarBecomesFirstResponderNotification,
       ios_internal::kSideSwipeDidStopNotification :
           ios_internal::kSideSwipeWillStartNotification
-    } retain]);
+    };
     [self registerNotifications];
   }
   return self;
 }
 
 - (void)dealloc {
   self.overscrollActionView.delegate = nil;
   [self invalidate];
-  [super dealloc];
 }
 
 - (void)scheduleInvalidate {
   if (self.overscrollState == OverscrollState::NO_PULL_STARTED) {
     [self invalidate];
   } else {
     _shouldInvalidate = YES;
   }
 }
 
 - (void)invalidate {
   [self clear];
   [self stopBounce];
   [self tearDown];
   [[NSNotificationCenter defaultCenter] removeObserver:self];
   [self setWebViewInteractionEnabled:YES];
   _delegate = nil;
-  _webViewProxy.reset();
+  _webViewProxy = nil;
   [_webViewScrollViewProxy removeObserver:self];
-  _webViewScrollViewProxy.reset();
+  _webViewScrollViewProxy = nil;
 }
 
 - (void)clear {
   self.overscrollState = OverscrollState::NO_PULL_STARTED;
 }
 
 - (void)enableOverscrollActions {
   _isOverscrollActionsDisabledForLoading = NO;
   [self setup];
 }
@@ skipping 194 matching lines @@
   return YES;
 }
 
 #pragma mark - CRWWebControllerObserver methods
 
 - (void)setWebViewProxy:(id<CRWWebViewProxy>)webViewProxy
              controller:(CRWWebController*)webController {
   DCHECK([webViewProxy scrollViewProxy]);
   _initialHeaderInset = 0;
   _initialHeaderHeight = 0;
-  _webViewProxy.reset([webViewProxy retain]);
+  _webViewProxy = webViewProxy;
   [_webViewScrollViewProxy removeObserver:self];
-  _webViewScrollViewProxy.reset([[webViewProxy scrollViewProxy] retain]);
+  _webViewScrollViewProxy = [webViewProxy scrollViewProxy];
   [_webViewScrollViewProxy addObserver:self];
   [self enableOverscrollActions];
 }
 
 - (void)webControllerWillClose:(CRWWebController*)webController {
   [self disableOverscrollActions];
   [_webViewScrollViewProxy removeObserver:self];
-  _webViewScrollViewProxy.reset();
+  _webViewScrollViewProxy = nil;
 }
 
 #pragma mark - Private
 
 - (void)recordMetricForTriggeredAction:(OverscrollAction)action {
   switch (action) {
     case OverscrollAction::NONE:
       UMA_HISTOGRAM_ENUMERATION(kOverscrollActionsHistogram,
                                 OVERSCROLL_ACTION_CANCELED,
                                 OVERSCROLL_ACTION_COUNT);
@@ skipping 12 matching lines @@
       UMA_HISTOGRAM_ENUMERATION(kOverscrollActionsHistogram,
                                 OVERSCROLL_ACTION_CLOSE_TAB,
                                 OVERSCROLL_ACTION_COUNT);
       break;
   }
 }
 
 - (void)registerNotifications {
   NSNotificationCenter* center = [NSNotificationCenter defaultCenter];
   for (NSString* counterpartNotificationName in _lockNotificationsCounterparts
-           .get()) {
+           .allKeys) {
     [center addObserver:self
                selector:@selector(incrementOverscrollActionLockForNotification:)
                    name:[_lockNotificationsCounterparts
                             objectForKey:counterpartNotificationName]
                  object:nil];
     [center addObserver:self
                selector:@selector(decrementOverscrollActionLockForNotification:)
                    name:counterpartNotificationName
                  object:nil];
   }
   [center addObserver:self
              selector:@selector(deviceOrientationDidChange)
                  name:UIDeviceOrientationDidChangeNotification
                object:nil];
 }
 
 - (void)tearDown {
   [[self scrollView] removeGestureRecognizer:self.panGestureRecognizer];
   self.panGestureRecognizer = nil;
 }
 
 - (void)setup {
-  base::scoped_nsobject<UIPanGestureRecognizer> panGesture;
+  UIPanGestureRecognizer* panGesture;
   // Workaround a bug occuring when Speak Selection is enabled.
   // See crbug.com/699655.
   if (UIAccessibilityIsSpeakSelectionEnabled()) {
-    panGesture.reset([[OverscrollActionsGestureRecognizer alloc]
+    panGesture = [[OverscrollActionsGestureRecognizer alloc]
         initWithTarget:self
-                action:@selector(panGesture:)]);
+                action:@selector(panGesture:)];
   } else {
-    panGesture.reset([[UIPanGestureRecognizer alloc]
-        initWithTarget:self
-                action:@selector(panGesture:)]);
+    panGesture =
+        [[UIPanGestureRecognizer alloc] initWithTarget:self
+                                                action:@selector(panGesture:)];
   }
   [panGesture setMaximumNumberOfTouches:1];
   [panGesture setDelegate:self];
   [[self scrollView] addGestureRecognizer:panGesture];
-  self.panGestureRecognizer = panGesture.get();
+  self.panGestureRecognizer = panGesture;
 }
 
 - (id<OverscrollActionsScrollView>)scrollView {
   if (_scrollview) {
-    return static_cast<id<OverscrollActionsScrollView>>(_scrollview.get());
+    return static_cast<id<OverscrollActionsScrollView>>(_scrollview);
   } else {
     return static_cast<id<OverscrollActionsScrollView>>(
-        _webViewScrollViewProxy.get());
+        _webViewScrollViewProxy);
   }
 }
 
 - (void)setScrollViewContentInset:(UIEdgeInsets)contentInset {
   if (_scrollview)
     [_scrollview setContentInset:contentInset];
   else
     [_webViewScrollViewProxy setContentInset:contentInset];
 }
 
@@ skipping 163 matching lines @@
   for (UIGestureRecognizer* gesture in
        [_webViewScrollViewProxy gestureRecognizers]) {
     if (![gesture isKindOfClass:[UIPanGestureRecognizer class]]) {
       [gesture setEnabled:enabled];
     }
   }
   // Add a dummy view on top of the webview in order to catch touches on some
   // specific subviews.
   if (!enabled) {
     if (!_dummyView)
-      _dummyView.reset([[UIView alloc] init]);
+      _dummyView = [[UIView alloc] init];
     [_dummyView setFrame:[_webViewProxy bounds]];
     [_webViewProxy addSubview:_dummyView];
   } else {
     [_dummyView removeFromSuperview];
   }
 }
 
 - (void)updateWithVerticalOffset:(CGFloat)verticalOffset {
   self.overscrollActionView.backgroundView.alpha =
       1.0 -
@@ skipping 115 matching lines @@
       overscrollActionsController:self
                  didTriggerAction:self.overscrollActionView.selectedAction];
 }
 
 - (void)overscrollActionsView:(OverscrollActionsView*)view
       selectedActionDidChange:(OverscrollAction)newAction {
   TriggerHapticFeedbackForSelectionChange();
 }
 
 @end