Added translation policy API.

ios/web_view/internal/translate/cwv_translation_controller.mm

 // Copyright 2017 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/web_view/internal/translate/cwv_translation_controller_internal.h"
 
 #include <string>
 
 #include "base/memory/ptr_util.h"
 #include "base/strings/string16.h"
+#include "base/strings/sys_string_conversions.h"
 #include "components/translate/core/browser/translate_manager.h"
 #include "components/translate/core/browser/translate_ui_delegate.h"
 #import "ios/web_view/internal/translate/cwv_language_detection_result_internal.h"
 #import "ios/web_view/internal/translate/cwv_translation_language_internal.h"
 #import "ios/web_view/internal/translate/web_view_translate_client.h"
 #import "ios/web_view/public/cwv_translation_controller_delegate.h"
+#import "ios/web_view/public/cwv_translation_policy.h"
 
 #if !defined(__has_feature) || !__has_feature(objc_arc)
 #error "This file requires ARC support."
 #endif
 
 NSErrorDomain const CWVTranslationErrorDomain =
     @"org.chromium.chromewebview.TranslationErrorDomain";
 
 const NSInteger CWVTranslationErrorNetwork =
     translate::TranslateErrors::NETWORK;
@@ skipping 106 matching lines @@
       break;
     case translate::TRANSLATE_STEP_TRANSLATE_ERROR:
       break;
   }
 }
 
 #pragma mark - Public Methods
 
 - (void)translatePageFromLanguage:(CWVTranslationLanguage*)sourceLanguage
                        toLanguage:(CWVTranslationLanguage*)targetLanguage {
-  // TODO(706289): Use the passed parameters.
+  _translateUIDelegate->UpdateOriginalLanguage(
+      base::SysNSStringToUTF8(sourceLanguage.languageCode));
+  _translateUIDelegate->UpdateTargetLanguage(
+      base::SysNSStringToUTF8(targetLanguage.languageCode));
   _translateUIDelegate->Translate();
 }
 
 - (void)revertTranslation {
   _translateUIDelegate->RevertTranslation();
 }
 
+- (void)setTranslationPolicy:(CWVTranslationPolicy*)policy
+             forPageLanguage:(CWVTranslationLanguage*)pageLanguage {
+  std::string languageCode = base::SysNSStringToUTF8(pageLanguage.languageCode);
+  switch (policy.type) {
+    case CWVTranslationPolicyAsk: {
+      _translateUIDelegate->SetLanguageBlocked(false, languageCode);
+      std::string autoTargetLanguageCode =
+          _translateUIDelegate->GetAlwaysTranslateToLanguage(languageCode);
+      _translateUIDelegate->SetAlwaysTranslate(false, languageCode,
+                                               autoTargetLanguageCode);
+      break;
+    }
+    case CWVTranslationPolicyNever: {
+      _translateUIDelegate->SetLanguageBlocked(true, languageCode);
+      break;
+    }
+    case CWVTranslationPolicyAuto: {
+      _translateUIDelegate->SetAlwaysTranslate(
+          true, languageCode,
+          base::SysNSStringToUTF8(policy.language.languageCode));
+      break;
+    }
+  }
+}
+
+- (CWVTranslationPolicy*)translationPolicyForPageLanguage:
+    (CWVTranslationLanguage*)pageLanguage {
+  std::string languageCode = base::SysNSStringToUTF8(pageLanguage.languageCode);
+  std::string autoTargetLanguageCode =
+      _translateUIDelegate->GetAlwaysTranslateToLanguage(languageCode);
+  bool isLanguageBlocked =
+      _translateUIDelegate->IsLanguageBlocked(languageCode);
+  if (isLanguageBlocked) {
+    return [CWVTranslationPolicy translationPolicyNever];
+  } else if (!autoTargetLanguageCode.empty()) {
+    size_t autoTargetLanguageIndex =
+        _translateUIDelegate->GetLanguageIndex(autoTargetLanguageCode);
+    base::string16 autoTargetLanguageName =
+        _translateUIDelegate->GetLanguageNameAt(autoTargetLanguageIndex);
+    CWVTranslationLanguage* targetLanguage = [[CWVTranslationLanguage alloc]
+        initWithLanguageCode:autoTargetLanguageCode
+                languageName:autoTargetLanguageName];
+    return [CWVTranslationPolicy
+        translationPolicyAutoTranslateToLanguage:targetLanguage];
+  } else {
+    return [CWVTranslationPolicy translationPolicyAsk];
+  }
+}
+
+- (void)setTranslationPolicy:(CWVTranslationPolicy*)policy
+                 forPageHost:(NSString*)pageHost {
+  switch (policy.type) {
+    case CWVTranslationPolicyAsk: {
+      _translateUIDelegate->SetSiteBlacklist(false,
+                                             base::SysNSStringToUTF8(pageHost));
+      break;
+    }
+    case CWVTranslationPolicyNever: {
+      _translateUIDelegate->SetSiteBlacklist(true,
+                                             base::SysNSStringToUTF8(pageHost));
+      break;
+    }
+    case CWVTranslationPolicyAuto: {
+      NOTREACHED();
+      // TODO(crbug.com/706289): Support auto translation policies for websites.

[Hiroshi Ichikawa, 2017/05/11 04:14:15]

Nit: It may be better to put this comment before NOTREACHED().

[jzw1, 2017/05/11 04:43:00]

Done.

+      break;
+    }
+  }
+}
+
+- (CWVTranslationPolicy*)translationPolicyForPageHost:(NSString*)pageHost {
+  bool IsSiteBlackListed = _translateUIDelegate->IsSiteBlacklisted(
+      base::SysNSStringToUTF8(pageHost));
+  if (IsSiteBlackListed) {
+    return [CWVTranslationPolicy translationPolicyNever];
+  } else {
+    return [CWVTranslationPolicy translationPolicyAsk];
+  }
+}
+
 #pragma mark - Private Methods
 
 - (NSArray<CWVTranslationLanguage*>*)supportedLanguages {
   NSMutableArray* supportedLanguages = [NSMutableArray array];
   for (size_t i = 0; i < _translateUIDelegate->GetNumberOfLanguages(); i++) {
     CWVTranslationLanguage* language = [self languageAtIndex:i];
     [supportedLanguages addObject:language];
   }
 
   return [supportedLanguages copy];
 }
 
 - (CWVTranslationLanguage*)languageAtIndex:(size_t)index {
   std::string languageCode = _translateUIDelegate->GetLanguageCodeAt(index);
   base::string16 languageName = _translateUIDelegate->GetLanguageNameAt(index);
   return [[CWVTranslationLanguage alloc] initWithLanguageCode:languageCode
                                                  languageName:languageName];
 }
 
 @end