Add some closureised JS bindings for DevTools for use by headless embedder

headless/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chrome_build.gni")
 import("//build/util/process_version.gni")
 import("//headless/headless.gni")
 import("//mojo/public/tools/bindings/mojom.gni")
 import("//printing/features/features.gni")
 import("//testing/test.gni")
+import("//third_party/closure_compiler/compile_js.gni")
 import("//tools/grit/grit_rule.gni")
 import("//tools/grit/repack.gni")
 
 config("headless_implementation") {
   defines = [ "HEADLESS_IMPLEMENTATION" ]
 
   if (headless_use_embedded_resources) {
     defines += [ "HEADLESS_USE_EMBEDDED_RESOURCES" ]
   }
 }
@@ skipping 132 matching lines @@
   "page",
   "profiler",
   "runtime",
   "security",
   "service_worker",
   "target",
   "tracing",
 ]
 
 generated_devtools_api = []
+generated_devtools_api_js = []
 foreach(domain, devtools_domains) {
+  generated_devtools_api_js +=
+      [ "$target_gen_dir/public/devtools_js/" + domain + ".js" ]
   generated_devtools_api += [
     "$target_gen_dir/public/devtools/domains/" + domain + ".cc",
     "$target_gen_dir/public/devtools/domains/" + domain + ".h",
     "$target_gen_dir/public/devtools/domains/types_" + domain + ".h",
     "$target_gen_dir/public/devtools/domains/types_" + domain + ".cc",
     "$target_gen_dir/public/devtools/internal/type_conversions_" + domain +
         ".h",
     "$target_gen_dir/public/devtools/internal/" +
         "types_forward_declarations_" + domain + ".h",
   ]
 }
 
 action("gen_devtools_client_api") {
   script = "lib/browser/devtools_api/client_api_generator.py"
   deps = [
     "//third_party/WebKit/Source/core/inspector:protocol_version",
   ]
   inputs = [
     "$root_gen_dir/blink/core/inspector/protocol.json",
   ]
 
-  outputs = generated_devtools_api
+  outputs = generated_devtools_api + generated_devtools_api_js
 
   sources = [
     "lib/browser/devtools_api/domain_cc.template",
     "lib/browser/devtools_api/domain_h.template",
+    "lib/browser/devtools_api/domain_js.template",
     "lib/browser/devtools_api/domain_type_conversions_h.template",
     "lib/browser/devtools_api/domain_types_cc.template",
     "lib/browser/devtools_api/domain_types_forward_declarations_h.template",
     "lib/browser/devtools_api/domain_types_h.template",
   ]
 
   args = [
     "--protocol",
     rebase_path(inputs[0], root_build_dir),
     "--output_dir",
     rebase_path(target_gen_dir, root_build_dir) + "/public",
   ]
 }
 
+js_library("js_devtools_bindings_lib") {
+  sources = [ "lib/browser/devtools_api/devtools_connection.js" ] +
+            generated_devtools_api_js
+  deps = []
+  extra_deps = [ ":gen_devtools_client_api" ]
+}
+
 if (headless_fontconfig_utils) {
   static_library("headless_fontconfig_utils") {
     sources = [
       "public/util/fontconfig.cc",
       "public/util/fontconfig.h",
     ]
 
     deps = [
       "//build/linux:fontconfig",
       "//third_party/freetype",
@@ skipping 286 matching lines @@
       "//base",
       "//third_party/crashpad/crashpad/handler:crashpad_handler",
     ]
 
     outputs = [
       "$root_out_dir/Helpers/{{source_file_part}}",
     ]
   }
 }
 
+if (!is_win) {
+  js_binary("js_devtools_bindings_test") {
+    sources = [
+      "test/bindings_test.js",
+    ]
+    deps = [
+      ":js_devtools_bindings_lib",
+    ]
+    externs_list = [ "lib/tab_socket_externs.js" ]
+    outputs = [
+      "$target_gen_dir/devtools_bindings_test.js",
+    ]
+    config_files = []
+    closure_flags = [
+      "jscomp_error=checkTypes",
+      "dependency_mode=STRICT",
+
+      # Currently the bindings do not support property renaming so we can't use
+      # ADVANCED_OPTIMIZATIONS here.  We could add support via either moving all
+      # the types to externs, or via applying the same renaming to the json
+      # dictionaries sent between C++ and JS.  The closure compiler can produce
+      # files which contain those mappings with the appropriate flag.
+      "compilation_level=SIMPLE",
+      "language_out=ES5_STRICT",
+      "entry_point=chromium.BindingsTest",
+    ]
+  }
+
+  grit("headless_browsertest_resources_grit") {
+    source = "headless_browsertest_resources.grd"
+    outputs = [
+      "grit/headless_browsertest_resources.h",
+      "$root_gen_dir/headless/headless_browsertest_resources.pak",
+    ]
+    grit_flags = [
+      "-E",
+      "gen_root=" + rebase_path(root_gen_dir),
+    ]
+    deps = [
+      ":js_devtools_bindings_test",
+    ]
+    resource_ids = "lib/headless_browsertest_resource_ids"
+  }
+
+  repack("headless_browser_tests_pak") {
+    sources = [
+      "$root_gen_dir/headless/headless_browsertest_resources.pak",
+    ]
+    output = "$root_out_dir/headless_browser_tests.pak"
+    deps = [
+      ":headless_browsertest_resources_grit",
+    ]
+  }
+}
+
 test("headless_browsertests") {
   sources = [
     "lib/frame_id_browsertest.cc",
     "lib/headless_browser_browsertest.cc",
     "lib/headless_browser_context_browsertest.cc",
     "lib/headless_devtools_client_browsertest.cc",
     "lib/headless_web_contents_browsertest.cc",
     "public/util/dom_tree_extractor_browsertest.cc",
     "public/util/flat_dom_tree_extractor_browsertest.cc",
     "test/headless_browser_test.cc",
@@ skipping 33 matching lines @@
   deps = [
     ":headless_renderer",
     "//base",
     "//components/crash/content/browser",
     "//components/security_state/content",
     "//content/test:test_support",
     "//testing/gmock",
     "//testing/gtest",
   ]
 
+  # The js_binary rule doesn't currently work on windows.
+  if (!is_win) {
+    data += [ "$root_out_dir/headless_browser_tests.pak" ]
+    sources += [ "test/headless_js_bindings_browsertest.cc" ]
+    deps += [ ":headless_browser_tests_pak" ]
+  }
+
   if (enable_basic_printing) {
     deps += [
       "//components/printing/browser",
       "//pdf",
     ]
   }
 }
 
 if (is_win) {
   # Headless library with only browser dependencies. This is used when no child
@@ skipping 141 matching lines @@
 executable("headless_example") {
   sources = [
     "app/headless_example.cc",
   ]
 
   deps = [
     ":headless_shell_lib",
     "//build/config:exe_and_shlib_deps",
   ]
 }