Revert of Build FreeType with HarfBuzz support

third_party/freetype/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chromecast_build.gni")
-import("//third_party/harfbuzz-ng/harfbuzz.gni")
 
 config("freetype_config") {
   include_dirs = [
     "include",
     "src/include",
   ]
 }
 
 config("freetype-warnings") {
   cflags = []
 
   if (is_clang) {
     # The reduction of FreeType files to a minimum triggers -Wunused-function
     # warnings in ftbase.c
 
     # "-Wno-int-to-pointer-cast" tracked by
     # https://savannah.nongnu.org/bugs/index.php?50560,
     # TODO(drott): Remove this once we roll past 7aeee3c50f2656b65f.
     cflags += [
       "-Wno-unused-function",
       "-Wno-int-to-pointer-cast",
     ]
   }
 }
 
-# This component is used to resolve a cyclic dependency between HarfBuzz and
-# FreeType. HarfBuzz needs basic FreeType glyph information symbols for its
-# hb-ft.* functions, FreeType needs HarfBuzz' OpenType parsing functionality in
-# the autohinting code. We start by building a minimum FreeType here - enough to
-# satisfy harfbuzz-ng-ft symbol requirements. Then we can build harfbuzz-ng-ft
-# based on the minimal FreeType and harfbuzz-ng which does not depend on
-# FreeType itself. Then we build FreeType depending on harfbuzz-ng-ft and
-# harfbuzz-ng.
-static_library("bootstrap_freetype_for_harfbuzz") {
-  visibility = [
-    "//third_party/harfbuzz-ng:harfbuzz-ng-ft",
-    ":freetype",
-  ]
-
-  defines = []
-
-  sources = [
-    "include/freetype-custom-config/ftmodule.h",
-    "include/freetype-custom-config/ftoption.h",
-    "src/src/base/ftbase.c",
-    "src/src/base/ftbitmap.c",
-    "src/src/base/ftsystem.c",
-  ]
-
-  if (is_mac && !is_component_build) {
-    defines += [ "MAC_RESTRICT_VISIBILITY" ]
-  }
-
-  defines += [
-    "FT2_BUILD_LIBRARY",
-    "DARWIN_NO_CARBON",
-
-    # Long directory name to avoid accidentally using wrong headers.
-    # GN currently does not escape '<' and '>' when generating xml based Visual
-    # Studio project files. As a result, use quotes instead of pointy brackets
-    # in these defines.
-    "FT_CONFIG_MODULES_H=\"freetype-custom-config/ftmodule.h\"",
-    "FT_CONFIG_OPTIONS_H=\"freetype-custom-config/ftoption.h\"",
-  ]
-
-  if (is_win && is_component_build) {
-    # Used for managing declspec(dllimport/export) visibility.
-    defines += [ "FT2_BUILD_DLL" ]
-  }
-
-  public_configs = [ ":freetype_config" ]
-  configs -= [ "//build/config/compiler:chromium_code" ]
-  configs += [ "//build/config/compiler:no_chromium_code" ]
-
-  configs += [ ":freetype-warnings" ]
-}
-
 component("freetype") {
   if (is_linux) {
     output_name = "freetype"
     output_extension = "so.6"
   }
 
   defines = []
 
   sources = [
     "include/freetype-custom-config/ftmodule.h",
     "include/freetype-custom-config/ftoption.h",
     "src/src/autofit/autofit.c",
+    "src/src/base/ftbase.c",
     "src/src/base/ftbbox.c",
+    "src/src/base/ftbitmap.c",
     "src/src/base/ftfntfmt.c",
     "src/src/base/ftfstype.c",
     "src/src/base/ftgasp.c",
     "src/src/base/ftglyph.c",
     "src/src/base/ftinit.c",
     "src/src/base/ftlcdfil.c",
     "src/src/base/ftmm.c",
     "src/src/base/ftstroke.c",
+    "src/src/base/ftsystem.c",
     "src/src/base/fttype1.c",
     "src/src/cff/cff.c",
     "src/src/gzip/ftgzip.c",
     "src/src/pshinter/pshinter.c",
     "src/src/psnames/psnames.c",
     "src/src/raster/raster.c",
     "src/src/sfnt/sfnt.c",
     "src/src/smooth/smooth.c",
     "src/src/truetype/truetype.c",
   ]
@@ skipping 31 matching lines @@
     "DARWIN_NO_CARBON",
 
     # Long directory name to avoid accidentally using wrong headers.
     # GN currently does not escape '<' and '>' when generating xml based Visual
     # Studio project files. As a result, use quotes instead of pointy brackets
     # in these defines.
     "FT_CONFIG_MODULES_H=\"freetype-custom-config/ftmodule.h\"",
     "FT_CONFIG_OPTIONS_H=\"freetype-custom-config/ftoption.h\"",
   ]
 
-  if (!use_system_harfbuzz) {
-    defines += [ "HAVE_HARFBUZZ_FT" ]
-  }
-
   if (is_win && is_component_build) {
     # Used for managing declspec(dllimport/export) visibility.
     defines += [ "FT2_BUILD_DLL" ]
   }
 
   public_configs = [ ":freetype_config" ]
   configs -= [ "//build/config/compiler:chromium_code" ]
   configs += [ "//build/config/compiler:no_chromium_code" ]
 
   configs += [ ":freetype-warnings" ]
 
   deps = [
     "//third_party/libpng",
     "//third_party/zlib",
   ]
-
-  public_deps = [
-    ":bootstrap_freetype_for_harfbuzz",
-  ]
-
-  if (!use_system_harfbuzz) {
-    deps += [
-      "//third_party/harfbuzz-ng:harfbuzz-ng",
-      "//third_party/harfbuzz-ng:harfbuzz-ng-ft",
-    ]
-  }
 }