GN win: prep_libc and fix tcmalloc linkage

base/allocator/BUILD.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/allocator.gni")
 
 # Only executables and not libraries should depend on the allocator target;
 # only the application (the final executable) knows what allocator makes sense.
 # This "allocator" meta-target will forward to the default allocator according
 # to the build settings.
 group("allocator") {
   if (use_allocator == "tcmalloc") {
     deps = [ ":tcmalloc" ]
   }
 }
 
+# This config and libc modification are only used on Windows.
+if (is_win) {
+  import("//build/config/win/visual_studio_version.gni")
+
+  config("nocmt") {
+    ldflags = [
+      "/NODEFAULTLIB:libcmt",
+      "/NODEFAULTLIB:libcmtd",
+    ]
+    libs = [ rebase_path("$target_gen_dir/allocator/libcmt.lib") ]
+  }
+
+  action("prep_libc") {
+    script = "prep_libc.py"
+    outputs = [ "$target_gen_dir/allocator/libcmt.lib" ]
+    args = [
+      visual_studio_path + "/vc/lib",
+      rebase_path("$target_gen_dir/allocator"),
+      cpu_arch,
+    ]
+  }
+}
+
 if (!is_android) {
   # tcmalloc currently won't compile on Android.
   source_set("tcmalloc") {
     tcmalloc_dir = "//third_party/tcmalloc/chromium"
 
     sources = [
       # Generated for our configuration from tcmalloc"s build
       # and checked in.
       "$tcmalloc_dir/src/config.h",
       "$tcmalloc_dir/src/config_android.h",
@@ skipping 91 matching lines @@
 
     include_dirs = [
       ".",
       "$tcmalloc_dir/src/base",
       "$tcmalloc_dir/src",
     ]
 
     configs -= [ "//build/config/compiler:chromium_code" ]
     configs += [ "//build/config/compiler:no_chromium_code" ]
 
+    deps = []
+
     if (is_win) {
       sources -= [
         "$tcmalloc_dir/src/base/elf_mem_image.cc",
         "$tcmalloc_dir/src/base/elf_mem_image.h",
         "$tcmalloc_dir/src/base/linuxthreads.cc",
         "$tcmalloc_dir/src/base/linuxthreads.h",
         "$tcmalloc_dir/src/base/vdso_support.cc",
         "$tcmalloc_dir/src/base/vdso_support.h",
         "$tcmalloc_dir/src/maybe_threads.cc",
         "$tcmalloc_dir/src/maybe_threads.h",
         "$tcmalloc_dir/src/symbolize.h",
         "$tcmalloc_dir/src/system-alloc.cc",
         "$tcmalloc_dir/src/system-alloc.h",
 
         # included by allocator_shim.cc
         "debugallocation_shim.cc",
 
         # cpuprofiler
         "$tcmalloc_dir/src/base/thread_lister.c",
         "$tcmalloc_dir/src/base/thread_lister.h",
         "$tcmalloc_dir/src/profiledata.cc",
         "$tcmalloc_dir/src/profiledata.h",
         "$tcmalloc_dir/src/profile-handler.cc",
         "$tcmalloc_dir/src/profile-handler.h",
         "$tcmalloc_dir/src/profiler.cc",
       ]
       defines += [ "PERFTOOLS_DLL_DECL=" ]
+
+      direct_dependent_configs = [ ":nocmt" ]
+
+      deps += [
+        ":prep_libc",
+      ]
     }
+
     if (is_linux || is_android) {
       sources -= [
         "$tcmalloc_dir/src/system-alloc.h",
         "$tcmalloc_dir/src/windows/port.cc",
         "$tcmalloc_dir/src/windows/port.h",
 
         # TODO(willchan): Support allocator shim later on.
         "allocator_shim.cc",
       ]
 
@@ skipping 18 matching lines @@
       ]
     }
 
     # Make sure the allocation library is optimized as much as possible when
     # we"re in release mode.
     if (!is_debug) {
       configs -= [ "//build/config/compiler:optimize" ]
       configs += [ "//build/config/compiler:optimize_max" ]
     }
 
-    deps = [
+    deps += [
       "//base/third_party/dynamic_annotations",
     ]
 
     if (is_win) {
       ldflags = [ "/ignore:4006:4221" ]
     }
   }
 }  # !is_android
 
 source_set("allocator_extension_thunks") {
   visibility = "//base/*"
   sources = [
     "allocator_extension_thunks.cc",
     "allocator_extension_thunks.h",
   ]
 }