Add some closureised JS bindings for DevTools for use by headless embedder

third_party/closure_compiler/compile_js.gni

 # Copyright 2017 The Chromium Authors.  All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//third_party/closure_compiler/closure_args.gni")
 
 script_path = "//third_party/closure_compiler"
 compiler_path = "$script_path/compiler/compiler.jar"
 
 # Defines a target that creates an ordering for .js files to be used by
 # js_binary to compile.
 #
 # Variables:
 #   sources:
 #     List of Javascript files to include in the library
 #
 #   deps:

[Sami, 2017/05/24 09:16:22]

I think renaming this to js_deps instead would make deps work like you'd expect
from other gn rules.

[alex clarke (OOO till 29th), 2017/05/24 11:38:19]

+dbeam@ WDYT?

 #     List of js_library targets to depend on
 #
+#   extra_deps:
+#     List of any other rules to depend on. E.g. a rule that generates js source
+#     files
+#
 # Example:
 #   js_library("apple_tree") {
 #     sources = ["tree_main.js"]
 #     deps = [
 #       ":branch",
 #       ":trunk",
 #       ":root",
 #     ]
 #   }
 
 template("js_library") {
   assert(defined(invoker.sources) || defined(invoker.deps),
          "Need sources or deps in $target_name for js_library")
   action(target_name) {
     script = "$script_path/js_library.py"
     forward_variables_from(invoker,
                            [
                              "sources",
                              "deps",
+                             "extra_deps",
                            ])
     output_file = "$target_gen_dir/$target_name.js_library"
     outputs = [
       output_file,
     ]
     args = [ "--output" ] + [ rebase_path(output_file, root_build_dir) ]
     if (defined(sources)) {
       args += [ "--sources" ] + rebase_path(sources, root_build_dir)
     }
     if (defined(deps)) {
       args += [ "--deps" ]
       foreach(dep, deps) {
         # Get the output path for each dep
         dep_gen_dir = get_label_info(dep, "target_gen_dir")
         dep_name = get_label_info(dep, "name")
         dep_output_path = "$dep_gen_dir/$dep_name.js_library"
         args += [ rebase_path(dep_output_path, root_build_dir) ]
       }
     }
+    if (defined(extra_deps)) {
+      if (!defined(deps)) {
+        deps = []
+      }
+      deps += extra_deps
+    }
   }
 }
 
 # Defines a target that compiles javascript files using the Closure compiler.
 # This will produce a minified javascript output file. Additional checks and
 # optimizations can be configured using the closure_flags attribute.
 #
 # Variables:
 #   sources:
 #     List of .js files to compile
 #
 #   deps:
 #     List of js_library rules to depend on
 #
+#   extra_deps:
+#     List of any other rules to depend on. E.g. a rule that generates js source
+#     files
+#
 #   outputs:
 #     A file to write the compiled .js to.
 #     Only takes in a single file, but must be placed in a list
 #
 #   bootstrap_file:
 #      A .js files to include before all others
 #
 #   config_files:
 #     A list of .js files to include after the bootstrap_file but before all
 #     others
@@ skipping 28 matching lines @@
     script = "$script_path/js_binary.py"
     forward_variables_from(invoker,
                            [
                              "sources",
                              "deps",
                              "outputs",
                              "bootstrap_file",
                              "config_files",
                              "closure_flags",
                              "externs_list",
+                             "extra_deps",
                            ])
     args = [
       "--compiler",
       rebase_path(compiler_path, root_build_dir),
     ]
     args += [ "--output" ] + rebase_path(outputs, root_build_dir)
     if (defined(sources)) {
       args += [ "--sources" ] + rebase_path(sources, root_build_dir)
     } else {
       sources = []
     }
     if (defined(deps)) {
       args += [ "--deps" ]
       foreach(dep, deps) {
         # Get the output path for each dep
         dep_gen_dir = get_label_info(dep, "target_gen_dir")
         dep_name = get_label_info(dep, "name")
         dep_output_path = "$dep_gen_dir/$dep_name.js_library"
         args += [ rebase_path(dep_output_path, root_build_dir) ]
       }
     }
+    if (defined(extra_deps)) {
+      if (!defined(deps)) {
+        deps = []
+      }
+      deps += extra_deps
+    }
     if (defined(bootstrap_file)) {
       args += [
         "--bootstrap",
         rebase_path(bootstrap_file, root_build_dir),
       ]
       sources += [ bootstrap_file ]
     }
     if (defined(config_files)) {
       args += [ "--config" ] + rebase_path(config_files, root_build_dir)
       sources += config_files
     }
 
     # |minifying_closure_args| from
     # //third_party/closure_compiler/closure_args.gni
     args += [ "--flags" ] + minifying_closure_args
     if (defined(closure_flags)) {
       args += closure_flags
     }
     if (defined(externs_list)) {
       args += [ "--externs" ]
       args += rebase_path(externs_list, root_build_dir)
       sources += externs_list
     }
   }
 }