[Chromecast] Add service for "displaying" cast web contents.

chromecast/browser/android/BUILD.gn

 # Copyright 2016 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
+import("//chromecast/chromecast.gni")
 import("//build/config/android/rules.gni")
 
 assert(is_android)
 
 cast_shell_android_manifest =
     "$root_gen_dir/cast_shell_manifest/AndroidManifest.xml"
 
 jinja_template("cast_shell_manifest") {
   input = "apk/AndroidManifest.xml.jinja2"
   output = cast_shell_android_manifest
 }
 
+java_cpp_template("cast_shell_build_config_gen") {
+  sources = [
+    "apk/templates/BuildConfig.template",
+  ]
+  package_path = "org/chromium/chromecast/shell"
+
+  defines = []
+  if (cast_android_use_service) {
+    defines += [ "_CAST_ANDROID_USE_SERVICE" ]
+  }
+}
+
 android_resources("cast_shell_android_resources") {
   android_manifest = cast_shell_android_manifest
   android_manifest_dep = ":cast_shell_manifest"
   resource_dirs = [ "//chromecast/browser/android/apk/res" ]
 }
 
 android_library("cast_shell_java") {
   java_src_dir = "//chromecast/browser/android/apk/src"
   java_files = [
     "$java_src_dir/org/chromium/chromecast/shell/CastApplication.java",
     "$java_src_dir/org/chromium/chromecast/shell/CastAudioManager.java",
     "$java_src_dir/org/chromium/chromecast/shell/CastBrowserHelper.java",
     "$java_src_dir/org/chromium/chromecast/shell/CastContentWindowAndroid.java",
     "$java_src_dir/org/chromium/chromecast/shell/CastCrashHandler.java",
     "$java_src_dir/org/chromium/chromecast/shell/CastCrashUploader.java",
     "$java_src_dir/org/chromium/chromecast/shell/CastMetricsHelper.java",
     "$java_src_dir/org/chromium/chromecast/shell/CastSysInfoAndroid.java",
     "$java_src_dir/org/chromium/chromecast/shell/CastWebContentsActivity.java",
+    "$java_src_dir/org/chromium/chromecast/shell/CastWebContentsService.java",
+    "$java_src_dir/org/chromium/chromecast/shell/CastWebContentsComponent.java",
     "$java_src_dir/org/chromium/chromecast/shell/LogcatExtractor.java",
   ]
 
   android_manifest = cast_shell_android_manifest
 
+  srcjar_deps = [ ":cast_shell_build_config_gen" ]
+
   deps = [
     ":cast_shell_android_resources",
     ":cast_shell_manifest",
     "//base:base_java",
     "//chromecast/base:base_java",
     "//content/public/android:content_java",
     "//device/geolocation:geolocation_java",
     "//media/base/android:media_java",
     "//net/android:net_java",
 
     # TODO(slan): We may need to pass this in as a parameter.
     "//third_party/android_tools:android_support_core_utils_java",
     "//ui/android:ui_java",
   ]
 }
+
+junit_binary("cast_shell_java_junit_tests") {

[Simeon, 2017/05/15 19:47:24]

Let's call this "cast_shell_junit_tests" for now, since "java" and
"junit" are somewhat redundant, and nothing else in Chromium uses "java_junit"
in their target names.

[thoren, 2017/05/15 22:25:23]

Done.

+  java_files = [ "junit/src/org/chromium/chromecast/shell/CastWebContentsComponentTest.java" ]
+
+  srcjar_deps = [ ":cast_shell_build_config_gen" ]
+
+  deps = [
+    ":cast_shell_java",
+    "//base:base_java_test_support",
+    "//content/public/android:content_java",
+    "//third_party/android_tools:android_support_core_utils_java",
+  ]
+}