[ObjC ARC] Converts ios/web:earl_grey_test_support to ARC.

ios/web/public/test/earl_grey/web_view_matchers.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/web/public/test/earl_grey/web_view_matchers.h"
 
 #import <UIKit/UIKit.h>
 #import <WebKit/WebKit.h>
 
 #import "base/mac/bind_objc_block.h"
-#import "base/mac/scoped_nsobject.h"
 #include "base/strings/stringprintf.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/strings/utf_string_conversions.h"
 #import "base/test/ios/wait_util.h"
 #include "base/values.h"
 #import "ios/testing/wait_util.h"
 #import "ios/web/interstitials/web_interstitial_impl.h"
 #import "ios/web/public/test/earl_grey/js_test_util.h"
 #import "ios/web/public/test/web_view_interaction_test_util.h"
 #import "net/base/mac/url_conversions.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 using testing::kWaitForDownloadTimeout;
 using testing::WaitUntilConditionOrTimeout;
 
 // A helper delegate class that allows downloading responses with invalid
 // SSL certs.
 @interface TestURLSessionDelegate : NSObject<NSURLSessionDelegate>
 @end
 
 @implementation TestURLSessionDelegate
 
@@ skipping 19 matching lines @@
 };
 
 // Script that returns document.body as a string.
 char kGetDocumentBodyJavaScript[] =
     "document.body ? document.body.textContent : null";
 // Script that tests presence of css selector.
 char kTestCssSelectorJavaScriptTemplate[] = "!!document.querySelector(\"%s\");";
 
 // Fetches the image from |image_url|.
 UIImage* LoadImage(const GURL& image_url) {
-  __block base::scoped_nsobject<UIImage> image;
-  __block base::scoped_nsobject<NSError> error;
+  __block UIImage* image;
+  __block NSError* error;
   TestURLSessionDelegate* session_delegate =
       [[TestURLSessionDelegate alloc] init];
   NSURLSessionConfiguration* session_config =
       [NSURLSessionConfiguration defaultSessionConfiguration];
   NSURLSession* session =
       [NSURLSession sessionWithConfiguration:session_config
                                     delegate:session_delegate
                                delegateQueue:nil];
   id completion_handler = ^(NSData* data, NSURLResponse*, NSError* task_error) {
     if (task_error) {

[Eugene But (OOO till 7-30), 2017/05/16 22:39:37]

Do we even need this if-else? Should we simply assign the values?

[baxley, 2017/06/02 15:39:38]

Done.

-      error.reset([task_error retain]);
+      error = task_error;
     } else {
-      image.reset([[UIImage alloc] initWithData:data]);
+      image = [[UIImage alloc] initWithData:data];
     }
-    [session_delegate autorelease];
   };
 
   NSURLSessionDataTask* task =
       [session dataTaskWithURL:net::NSURLWithGURL(image_url)
              completionHandler:completion_handler];
   [task resume];
 
   bool image_loaded = WaitUntilConditionOrTimeout(kWaitForDownloadTimeout, ^{
     return image || error;
   });
   GREYAssert(image_loaded, @"Failed to download image");
 
-  return [[image retain] autorelease];
+  return image;
 }
 
 // Helper function for matching web views containing or not containing |text|,
 // depending on the value of |should_contain_text|.
 id<GREYMatcher> WebViewWithText(std::string text,
                                 web::WebState* web_state,
                                 bool should_contain_text) {
   MatchesBlock matches = ^BOOL(WKWebView*) {
     return WaitUntilConditionOrTimeout(testing::kWaitForUIElementTimeout, ^{
       std::unique_ptr<base::Value> value =
           web::test::ExecuteJavaScript(web_state, kGetDocumentBodyJavaScript);
       std::string body;
       if (value && value->GetAsString(&body)) {
         BOOL contains_text = body.find(text) != std::string::npos;
         return contains_text == should_contain_text;
       }
       return false;
     });
   };
 
   DescribeToBlock describe = ^(id<GREYDescription> description) {
     [description appendText:should_contain_text ? @"web view containing "
                                                 : @"web view not containing "];
     [description appendText:base::SysUTF8ToNSString(text)];
   };
 
-  return grey_allOf(WebViewInWebState(web_state),
-                    [[[GREYElementMatcherBlock alloc]
-                        initWithMatchesBlock:matches
-                            descriptionBlock:describe] autorelease],
-                    nil);
+  return grey_allOf(
+      WebViewInWebState(web_state),
+      [[GREYElementMatcherBlock alloc] initWithMatchesBlock:matches
+                                           descriptionBlock:describe],
+      nil);
 }
 
 // Matcher for WKWebView containing loaded or blocked image with |image_id|.
 // Pass IMAGE_STATE_LOADED |image_state| to match fully loaded image and
 // IMAGE_STATE_BLOCKED to match fully blocked image.
 id<GREYMatcher> WebViewContainingImage(std::string image_id,
                                        web::WebState* web_state,
                                        ImageState image_state) {
   std::string get_url_script =
       base::StringPrintf("document.getElementById('%s').src", image_id.c_str());
@@ skipping 51 matching lines @@
         [description appendText:@"web view blocked resource with id "];
         break;
       case IMAGE_STATE_LOADED:
         [description appendText:@"web view loaded resource with id "];
         break;
     }
 
     [description appendText:base::SysUTF8ToNSString(image_id)];
   };
 
