[iOS Clean] Added JavaScript dialog support.

ios/clean/chrome/browser/ui/dialogs/java_script_dialogs/java_script_dialog_coordinator.mm

Index: ios/clean/chrome/browser/ui/dialogs/java_script_dialogs/java_script_dialog_coordinator.mm
diff --git a/ios/clean/chrome/browser/ui/dialogs/java_script_dialogs/java_script_dialog_coordinator.mm b/ios/clean/chrome/browser/ui/dialogs/java_script_dialogs/java_script_dialog_coordinator.mm
new file mode 100644
index 0000000000000000000000000000000000000000..fdf9732f6bc05f1d489d58626e83f4fbdc35fc8a
--- /dev/null
+++ b/ios/clean/chrome/browser/ui/dialogs/java_script_dialogs/java_script_dialog_coordinator.mm
@@ -0,0 +1,99 @@
+// Copyright 2017 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/clean/chrome/browser/ui/dialogs/java_script_dialogs/java_script_dialog_coordinator.h"
+
+#import "ios/clean/chrome/browser/ui/commands/java_script_dialog_commands.h"
+#import "ios/clean/chrome/browser/ui/commands/overlay_commands.h"
+#import "ios/clean/chrome/browser/ui/dialogs/dialog_view_controller.h"
+#import "ios/clean/chrome/browser/ui/dialogs/java_script_dialogs/java_script_dialog_mediator.h"
+#import "ios/clean/chrome/browser/ui/dialogs/java_script_dialogs/java_script_dialog_state.h"
+#import "ios/clean/chrome/browser/ui/overlays/overlay_queue.h"
+#import "ios/shared/chrome/browser/ui/browser_list/browser.h"
+#import "ios/shared/chrome/browser/ui/commands/command_dispatcher.h"
+#import "ios/shared/chrome/browser/ui/coordinators/browser_coordinator+internal.h"
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+@interface JavaScriptDialogCoordinator ()<JavaScriptDialogDismissalCommands>
+
+// The dispatcher for DialogDismissalCommands.
+@property(nonatomic, readonly) id<DialogDismissalCommands> dismissalDispatcher;
+// The state used to configure this dialog.
+@property(nonatomic, strong) JavaScriptDialogState* state;
+// The view controller used to display this dialog.
+@property(nonatomic, strong) DialogViewController* viewController;
+// The mediator for this dialog.
+@property(nonatomic, strong) JavaScriptDialogMediator* mediator;
+
+@end
+
+@implementation JavaScriptDialogCoordinator
+
+@synthesize state = _state;
+@synthesize viewController = _viewController;
+@synthesize mediator = _mediator;
+
+- (instancetype)initWithState:(JavaScriptDialogState*)state {
+  DCHECK(state.webState);
+  if ((self = [super initWithWebState:state.webState])) {
+    _state = state;
+  }
+  return self;
+}
+
+#pragma mark - Accessors
+
+- (id<DialogDismissalCommands>)dismissalDispatcher {
+  return static_cast<id<DialogDismissalCommands>>(self.browser->dispatcher());
+}
+
+#pragma mark - BrowserCoordinator
+
+- (void)start {
+  self.viewController =
+      [[DialogViewController alloc] initWithStyle:UIAlertControllerStyleAlert
+                                       dispatcher:self.dismissalDispatcher];
+  self.mediator = [[JavaScriptDialogMediator alloc]
+      initWithDispatcher:self.browser->dispatcher()
+                   state:self.state];
+  [self.mediator updateConsumer:self.viewController];
+  [self.mediator dialogWillStart];
+  [self.browser->dispatcher()
+      startDispatchingToTarget:self
+                   forProtocol:@protocol(JavaScriptDialogDismissalCommands)];
+  [super start];
+}
+
+- (void)stop {
+  [self.mediator dialogWillStop];
+  [super stop];
+}
+
+#pragma mark - OverlayCoordinator
+
+- (void)cancelOverlay {
+  [self.state runCallbackWithSuccess:NO userInput:nil];
+}
+
+#pragma mark - JavaScriptDialogDismisalCommands
+
+- (void)dismissJavaScriptAlert {
+  [self.state runCallbackWithSuccess:YES userInput:nil];
+  [self stop];
+}
+
+- (void)dimsissJavaScriptConfirmationWithSuccess:(BOOL)success {
+  [self.state runCallbackWithSuccess:success userInput:nil];
+  [self stop];
+}
+
+- (void)dismissJavaScriptPromptWithResult:(NSString*)result {
+  [self.state runCallbackWithSuccess:YES userInput:result];
+  [self stop];
+}
+
+@end