[ObjC ARC] Converts ios/chrome/browser/omaha:omaha to ARC.

ios/chrome/browser/omaha/omaha_service.mm

 // Copyright 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "ios/chrome/browser/omaha/omaha_service.h"
 
 #import <Foundation/Foundation.h>
 
 #include <memory>
 #include <utility>
 
 #include "base/bind.h"
 #include "base/i18n/time_formatting.h"
 #include "base/ios/device_util.h"
 #include "base/logging.h"
-#include "base/mac/scoped_nsobject.h"
 #include "base/memory/ptr_util.h"
 #include "base/metrics/field_trial.h"
 #include "base/rand_util.h"
 #include "base/strings/stringprintf.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/strings/utf_string_conversions.h"
 #include "base/sys_info.h"
 #include "base/time/time.h"
 #include "base/values.h"
 #include "components/metrics/metrics_pref_names.h"
@@ skipping 10 matching lines @@
 #include "ios/public/provider/chrome/browser/chrome_browser_provider.h"
 #include "ios/public/provider/chrome/browser/omaha/omaha_service_provider.h"
 #include "ios/public/provider/chrome/browser/omaha/omaha_xml_writer.h"
 #include "ios/web/public/web_thread.h"
 #include "libxml/xmlwriter.h"
 #include "net/base/backoff_entry.h"
 #include "net/base/load_flags.h"
 #include "net/url_request/url_fetcher.h"
 #include "url/gurl.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 namespace {
 // Number of hours to wait between successful requests.
 const int kHoursBetweenRequests = 5;
 // Minimal time to wait between retry requests.
 const CFTimeInterval kPostRetryBaseSeconds = 3600;
 // Maximal time to wait between retry requests.
 const CFTimeInterval kPostRetryMaxSeconds = 6 * kPostRetryBaseSeconds;
 
 // Default last sent application version when none has been sent yet.
 const char kDefaultLastSentVersion[] = "0.0.0.0";
@@ skipping 63 matching lines @@
 // XML parser for the server response.
 @interface ResponseParser : NSObject<NSXMLParserDelegate> {
   BOOL hasError_;
   BOOL responseIsParsed_;
   BOOL appIsParsed_;
   BOOL updateCheckIsParsed_;
   BOOL urlIsParsed_;
   BOOL manifestIsParsed_;
   BOOL pingIsParsed_;
   BOOL eventIsParsed_;
-  base::scoped_nsobject<NSString> appId_;
+  NSString* appId_;
   std::unique_ptr<UpgradeRecommendedDetails> updateInformation_;
 }
 
 // Initialization method. |appId| is the application id one expects to find in
 // the response message.
 - (instancetype)initWithAppId:(NSString*)appId;
 
 // Returns YES if the message has been correctly parsed.
 - (BOOL)isCorrect;
 
 // If an upgrade is possible, returns the details of the notification to send.
 // Otherwise, return NULL.
 - (UpgradeRecommendedDetails*)upgradeRecommendedDetails;
 
 @end
 
 @implementation ResponseParser
 
 - (instancetype)initWithAppId:(NSString*)appId {
   if (self = [super init]) {
-    appId_.reset([appId retain]);
+    appId_ = appId;
   }
   return self;
 }
 
 - (BOOL)isCorrect {
   // A response should have either a ping ACK or an event ACK, depending on the
   // contents of the request.
   return !hasError_ && (pingIsParsed_ || eventIsParsed_);
 }
 
@@ skipping 427 matching lines @@
   if (fetcher->GetResponseCode() != 200) {
     DLOG(WARNING) << "Error contacting the Omaha server";
     SendOrScheduleNextPing();
     return;
   }
 
   std::string response;
   bool result = fetcher->GetResponseAsString(&response);
   DCHECK(result);
   NSData* xml = [NSData dataWithBytes:response.data() length:response.length()];
-  base::scoped_nsobject<NSXMLParser> parser(
-      [[NSXMLParser alloc] initWithData:xml]);
+  NSXMLParser* parser = [[NSXMLParser alloc] initWithData:xml];
   const std::string application_id = ios::GetChromeBrowserProvider()
                                          ->GetOmahaServiceProvider()
                                          ->GetApplicationID();
-  base::scoped_nsobject<ResponseParser> delegate([[ResponseParser alloc]
-      initWithAppId:base::SysUTF8ToNSString(application_id)]);
-  parser.get().delegate = delegate.get();
+  ResponseParser* delegate = [[ResponseParser alloc]
+      initWithAppId:base::SysUTF8ToNSString(application_id)];
+  parser.delegate = delegate;
 
   if (![parser parse] || ![delegate isCorrect]) {
     DLOG(ERROR) << "Unable to parse XML response from Omaha server.";
     SendOrScheduleNextPing();
     return;
   }
   // Handle success.
   number_of_tries_ = 0;
   // Schedule the next request. If requset that just finished was an install
   // notification, send an active ping immediately.
   next_tries_time_ = sending_install_event_
                          ? base::Time::Now()
                          : base::Time::Now() + base::TimeDelta::FromHours(
                                                    kHoursBetweenRequests);
   current_ping_time_ = next_tries_time_;
   last_sent_time_ = base::Time::Now();
   last_sent_version_ = base::Version(version_info::GetVersionNumber());
   sending_install_event_ = false;
   ClearInstallRetryRequestId();
   PersistStates();
   SendOrScheduleNextPing();
 
   // Send notification for updates if needed.
-  UpgradeRecommendedDetails* details =
-      [delegate.get() upgradeRecommendedDetails];
+  UpgradeRecommendedDetails* details = [delegate upgradeRecommendedDetails];
   if (details) {
     web::WebThread::PostTask(
         web::WebThread::UI, FROM_HERE,
         base::Bind(upgrade_recommended_callback_, *details));
   }
 }
 
 void OmahaService::GetDebugInformationOnIOThread(
     const base::Callback<void(base::DictionaryValue*)> callback) {
   auto result = base::MakeUnique<base::DictionaryValue>();
@@ skipping 59 matching lines @@
 
 void OmahaService::ClearPersistentStateForTests() {
   NSUserDefaults* defaults = [NSUserDefaults standardUserDefaults];
   [defaults removeObjectForKey:kNextTriesTimesKey];
   [defaults removeObjectForKey:kCurrentPingKey];
   [defaults removeObjectForKey:kNumberTriesKey];
   [defaults removeObjectForKey:kLastSentVersionKey];
   [defaults removeObjectForKey:kLastSentTimeKey];
   [defaults removeObjectForKey:kRetryRequestIdKey];
 }