-  return grey_allOf(WebViewInWebState(web_state),
-                    [[[GREYElementMatcherBlock alloc]
-                        initWithMatchesBlock:matches
-                            descriptionBlock:describe] autorelease],
-                    nil);
+  return grey_allOf(
+      WebViewInWebState(web_state),
+      [[GREYElementMatcherBlock alloc] initWithMatchesBlock:matches
+                                           descriptionBlock:describe],
+      nil);
 }
 
 }  // namespace
 
 namespace web {
 
 id<GREYMatcher> WebViewInWebState(WebState* web_state) {
   MatchesBlock matches = ^BOOL(UIView* view) {
     return [view isKindOfClass:[WKWebView class]] &&
            [view isDescendantOfView:web_state->GetView()];
   };
 
   DescribeToBlock describe = ^(id<GREYDescription> description) {
     [description appendText:@"web view in web state"];
   };
 
-  return [[[GREYElementMatcherBlock alloc] initWithMatchesBlock:matches
-                                               descriptionBlock:describe]
-      autorelease];
+  return [[GREYElementMatcherBlock alloc] initWithMatchesBlock:matches
+                                              descriptionBlock:describe];
 }
 
 id<GREYMatcher> WebViewContainingText(std::string text, WebState* web_state) {
   return WebViewWithText(text, web_state, true);
 }
 
 id<GREYMatcher> WebViewNotContainingText(std::string text,
                                          WebState* web_state) {
   return WebViewWithText(text, web_state, false);
 }
@@ skipping 21 matching lines @@
       }
       return did_succeed;
     });
   };
 
   DescribeToBlock describe = ^(id<GREYDescription> description) {
     [description appendText:@"web view selector "];
     [description appendText:base::SysUTF8ToNSString(selector)];
   };
 
-  return grey_allOf(WebViewInWebState(web_state),
-                    [[[GREYElementMatcherBlock alloc]
-                        initWithMatchesBlock:matches
-                            descriptionBlock:describe] autorelease],
-                    nil);
+  return grey_allOf(
+      WebViewInWebState(web_state),
+      [[GREYElementMatcherBlock alloc] initWithMatchesBlock:matches
+                                           descriptionBlock:describe],
+      nil);
 }
 
 id<GREYMatcher> WebViewScrollView(WebState* web_state) {
   MatchesBlock matches = ^BOOL(UIView* view) {
     return [view isKindOfClass:[UIScrollView class]] &&
            [view.superview isKindOfClass:[WKWebView class]] &&
            [view isDescendantOfView:web_state->GetView()];
   };
 
   DescribeToBlock describe = ^(id<GREYDescription> description) {
     [description appendText:@"web view scroll view"];
   };
 
-  return [[[GREYElementMatcherBlock alloc] initWithMatchesBlock:matches
-                                               descriptionBlock:describe]
-      autorelease];
+  return [[GREYElementMatcherBlock alloc] initWithMatchesBlock:matches
+                                              descriptionBlock:describe];
 }
 
 id<GREYMatcher> Interstitial(WebState* web_state) {
   MatchesBlock matches = ^BOOL(WKWebView* view) {
     web::WebInterstitialImpl* interstitial =
         static_cast<web::WebInterstitialImpl*>(web_state->GetWebInterstitial());
     return interstitial &&
            [view isDescendantOfView:interstitial->GetContentView()];
   };
 
   DescribeToBlock describe = ^(id<GREYDescription> description) {
     [description appendText:@"interstitial displayed"];
   };
 
-  return grey_allOf(WebViewInWebState(web_state),
-                    [[[GREYElementMatcherBlock alloc]
-                        initWithMatchesBlock:matches
-                            descriptionBlock:describe] autorelease],
-                    nil);
+  return grey_allOf(
+      WebViewInWebState(web_state),
+      [[GREYElementMatcherBlock alloc] initWithMatchesBlock:matches
+                                           descriptionBlock:describe],
+      nil);
 }
 
 id<GREYMatcher> InterstitialContainingText(NSString* text,
                                            WebState* web_state) {
   MatchesBlock matches = ^BOOL(WKWebView* view) {
     return WaitUntilConditionOrTimeout(testing::kWaitForUIElementTimeout, ^{
       NSString* script = base::SysUTF8ToNSString(kGetDocumentBodyJavaScript);
       id body = ExecuteScriptOnInterstitial(web_state, script);
       return [body containsString:text] ? true : false;
     });
   };
 
   DescribeToBlock describe = ^(id<GREYDescription> description) {
     [description appendText:@"interstitial containing "];
     [description appendText:text];
   };
 
-  return grey_allOf(Interstitial(web_state),
-                    [[[GREYElementMatcherBlock alloc]
-                        initWithMatchesBlock:matches
-                            descriptionBlock:describe] autorelease],
-                    nil);
+  return grey_allOf(
+      Interstitial(web_state),
+      [[GREYElementMatcherBlock alloc] initWithMatchesBlock:matches
+                                           descriptionBlock:describe],
+      nil);
 }
 
 }  // namespace web