Use assembly instead of C array literals to link the core snapshot into the VM.

runtime/bin/BUILD.gn

 # Copyright (c) 2014, the Dart project authors.  Please see the AUTHORS file
 # for details. All rights reserved. Use of this source code is governed by a
 # BSD-style license that can be found in the LICENSE file.
 
 import("gypi_contents.gni")
 import("../runtime_args.gni")
 import("../../build/compiled_action.gni")
 
 # Generate a resources.cc file for the service isolate without Observatory.
 action("gen_resources_cc") {
@@ skipping 471 matching lines @@
     rebase_path(vm_isolate_snapshot, root_build_dir),
     "--isolate_output_bin",
     rebase_path(isolate_snapshot, root_build_dir),
     "--target_os",
     current_os,
     "--timestamp_file",
     rebase_path(gen_snapshot_stamp_file, root_build_dir),
   ]
 }
 
-action("generate_snapshot_file") {
+# Generates an assembly file defining a given symbol with the bytes from a
+# binary file. Places the symbol in a text section if 'executable' is true,
+# otherwise places the symbol in a read-only data section.
+template("bin_to_assembly") {
+  assert(defined(invoker.deps), "Must define deps")
+  assert(defined(invoker.input), "Must define input binary file")
+  assert(defined(invoker.output), "Must define output assembly file")
+  assert(defined(invoker.symbol), "Must define symbol name")
+  assert(defined(invoker.executable), "Must define boolean executable")
+
+  action(target_name) {
+    deps = invoker.deps
+    script = "../tools/bin_to_assembly.py"
+    args = [
+      "--input",
+      rebase_path(invoker.input),
+      "--output",
+      rebase_path(invoker.output),
+      "--symbol_name",
+      invoker.symbol,
+      "--target_os",
+      target_os,
+    ]
+    if (invoker.executable) {
+      args += [ "--executable" ]
+    }
+    inputs = [
+      script,
+      invoker.input,
+    ]
+    outputs = [
+      invoker.output,
+    ]
+  }
+}
+
+bin_to_assembly("vm_snapshot_data_assembly") {
   deps = [
     ":generate_snapshot_bin",
   ]
+  input = "$target_gen_dir/vm_isolate_snapshot.bin"
+  output = "$target_gen_dir/vm_snapshot_data.S"
+  symbol = "kDartVmSnapshotData"
+  executable = false
+}
 
-  snapshot_in_cc_file = "snapshot_in.cc"
-  inputs = [
-    "../tools/create_snapshot_file.py",
-    snapshot_in_cc_file,
-    "$target_gen_dir/vm_isolate_snapshot.bin",
-    "$target_gen_dir/isolate_snapshot.bin",
+bin_to_assembly("vm_snapshot_instructions_assembly") {
+  deps = []
+  input = "../tools/empty.bin"
+  output = "$target_gen_dir/vm_snapshot_instructions.S"
+  symbol = "kDartVmSnapshotInstructions"
+  executable = true
+}
+
+bin_to_assembly("isolate_snapshot_data_assembly") {
+  deps = [
+    ":generate_snapshot_bin",
   ]
-  output = "$root_gen_dir/dart_snapshot.cc"
-  outputs = [
-    output,
+  input = "$target_gen_dir/isolate_snapshot.bin"
+  output = "$target_gen_dir/isolate_snapshot_data.S"
+  symbol = "kDartCoreIsolateSnapshotData"
+  executable = false
+}
+
+bin_to_assembly("isolate_snapshot_instructions_assembly") {
+  deps = []
+  input = "../tools/empty.bin"
+  output = "$target_gen_dir/isolate_snapshot_instructions.S"
+  symbol = "kDartCoreIsolateSnapshotInstructions"
+  executable = true
+}
+
+source_set("dart_snapshot_cc") {
+  deps = [
+    ":isolate_snapshot_data_assembly",
+    ":isolate_snapshot_instructions_assembly",
+    ":vm_snapshot_data_assembly",
+    ":vm_snapshot_instructions_assembly",
   ]
-
-  script = "../tools/create_snapshot_file.py"
-  args = [
-    "--vm_input_bin",
-    rebase_path("$target_gen_dir/vm_isolate_snapshot.bin"),
-    "--input_bin",
-    rebase_path("$target_gen_dir/isolate_snapshot.bin"),
-    "--input_cc",
-    rebase_path(snapshot_in_cc_file),
-    "--output",
-    rebase_path(output),
+  sources = [
+    "$target_gen_dir/isolate_snapshot_data.S",
+    "$target_gen_dir/isolate_snapshot_instructions.S",
+    "$target_gen_dir/vm_snapshot_data.S",
+    "$target_gen_dir/vm_snapshot_instructions.S",
   ]
 }
 
-source_set("dart_snapshot_cc") {
-  sources = [
-    "$root_gen_dir/dart_snapshot.cc",
-  ]
-
-  deps = [
-    ":generate_snapshot_file",
-  ]
-}
-
 template("dart_executable") {
   extra_configs = []
   if (defined(invoker.extra_configs)) {
     extra_configs += invoker.extra_configs
   }
   extra_deps = []
   if (defined(invoker.extra_deps)) {
     extra_deps += invoker.extra_deps
   }
   extra_defines = []
@@ skipping 323 matching lines @@
   ]
   if (is_linux || is_android) {
     cflags = [ "-fPIC" ]
   }
   if (is_win) {
     libs = [ "dart.lib" ]
     abs_root_out_dir = rebase_path(root_out_dir)
     ldflags = [ "/LIBPATH:$abs_root_out_dir" ]
   }
 }