Optimize yasm even in debug builds

third_party/yasm/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # The yasm build process creates a slew of small C subprograms that
 # dynamically generate files at various point in the build process.  This makes
 # the build integration moderately complex.
 #
 # There are three classes of dynamically generated files:
 #   1) C source files that should be included in the build (eg., lc3bid.c)
@@ skipping 11 matching lines @@
 #   3) yasm_utils -- Object files with memory management and hashing utilities
 #              shared between yasm and the genperf subprogram.
 #   4) genmacro, genmodule, etc. -- One executable target for each subprogram.
 #   5) generate_license, generate_module, etc. -- Actions that invoke programs
 #              built in #4 to generate .c files.
 #   6) compile_gperf, compile_re2c, etc. -- Actions that invoke programs that
 #              turn intermediate files into .c files.
 
 import("//build/config/compiler/compiler.gni")
 
+configs_to_delete = []
+configs_to_add = []
+if (is_debug) {
+  configs_to_delete += [
+    # Build with full optimizations even on debug configurations, because some
+    # yasm build steps (highbd_sad4d_sse2.asm) can take ~33 seconds or more in
+    # debug component builds on Windows. Enabling compiler optimizations saves
+    #  ~5 seconds.
+    "//build/config/compiler:default_optimization",
+
+    # Don't define _DEBUG. Modest savings, but good for consistency.
+    "//build/config:debug",
+  ]
+  configs_to_add += [
+    "//build/config:release",
+    "//build/config/compiler:optimize_max",
+  ]
+  if (is_win) {
+    # This switches to using the release CRT. On debug component builds of
+    # highbd_sad4d_sse2.asm on Windows this saves about 15 s.
+    configs_to_delete += [ "//build/config/win:default_crt" ]
+    configs_to_add += [ "//build/config/win:release_crt" ]
+  }
+}
+
 if (current_toolchain == host_toolchain) {
   # Various files referenced by multiple targets.
   yasm_gen_include_dir = "$target_gen_dir/include"
   config_makefile = "source/config/$host_os/Makefile"
   version_file = "version.mac"
 
   import("//build/compiled_action.gni")
 
   config("yasm_config") {
     include_dirs = [
@@ skipping 45 matching lines @@
       "source/patched-yasm/tools/genperf/genperf.c",
       "source/patched-yasm/tools/genperf/perfect.c",
     ]
 
     configs -= [ "//build/config/compiler:chromium_code" ]
     configs += [
       ":yasm_config",
       "//build/config/compiler:no_chromium_code",
     ]
 
+    # Must be compatible with yasm_utils/yasm
+    configs -= configs_to_delete
+    configs += configs_to_add
+
     deps = [
       ":yasm_utils",
       "//build/config/sanitizers:deps",
 
       # Default manifest on Windows (a no-op elsewhere).
       "//build/win:default_exe_manifest",
     ]
   }
 
   # Used by both yasm and genperf binaries.
   static_library("yasm_utils") {
     sources = [
       "source/patched-yasm/libyasm/phash.c",
       "source/patched-yasm/libyasm/xmalloc.c",
       "source/patched-yasm/libyasm/xstrdup.c",
     ]
 
     configs -= [ "//build/config/compiler:chromium_code" ]
     configs += [
       ":yasm_config",
       "//build/config/compiler:no_chromium_code",
     ]
+
+    # Must be compatible with yasm
+    configs -= configs_to_delete
+    configs += configs_to_add
   }
 
   executable("genstring") {
     sources = [
       "source/patched-yasm/genstring.c",
     ]
     configs -= [ "//build/config/compiler:chromium_code" ]
     configs += [
       ":yasm_config",
       "//build/config/compiler:no_chromium_code",
@@ skipping 172 matching lines @@
 
       # Must be after no_chromium_code for warning flags to be ordered
       # correctly.
       ":yasm_warnings",
     ]
 
     # Disable WPO for yasm: crbug.com/604808
     if (is_official_build && full_wpo_on_official) {
       configs -= [ "//build/config/compiler:default_optimization" ]
       configs += [ "//build/config/compiler:optimize_no_wpo" ]
+    } else {
+      configs -= configs_to_delete
+      configs += configs_to_add
     }
 
     # Yasm generates a bunch of .c files which its source file #include.
     # Add the |target_gen_dir| into the include path so it can find them.
     # Ideally, these generated .c files would be placed into a separate
     # directory, but the gen_x86_insn.py script does not make this easy.
     include_dirs = [ yasm_gen_include_dir ]
 
     if (!is_win) {
       cflags = [
@@ skipping 217 matching lines @@
 
     # Output eventually #included by source/patched-yasm/frontends/yasm/x86id.c
     outputs = [
       "$yasm_gen_include_dir/x86insns.c",
       "$yasm_gen_include_dir/x86insn_gas.gperf",
       "$yasm_gen_include_dir/x86insn_nasm.gperf",
     ]
     args = [ rebase_path(yasm_gen_include_dir, root_build_dir) ]
   }
 }