[ObjC ARC] Converts ios/chrome/browser/upgrade:upgrade to ARC.

ios/chrome/browser/upgrade/upgrade_center.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/upgrade/upgrade_center.h"
 
 #include <memory>
 #include <set>
 #include <utility>
 
 #include "base/mac/bundle_locations.h"
-#include "base/mac/scoped_nsobject.h"
 #include "base/memory/ptr_util.h"
 #include "base/scoped_observer.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/version.h"
 #include "components/infobars/core/confirm_infobar_delegate.h"
 #include "components/infobars/core/infobar.h"
 #include "components/infobars/core/infobar_manager.h"
 #include "components/version_info/version_info.h"
 #import "ios/chrome/browser/open_url_util.h"
 #import "ios/chrome/browser/ui/commands/UIKit+ChromeExecuteCommand.h"
 #import "ios/chrome/browser/ui/commands/open_url_command.h"
 #include "ios/chrome/grit/ios_chromium_strings.h"
 #include "ios/chrome/grit/ios_strings.h"
 #import "ios/web/public/url_scheme_util.h"
 #import "net/base/mac/url_conversions.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "ui/gfx/image/image.h"
 #include "url/gurl.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 @interface UpgradeCenter ()
 // Creates infobars on all tabs.
 - (void)showUpgradeInfoBars;
 // Removes all the infobars.
 - (void)hideUpgradeInfoBars;
 // Callback when an infobar is closed, for any reason. Perform upgrade is set to
 // YES if the user choose to upgrade.
 - (void)dismissedInfoBar:(NSString*)tabId performUpgrade:(BOOL)shouldUpgrade;
 // Returns YES if the infobar should be shown.
 - (BOOL)shouldShowInfoBar;
@@ skipping 92 matching lines @@
 
   ~UpgradeInfoBarDismissObserver() override {}
 
   void RegisterObserver(infobars::InfoBarManager* infobar_manager,
                         UpgradeInfoBarDelegate* infobar_delegate,
                         NSString* tab_id,
                         UpgradeCenter* dismiss_delegate) {
     scoped_observer_.Add(infobar_manager);
     infobar_delegate_ = infobar_delegate;
     dismiss_delegate_ = dismiss_delegate;
-    tab_id_.reset([tab_id copy]);
+    tab_id_ = [tab_id copy];
   }
 
   UpgradeInfoBarDelegate* infobar_delegate() { return infobar_delegate_; }
 
  private:
   // infobars::InfoBarManager::Observer implementation.
   void OnInfoBarRemoved(infobars::InfoBar* infobar, bool animate) override {
     if (infobar->delegate() == infobar_delegate_) {
-      [dismiss_delegate_ dismissedInfoBar:tab_id_.get()
+      [dismiss_delegate_ dismissedInfoBar:tab_id_
                            performUpgrade:infobar_delegate_->AcceptPressed()];
     }
   }
 
   void OnManagerShuttingDown(
       infobars::InfoBarManager* infobar_manager) override {
     scoped_observer_.Remove(infobar_manager);
   }
 
   UpgradeInfoBarDelegate* infobar_delegate_;
-  UpgradeCenter* dismiss_delegate_;
-  base::scoped_nsobject<NSString> tab_id_;
+  __weak UpgradeCenter* dismiss_delegate_;
+  __strong NSString* tab_id_;
   ScopedObserver<infobars::InfoBarManager, infobars::InfoBarManager::Observer>
       scoped_observer_;
 
   DISALLOW_COPY_AND_ASSIGN(UpgradeInfoBarDismissObserver);
 };
 
 }  // namespace
 
 // The delegateHolder is a simple wrapper to be able to store all the
 // infoBarDelegate related information in an object that can be put in
