Implementing sign-in promo for "Other Devices" on the iPad

ios/chrome/browser/ui/tab_switcher/tab_switcher_panel_overlay_view.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/tab_switcher/tab_switcher_panel_overlay_view.h"
 
 #include "base/metrics/user_metrics.h"
 #include "base/metrics/user_metrics_action.h"
+#include "components/signin/core/browser/signin_metrics.h"
+#include "ios/chrome/browser/experimental_flags.h"
+#import "ios/chrome/browser/ui/authentication/signin_promo_view.h"
+#import "ios/chrome/browser/ui/authentication/signin_promo_view_configurator.h"
+#import "ios/chrome/browser/ui/authentication/signin_promo_view_consumer.h"
+#import "ios/chrome/browser/ui/authentication/signin_promo_view_mediator.h"
 #import "ios/chrome/browser/ui/colors/MDCPalette+CrAdditions.h"
 #import "ios/chrome/browser/ui/commands/UIKit+ChromeExecuteCommand.h"
 #include "ios/chrome/browser/ui/commands/ios_command_ids.h"
 #import "ios/chrome/browser/ui/commands/show_signin_command.h"
 #import "ios/chrome/browser/ui/material_components/activity_indicator.h"
 #import "ios/chrome/browser/ui/sync/sync_util.h"
 #import "ios/chrome/browser/ui/tab_switcher/tab_switcher_model.h"
 #import "ios/chrome/browser/ui/uikit_ui_util.h"
 #include "ios/chrome/grit/ios_chromium_strings.h"
 #include "ios/chrome/grit/ios_strings.h"
@@ skipping 26 matching lines @@
   }
 }
 
 namespace {
 const CGFloat kContainerOriginYOffset = -58.0;
 const CGFloat kContainerWidth = 400.0;
 const CGFloat kTitleMinimumLineHeight = 32.0;
 const CGFloat kSubtitleMinimunLineHeight = 24.0;
 }
 
-@interface TabSwitcherPanelOverlayView ()
+@interface TabSwitcherPanelOverlayView ()<SigninPromoViewConsumer>
 
 // Updates the texts of labels and button according to the current
 // |overlayType|.
 - (void)updateText;
 // Updates the button target and tag according to the current |overlayType|.
 - (void)updateButtonTarget;
 // Sends a SignIn chrome command.
 - (void)showSignIn;
 
 @end
 
 @implementation TabSwitcherPanelOverlayView {
   ios::ChromeBrowserState* _browserState;  // Weak.
   UIView* _container;
   UILabel* _titleLabel;
   UILabel* _subtitleLabel;
   MDCButton* _textButton;
   MDCButton* _floatingButton;
   MDCActivityIndicator* _activityIndicator;
   std::string _recordedMetricString;
+  SigninPromoViewMediator* _signinPromoViewMediator;
+  SigninPromoView* _signinPromoView;
 }
 
 @synthesize overlayType = _overlayType;
 
 - (instancetype)initWithFrame:(CGRect)frame
                  browserState:(ios::ChromeBrowserState*)browserState {
   self = [super initWithFrame:frame];
   if (self) {
     _browserState = browserState;
     // Create and add container. Will be vertically and horizontally centered.
@@ skipping 74 matching lines @@
       @"H:|-[subtitle]-|", @"H:[button(>=180)]", @"H:[floatingButton(==48)]"
     ];
     ApplyVisualConstraints(constraints, viewsDictionary, _container);
 
     // Sets the container's width relative to the parent.
     ApplyVisualConstraintsWithMetrics(
         @[
           @"H:|-(>=0)-[container(==containerWidth@999)]-(>=0)-|",
         ],
         @{ @"container" : _container },
-        @{ @"containerWidth" : @(kContainerWidth) }, self);
+        @{ @"containerWidth" : @(kContainerWidth) });
   }
   return self;
 }
 
 - (void)layoutSubviews {
   [super layoutSubviews];
   CGRect containerFrame = [_container frame];
   containerFrame.origin.x =
       (self.frame.size.width - containerFrame.size.width) / 2;
   containerFrame.origin.y =
       (self.frame.size.height - containerFrame.size.height) / 2 +
       kContainerOriginYOffset;
   [_container setFrame:containerFrame];
 }
 
 - (void)setOverlayType:(TabSwitcherPanelOverlayType)overlayType {
   _overlayType = overlayType;
-  [self updateText];
-  [self updateButtonTarget];
+  if (experimental_flags::IsSigninPromoEnabled() &&
+      _overlayType ==
+          TabSwitcherPanelOverlayType::OVERLAY_PANEL_USER_SIGNED_OUT) {
+    [self createSigninPromoviewIfNeeded];
+    _container.hidden = YES;
+  } else {
+    _container.hidden = NO;
+    [_signinPromoView removeFromSuperview];
+    _signinPromoView = nil;
+    _signinPromoViewMediator.consumer = nil;
+    _signinPromoViewMediator = nil;
+    [self updateText];
+    [self updateButtonTarget];
+  }
 }
 
 #pragma mark - Private
 
