[Mac] Touch Bar Support for Dialogs

chrome/browser/ui/cocoa/bookmarks/bookmark_editor_base_controller.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include <stack>
 
 #import "chrome/browser/ui/cocoa/bookmarks/bookmark_editor_base_controller.h"
 
 #include "base/auto_reset.h"
 #include "base/logging.h"
 #include "base/mac/bundle_locations.h"
 #include "base/mac/foundation_util.h"
+#include "base/mac/mac_util.h"
+#import "base/mac/sdk_forward_declarations.h"
 #include "base/strings/sys_string_conversions.h"
 #include "chrome/browser/bookmarks/bookmark_model_factory.h"
 #include "chrome/browser/bookmarks/managed_bookmark_service_factory.h"
 #include "chrome/browser/profiles/profile.h"
 #include "chrome/browser/ui/browser_dialogs.h"
 #import "chrome/browser/ui/cocoa/bookmarks/bookmark_all_tabs_controller.h"
 #import "chrome/browser/ui/cocoa/bookmarks/bookmark_editor_controller.h"
 #import "chrome/browser/ui/cocoa/bookmarks/bookmark_name_folder_controller.h"
 #import "chrome/browser/ui/cocoa/bookmarks/bookmark_tree_browser_cell.h"
 #import "chrome/browser/ui/cocoa/browser_window_controller.h"
+#include "chrome/common/chrome_features.h"
+#include "chrome/grit/generated_resources.h"
 #include "components/bookmarks/browser/bookmark_model.h"
 #include "components/bookmarks/managed/managed_bookmark_service.h"
 #include "components/strings/grit/components_strings.h"
+#include "ui/base/cocoa/touch_bar_util.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 #include "ui/base/material_design/material_design_controller.h"
+#include "ui/strings/grit/ui_strings.h"
 
 using bookmarks::BookmarkExpandedStateTracker;
 using bookmarks::BookmarkModel;
 using bookmarks::BookmarkNode;
 
+namespace {
+
+// Touch bar identifier.
+NSString* const kBookmarkEditDialogTouchBarId = @"bookmark-edit-dialog";
+
+// Touch bar item identifiers.
+NSString* const kNewFolderTouchBarId = @"NEW-FOLDER";
+NSString* const kCancelTouchBarId = @"CANCEL";
+NSString* const kSaveTouchBarId = @"SAVE";
+
+}  // end namespace
+
 @interface BookmarkEditorBaseController ()
 
 // Return the folder tree object for the given path.
 - (BookmarkFolderInfo*)folderForIndexPath:(NSIndexPath*)path;
 
 // (Re)build the folder tree from the BookmarkModel's current state.
 - (void)buildFolderTree;
 
 // Notifies the controller that the bookmark model has changed.
 // |selection| specifies if the current selection should be
@@ skipping 290 matching lines @@
   [sheet close];
   [[BrowserWindowController browserWindowControllerForWindow:parentWindow_]
       releaseToolbarVisibilityForOwner:self
                          withAnimation:YES];
 }
 
 - (void)windowWillClose:(NSNotification*)notification {
   [self autorelease];
 }
 
+- (NSTouchBar*)makeTouchBar {
+  if (!base::FeatureList::IsEnabled(features::kBrowserTouchBar))
+    return nil;
+
+  base::scoped_nsobject<NSTouchBar> touchBar([[ui::NSTouchBar() alloc] init]);
+  [touchBar setCustomizationIdentifier:ui::GetTouchBarId(
+                                           kBookmarkEditDialogTouchBarId)];
+  [touchBar setDelegate:self];
+
+  NSArray* dialogItems = @[
+    ui::GetTouchBarItemId(kBookmarkEditDialogTouchBarId, kNewFolderTouchBarId),
+    ui::GetTouchBarItemId(kBookmarkEditDialogTouchBarId, kCancelTouchBarId),
+    ui::GetTouchBarItemId(kBookmarkEditDialogTouchBarId, kSaveTouchBarId)
+  ];
+
+  [touchBar setDefaultItemIdentifiers:dialogItems];
+  [touchBar setCustomizationAllowedItemIdentifiers:dialogItems];
+  return touchBar.autorelease();
+}
+
+- (NSTouchBarItem*)touchBar:(NSTouchBar*)touchBar
+      makeItemForIdentifier:(NSTouchBarItemIdentifier)identifier {
+  NSButton* button = nil;
+  if ([identifier hasSuffix:kNewFolderTouchBarId]) {
+    button =
+        [NSButton buttonWithTitle:l10n_util::GetNSString(
+                                      IDS_BOOKMARK_EDITOR_NEW_FOLDER_BUTTON)
+                           target:self
+                           action:@selector(newFolder:)];
+  } else if ([identifier hasSuffix:kCancelTouchBarId]) {
+    button = [NSButton buttonWithTitle:l10n_util::GetNSString(IDS_APP_CANCEL)
+                                target:self
+                                action:@selector(cancel:)];
+  } else if ([identifier hasSuffix:kSaveTouchBarId]) {
+    button = ui::GetBlueTouchBarButton(l10n_util::GetNSString(IDS_SAVE), self,
+                                       @selector(ok:));
+  } else {
+    return nil;
+  }
+
+  base::scoped_nsobject<NSCustomTouchBarItem> item(
+      [[ui::NSCustomTouchBarItem() alloc] initWithIdentifier:identifier]);
+  [item setView:button];
+  return item.autorelease();
+}
+
 #pragma mark Folder Tree Management
 
 - (BookmarkModel*)bookmarkModel {
   return BookmarkModelFactory::GetForBrowserContext(profile_);
 }
 
 - (Profile*)profile {
   return profile_;
 }
 
@@ skipping 375 matching lines @@
   [super dealloc];
 }
 
 // Implementing isEqual: allows the NSTreeController to preserve the selection
 // and open/shut state of outline items when the data changes.
 - (BOOL)isEqual:(id)other {
   return [other isKindOfClass:[BookmarkFolderInfo class]] &&
       folderNode_ == [(BookmarkFolderInfo*)other folderNode];
 }
 @end