@@ skipping 27 matching lines @@
 - (UpgradeInfoBarDelegate*)infoBarDelegate {
   return observer_.infobar_delegate();
 }
 
 @end
 
 @implementation UpgradeCenter {
   // YES if the infobars are currently visible.
   BOOL upgradeInfoBarIsVisible_;
   // Used to store the visible upgrade infobars, indexed by tabId.
-  base::scoped_nsobject<NSMutableDictionary> upgradeInfoBarDelegates_;
+  __strong NSMutableDictionary<NSString*, DelegateHolder*>*
+      upgradeInfoBarDelegates_;
   // Stores the clients of the upgrade center. These objectiveC objects are not
   // retained.
-  std::set<id<UpgradeCenterClientProtocol>> clients_;
+  __strong NSHashTable<id<UpgradeCenterClientProtocol>>* clients_;
 #ifndef NDEBUG
-  bool inCallback_;
+  BOOL inCallback_;
 #endif
 }
 
 + (UpgradeCenter*)sharedInstance {
   static UpgradeCenter* obj;
   static dispatch_once_t onceToken;
   dispatch_once(&onceToken, ^{
     obj = [[self alloc] init];
   });
   return obj;
 }
 
 - (instancetype)init {
   self = [super init];
   if (self) {
-    upgradeInfoBarDelegates_.reset([[NSMutableDictionary alloc] init]);
+    upgradeInfoBarDelegates_ = [[NSMutableDictionary alloc] init];
 
     // There is no dealloc and no unregister as this class is a never
     // deallocated singleton.
     [[NSNotificationCenter defaultCenter]
         addObserver:self
            selector:@selector(applicationWillEnterForeground:)
                name:UIApplicationWillEnterForegroundNotification
              object:nil];
 
     upgradeInfoBarIsVisible_ = [self shouldShowInfoBar];
+    clients_ = [NSHashTable weakObjectsHashTable];
   }
   return self;
 }
 
 - (BOOL)shouldShowInfoBar {
   return [self isCurrentVersionObsolete] && ![self infoBarShownRecently];
 }
 
 - (BOOL)isCurrentVersionObsolete {
   NSUserDefaults* defaults = [NSUserDefaults standardUserDefaults];
@@ skipping 22 matching lines @@
   if (upgradeInfoBarIsVisible_)
     return;
 
   // When returning to active if the upgrade notification has been dismissed,
   // bring it back.
   if ([self shouldShowInfoBar])
     [self showUpgradeInfoBars];
 }
 
 - (void)registerClient:(id<UpgradeCenterClientProtocol>)client {
-  clients_.insert(client);
+  [clients_ addObject:client];
   if (upgradeInfoBarIsVisible_)
     [client showUpgrade:self];
 }
 
 - (void)unregisterClient:(id<UpgradeCenterClientProtocol>)client {
 #ifndef NDEBUG
   DCHECK(!inCallback_);
 #endif
-  clients_.erase(client);
+  [clients_ removeObject:client];
 }
 
 - (void)addInfoBarToManager:(infobars::InfoBarManager*)infoBarManager
                    forTabId:(NSString*)tabId {
   DCHECK(tabId);
   DCHECK(infoBarManager);
 
   // Nothing to do if the infobar are not visible at this point in time.
   if (!upgradeInfoBarIsVisible_)
     return;
 
   // Nothing to do if the infobar is already there.
   if ([upgradeInfoBarDelegates_ objectForKey:tabId])
     return;
 
   auto infobarDelegate = base::MakeUnique<UpgradeInfoBarDelegate>();
-  base::scoped_nsobject<DelegateHolder> delegateHolder([[DelegateHolder alloc]
-      initWithInfoBarManager:infoBarManager
-             infoBarDelegate:infobarDelegate.get()
-               upgradeCenter:self
-                       tabId:tabId]);
+  DelegateHolder* delegateHolder =
+      [[DelegateHolder alloc] initWithInfoBarManager:infoBarManager
+                                     infoBarDelegate:infobarDelegate.get()
+                                       upgradeCenter:self
+                                               tabId:tabId];
 
   [upgradeInfoBarDelegates_ setObject:delegateHolder forKey:tabId];
   infoBarManager->AddInfoBar(
       infoBarManager->CreateConfirmInfoBar(std::move(infobarDelegate)));
 }
 
 - (void)tabWillClose:(NSString*)tabId {
   [upgradeInfoBarDelegates_ removeObjectForKey:tabId];
 }
 
 - (void)dismissedInfoBar:(NSString*)tabId performUpgrade:(BOOL)shouldUpgrade {
   // If the tabId is not in the upgradeInfoBarDelegates_ just ignore the
   // notification. In all likelyhood it was trigerred by calling
   // -hideUpgradeInfoBars. Or because a tab was closed without dismissing the
   // infobar.
-  base::scoped_nsobject<DelegateHolder> delegateHolder(
-      [[upgradeInfoBarDelegates_ objectForKey:tabId] retain]);
-  if (!delegateHolder.get())
+  DelegateHolder* delegateHolder =
+      [upgradeInfoBarDelegates_ objectForKey:tabId];
+  if (!delegateHolder)
     return;
 
   // Forget about this dismissed infobar.
   [upgradeInfoBarDelegates_ removeObjectForKey:tabId];
 
   // Get rid of all the infobars on the other tabs.
   [self hideUpgradeInfoBars];
 
   if (shouldUpgrade) {
     NSString* urlString =
         [[NSUserDefaults standardUserDefaults] valueForKey:kUpgradeURLKey];
     if (!urlString)
       return;  // Missing URL, no upgrade possible.
 
     GURL url = GURL(base::SysNSStringToUTF8(urlString));
     if (!url.is_valid())
       return;
 
     if (web::UrlHasWebScheme(url)) {
       // This URL can be opened in the application, just open in a new tab.
-      base::scoped_nsobject<OpenUrlCommand> command(
-          [[OpenUrlCommand alloc] initWithURLFromChrome:url]);
+      OpenUrlCommand* command =
+          [[OpenUrlCommand alloc] initWithURLFromChrome:url];
       UIWindow* main_window = [[UIApplication sharedApplication] keyWindow];
       DCHECK(main_window);
       [main_window chromeExecuteCommand:command];
     } else {
       // This URL scheme is not understood, ask the system to open it.
       NSURL* nsurl = [NSURL URLWithString:urlString];
       if (nsurl) {
         OpenUrlWithCompletionHandler(nsurl, nil);
       }
     }
   }
 }
 
 - (void)showUpgradeInfoBars {
 // Add an infobar on all the open tabs.
 #ifndef NDEBUG
   inCallback_ = YES;
 #endif
   upgradeInfoBarIsVisible_ = YES;
-  std::set<id<UpgradeCenterClientProtocol>>::iterator it;
-  for (it = clients_.begin(); it != clients_.end(); ++it)
-    [*it showUpgrade:self];
+  for (id<UpgradeCenterClientProtocol> upgradeClient in clients_)
+    [upgradeClient showUpgrade:self];
 #ifndef NDEBUG
   inCallback_ = NO;
 #endif
 
   [[NSUserDefaults standardUserDefaults] setObject:[NSDate date]
                                             forKey:kLastInfobarDisplayTimeKey];
 }
 
 - (void)hideUpgradeInfoBars {
   upgradeInfoBarIsVisible_ = NO;
   // It is important to call -allKeys here and not using a fast iteration on the
   // dictionary directly: the dictionary is modified as we go...
   for (NSString* tabId in [upgradeInfoBarDelegates_ allKeys]) {
     // It is important to retain the delegateHolder as otherwise it is
     // deallocated as soon as it is removed from the dictionary.
-    base::scoped_nsobject<DelegateHolder> delegateHolder(
-        [[upgradeInfoBarDelegates_ objectForKey:tabId] retain]);
-    if (delegateHolder.get()) {
+    DelegateHolder* delegateHolder =
+        [upgradeInfoBarDelegates_ objectForKey:tabId];
+    if (delegateHolder) {
       [upgradeInfoBarDelegates_ removeObjectForKey:tabId];
       UpgradeInfoBarDelegate* delegate = [delegateHolder infoBarDelegate];
       DCHECK(delegate);
       delegate->RemoveSelf();
     }
   }
 }
 
 - (void)upgradeNotificationDidOccur:(const UpgradeRecommendedDetails&)details {
   const GURL& upgradeUrl = details.upgrade_url;
@@ skipping 31 matching lines @@
   if ([self shouldShowInfoBar])
     [self showUpgradeInfoBars];
 }
 
 - (void)resetForTests {
   [[UpgradeCenter sharedInstance] hideUpgradeInfoBars];
   NSUserDefaults* defaults = [NSUserDefaults standardUserDefaults];
   [defaults removeObjectForKey:kNextVersionKey];
   [defaults removeObjectForKey:kUpgradeURLKey];
   [defaults removeObjectForKey:kLastInfobarDisplayTimeKey];
-  clients_.clear();
+  [clients_ removeAllObjects];
 }
 
 - (void)setLastDisplayToPast {
   NSDate* pastDate =
       [NSDate dateWithTimeIntervalSinceNow:-(kInfobarDisplayInterval + 1)];
   [[NSUserDefaults standardUserDefaults] setObject:pastDate
                                             forKey:kLastInfobarDisplayTimeKey];
 }
 
 @end