+// Creates the sign-in view and its mediator if it doesn't exist.
+- (void)createSigninPromoviewIfNeeded {
+  if (_signinPromoView) {
+    DCHECK(_signinPromoViewMediator);
+    return;
+  }
+  _signinPromoView = [[SigninPromoView alloc] initWithFrame:CGRectZero];
+  _signinPromoView.translatesAutoresizingMaskIntoConstraints = NO;
+  _signinPromoView.textLabel.text =
+      l10n_util::GetNSString(IDS_IOS_SIGNIN_PROMO_RECENT_TABS);
+  _signinPromoView.textLabel.textColor = [UIColor whiteColor];
+  _signinPromoView.textLabel.font = [MDCTypography headlineFont];
+  _signinPromoView.textLabel.preferredMaxLayoutWidth =
+      kContainerWidth - (2 * _signinPromoView.horizontalPadding);
+  [self addSubview:_signinPromoView];
+  ApplyVisualConstraintsWithMetrics(
+      @[ @"H:[signinPromoView(containerWidth)]" ],
+      @{ @"signinPromoView" : _signinPromoView },
+      @{ @"containerWidth" : @(kContainerWidth) });
+  AddSameCenterXConstraint(_signinPromoView, self);
+  [_signinPromoView.centerYAnchor
+      constraintEqualToAnchor:self.centerYAnchor
+                     constant:kContainerOriginYOffset]
+      .active = YES;
+  _signinPromoViewMediator = [[SigninPromoViewMediator alloc] init];
+  _signinPromoViewMediator.accessPoint =
+      signin_metrics::AccessPoint::ACCESS_POINT_RECENT_TABS;
+  _signinPromoView.delegate = _signinPromoViewMediator;
+  _signinPromoViewMediator.consumer = self;
+  [[_signinPromoViewMediator createConfigurator]
+      configureSigninPromoView:_signinPromoView];
+}
+
 - (void)updateText {
+  DCHECK(_signinPromoView == nil && _signinPromoViewMediator == nil);
   NSMutableAttributedString* titleString = nil;
   NSMutableAttributedString* subtitleString = nil;
 
   NSString* buttonTitle = nil;
   UIImage* buttonImage = nil;
   NSString* buttonAccessibilityLabel = nil;
   UIColor* floatingButtonNormalBackgroundColor = nil;
   UIColor* floatingButtonDisabledBackgroundColor = nil;
   UIColor* floatingButtonInkColor = nil;
   BOOL spinnerIsHidden = YES;
   switch (self.overlayType) {
     case TabSwitcherPanelOverlayType::OVERLAY_PANEL_EMPTY:
       break;
     case TabSwitcherPanelOverlayType::OVERLAY_PANEL_USER_SIGNED_OUT:
+      DCHECK(!experimental_flags::IsSigninPromoEnabled());
       titleString = [[NSMutableAttributedString alloc]
           initWithString:l10n_util::GetNSString(
                              IDS_IOS_TAB_SWITCHER_SIGN_IN_ACCOUNT_TITLE)];
       subtitleString = [[NSMutableAttributedString alloc]
           initWithString:l10n_util::GetNSString(
                              IDS_IOS_TAB_SWITCHER_SIGN_IN_ACCOUNT_PROMO)];
       buttonTitle =
           l10n_util::GetNSString(IDS_IOS_TAB_SWITCHER_SIGN_IN_ACCOUNT_BUTTON);
       break;
     case TabSwitcherPanelOverlayType::OVERLAY_PANEL_USER_SIGNED_IN_SYNC_OFF:
@@ skipping 99 matching lines @@
   [_floatingButton setAccessibilityLabel:buttonAccessibilityLabel];
   [_activityIndicator setHidden:spinnerIsHidden];
   if (spinnerIsHidden) {
     [_activityIndicator stopAnimating];
   } else {
     [_activityIndicator startAnimating];
   }
 }
 
 - (void)updateButtonTarget {
+  DCHECK(_signinPromoView == nil && _signinPromoViewMediator == nil);
   NSInteger tag = 0;
   SEL selector = nil;
   _recordedMetricString = "";
 
   BOOL shouldShowTextButton = YES;
   BOOL shouldShowFloatingButton = NO;
   switch (self.overlayType) {
     case TabSwitcherPanelOverlayType::OVERLAY_PANEL_EMPTY:
       shouldShowTextButton = NO;
       break;
     case TabSwitcherPanelOverlayType::OVERLAY_PANEL_USER_SIGNED_OUT:
+      DCHECK(!experimental_flags::IsSigninPromoEnabled());
       selector = @selector(showSignIn);
       _recordedMetricString = "MobileTabSwitcherSignIn";
       break;
     case TabSwitcherPanelOverlayType::OVERLAY_PANEL_USER_SIGNED_IN_SYNC_OFF:
       selector = @selector(showSyncSettings);
       _recordedMetricString = "MobileTabSwitcherEnableSync";
       break;
     case TabSwitcherPanelOverlayType::
         OVERLAY_PANEL_USER_SIGNED_IN_SYNC_ON_NO_SESSIONS:
       shouldShowTextButton = NO;
@@ skipping 52 matching lines @@
 - (void)rootViewControllerChromeCommand:(id)command {
   [self chromeExecuteCommand:command];
 }
 
 - (void)recordMetrics {
   if (!_recordedMetricString.length())
     return;
   base::RecordAction(base::UserMetricsAction(_recordedMetricString.c_str()));
 }
 
+#pragma mark - SigninPromoViewConsumer
+
+- (void)configureSigninPromoViewWithNewIdentity:(BOOL)newIdentity
+                                   configurator:(SigninPromoViewConfigurator*)
+                                                    configurator {
+  DCHECK(_signinPromoView);
+  DCHECK(_signinPromoViewMediator);
+  [configurator configureSigninPromoView:_signinPromoView];
+}
+
 @end