[ObjC ARC] Converts ios/chrome/browser/ui/static_content:static_content to ARC.

ios/chrome/browser/ui/static_content/static_html_native_content.mm

 // Copyright 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/static_content/static_html_native_content.h"
 
 #include "base/logging.h"
-#import "base/mac/scoped_nsobject.h"
 #import "ios/chrome/browser/ui/overscroll_actions/overscroll_actions_controller.h"
 #include "ios/chrome/browser/ui/static_content/static_html_view_controller.h"
 #import "ios/chrome/browser/ui/url_loader.h"
 #include "ios/web/public/referrer.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 @interface StaticHtmlNativeContent ()
 // Designated initializer.
 - (instancetype)initWithLoader:(id<UrlLoader>)loader
       staticHTMLViewController:(StaticHtmlViewController*)HTMLViewController
                            URL:(const GURL&)URL;
 @end
 
 @implementation StaticHtmlNativeContent {
   // The url of the controller.
   GURL _URL;
   // YES is web views are allowed to be created.
   BOOL _webUsageEnabled;
   // The static HTML view controller that is used to display the content in
   // a web view.
-  base::scoped_nsobject<StaticHtmlViewController> _staticHTMLViewController;
+  StaticHtmlViewController* _staticHTMLViewController;
   // Responsible for loading a particular URL.
   id<UrlLoader> _loader;  // weak
   // The controller handling the overscroll actions.
-  base::scoped_nsobject<OverscrollActionsController>
-      _overscrollActionsController;
+  OverscrollActionsController* _overscrollActionsController;
 }
 
 #pragma mark -
 #pragma mark Public
 
 - (instancetype)initWithLoader:(id<UrlLoader>)loader
       staticHTMLViewController:(StaticHtmlViewController*)HTMLViewController
                            URL:(const GURL&)URL {
   DCHECK(loader);
   DCHECK(HTMLViewController);
   // No DCHECK for URL (invalid URL is a valid input).
   if (self = [super init]) {
     web::Referrer referrer(URL, web::ReferrerPolicyDefault);
     [HTMLViewController setLoader:loader referrer:referrer];
     _URL = URL;
     _loader = loader;
-    _staticHTMLViewController.reset([HTMLViewController retain]);
+    _staticHTMLViewController = HTMLViewController;
   }
   return self;
 }
 
 - (instancetype)initWithResourcePathResource:(NSString*)resourcePath
                                       loader:(id<UrlLoader>)loader
                                 browserState:(web::BrowserState*)browserState
                                          url:(const GURL&)URL {
   DCHECK(loader);
   DCHECK(browserState);
   DCHECK(URL.is_valid());
   DCHECK(resourcePath);
-  base::scoped_nsobject<StaticHtmlViewController> HTMLViewController(
+  StaticHtmlViewController* HTMLViewController =
       [[StaticHtmlViewController alloc] initWithResource:resourcePath
-                                            browserState:browserState]);
+                                            browserState:browserState];
   return [self initWithLoader:loader
       staticHTMLViewController:HTMLViewController
                            URL:URL];
 }
 
 - (void)dealloc {
   [[self scrollView] setDelegate:nil];
-  [super dealloc];
 }
 
 - (void)loadURL:(const GURL&)URL
              referrer:(const web::Referrer&)referrer
            transition:(ui::PageTransition)transition
     rendererInitiated:(BOOL)rendererInitiated {
   [_loader loadURL:URL
                referrer:referrer
              transition:transition
       rendererInitiated:rendererInitiated];
 }
 
 - (OverscrollActionsController*)overscrollActionsController {
-  return _overscrollActionsController.get();
+  return _overscrollActionsController;
 }
 
 - (void)setOverscrollActionsController:
     (OverscrollActionsController*)controller {
-  _overscrollActionsController.reset([controller retain]);
+  _overscrollActionsController = controller;
   [[self scrollView] setDelegate:controller];
 }
 
 #pragma mark -
 #pragma mark CRWNativeContent implementation
 
 - (void)willBeDismissed {
   // Invalidate the _overscrollActionsController but let the animation finish.
   [_overscrollActionsController scheduleInvalidate];
 }
@@ skipping 45 matching lines @@
 - (void)setScrollEnabled:(BOOL)enabled {
   [_staticHTMLViewController setScrollEnabled:enabled];
 }
 
 - (void)setWebUsageEnabled:(BOOL)webUsageEnabled {
   if (_webUsageEnabled == webUsageEnabled) {
     return;
   }
   _webUsageEnabled = webUsageEnabled;
   if (!_webUsageEnabled) {
-    _staticHTMLViewController.reset();
+    _staticHTMLViewController = nil;
   }
 }
 
 - (UIScrollView*)scrollView {
   return [_staticHTMLViewController scrollView];
 }
 
 @end