Adds Compose Email Settings UI for deprecating Native App Launcher

ios/chrome/browser/ui/settings/compose_email_handler_collection_view_controller.mm

Index: ios/chrome/browser/ui/settings/compose_email_handler_collection_view_controller.mm
diff --git a/ios/chrome/browser/ui/settings/compose_email_handler_collection_view_controller.mm b/ios/chrome/browser/ui/settings/compose_email_handler_collection_view_controller.mm
new file mode 100644
index 0000000000000000000000000000000000000000..8a8cc5ae080aa55ce33f5c59c05452c26037abba
--- /dev/null
+++ b/ios/chrome/browser/ui/settings/compose_email_handler_collection_view_controller.mm
@@ -0,0 +1,121 @@
+// Copyright 2017 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/chrome/browser/ui/settings/compose_email_handler_collection_view_controller.h"
+
+#include "base/mac/foundation_util.h"
+#import "ios/chrome/browser/ui/collection_view/cells/collection_view_text_item.h"
+#import "ios/chrome/browser/web/mailto_handler.h"
+#import "ios/chrome/browser/web/mailto_url_rewriter.h"
+#include "ios/chrome/grit/ios_strings.h"
+#include "ui/base/l10n/l10n_util.h"
+#include "ui/base/l10n/l10n_util_mac.h"
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+namespace {
+
+typedef NS_ENUM(NSInteger, SectionIdentifier) {
+  SectionIdentifierMailtoHandlers = kSectionIdentifierEnumZero,
+};
+
+typedef NS_ENUM(NSInteger, ItemType) {
+  ItemTypeMailtoHandlers = kItemTypeEnumZero,
+};
+
+}  // namespace
+
+@interface ComposeEmailHandlerCollectionViewController () {
+  MailtoURLRewriter* _rewriter;
+}
+@end
+
+@implementation ComposeEmailHandlerCollectionViewController
+
+- (instancetype)initWithRewriter:(MailtoURLRewriter*)rewriter {
+  self = [super initWithStyle:CollectionViewControllerStyleAppBar];
+  if (self) {
+    self.title = l10n_util::GetNSString(IDS_IOS_COMPOSE_EMAIL_SETTING);
+    self.collectionViewAccessibilityIdentifier =
+        @"compose_email_handler_view_controller";
+    _rewriter = rewriter;
+    [self loadModel];
+  }
+  return self;
+}
+
+- (instancetype)initWithStyle:(CollectionViewControllerStyle)style {

[rohitrao (ping after 24h), 2017/05/12 01:57:57]

This implementation should not be necessary if you marked it as NS_UNAVAILABLE
in the header.

[pkl (ping after 24h if needed), 2017/05/12 18:01:19]

Done.

+  NOTREACHED();
+  return nil;
+}
+
+- (void)loadModel {
+  [super loadModel];
+  CollectionViewModel* model = self.collectionViewModel;
+  [model addSectionWithIdentifier:SectionIdentifierMailtoHandlers];
+
+  // Since this is a one-of-several selection UI, there must be more than one
+  // choice available to the user. If this UI is being presented when there is
+  // only one choice, it is considered a software error.

[rohitrao (ping after 24h), 2017/05/12 01:57:57]

Why not always allow this UI to be shown, even if there is only one choice? 
It's a little silly, but at least the UI would always be present and always be
findable in the same place.

[pkl (ping after 24h if needed), 2017/05/12 18:01:19]

I've started a comment thread on the design doc. In the mean time, I'll submit
this CL in the current form. It's easy enough to change once a decision has been
reached.

+  NSArray<MailtoHandler*>* handlers = [_rewriter defaultHandlers];
+  DCHECK([handlers count] > 1);
+  NSString* currentHandlerID = [_rewriter defaultHandlerID];
+  for (MailtoHandler* handler in handlers) {
+    CollectionViewTextItem* item =
+        [[CollectionViewTextItem alloc] initWithType:ItemTypeMailtoHandlers];
+    [item setText:[handler appName]];
+    [item setAccessibilityTraits:UIAccessibilityTraitButton];
+    if ([currentHandlerID isEqualToString:[handler appStoreID]])
+      [item setAccessoryType:MDCCollectionViewCellAccessoryCheckmark];
+    [model addItem:item
+        toSectionWithIdentifier:SectionIdentifierMailtoHandlers];
+  }
+}
+
+#pragma mark UICollectionViewDelegate
+
+- (void)collectionView:(UICollectionView*)collectionView
+    didSelectItemAtIndexPath:(NSIndexPath*)indexPath {
+  [super collectionView:collectionView didSelectItemAtIndexPath:indexPath];
+  CollectionViewModel* model = self.collectionViewModel;
+
+  // Only handle taps on Mailto Handler items.
+  CollectionViewTextItem* selectedItem =
+      base::mac::ObjCCastStrict<CollectionViewTextItem>(

[rohitrao (ping after 24h), 2017/05/12 01:57:57]

ObjCCastStrict will DCHECK if the item is of a different class.  We're strict
about checking here, but not strict with the early return at line 90.  Feels
like we should consistently be either strict or not.

(Also, if the code stays unchanged, is it safe to assume that everything will be
a TextItem?  I think the answer is yes.)

[pkl (ping after 24h if needed), 2017/05/12 18:01:20]

Using "strict" is right.

+          [model itemAtIndexPath:indexPath]);
+  if (selectedItem.type != ItemTypeMailtoHandlers)

[rohitrao (ping after 24h), 2017/05/12 01:57:57]

Do we display any rows that are not this type?  Could this be a DCHECK instead,
or is there some way to hit this early return in practice?

If this line actually does get hit, we should consider disabling selection for
those rows, instead of ignoring it after the fact.

[pkl (ping after 24h if needed), 2017/05/12 18:01:19]

Since the items are created in loadModel, the checking should be strict, so I
changed this early return into a DCHECK_EQ.

+    return;
+
+  // Do nothing if the tapped row was already chosen as the default.
+  if (selectedItem.accessoryType == MDCCollectionViewCellAccessoryCheckmark)
+    return;
+
+  // Iterate through the rows and remove the checkmark from any that has it.
+  NSMutableArray* modifiedItems = [NSMutableArray array];
+  for (CollectionViewTextItem* item in

[rohitrao (ping after 24h), 2017/05/12 01:57:57]

Are we somehow silently casting to CollectionViewTextItem here?  Should we use
ObjCCastStrict or ObjCCast?

[pkl (ping after 24h if needed), 2017/05/12 18:01:19]

Switched to use ObjCCastStrict<>.

+       [model itemsInSectionWithIdentifier:SectionIdentifierMailtoHandlers]) {
+    if (item.type != ItemTypeMailtoHandlers)

[rohitrao (ping after 24h), 2017/05/12 01:57:57]

Same question -- could this be a DCHECK, or do we legitimately have items with a
different type?

[pkl (ping after 24h if needed), 2017/05/12 18:01:19]

...and made this a DCHECK_EQ

+      continue;
+    if (item == selectedItem) {
+      // Shows the checkmark on the new default mailto: URL handler.
+      item.accessoryType = MDCCollectionViewCellAccessoryCheckmark;
+      [modifiedItems addObject:item];
+    } else if (item.accessoryType == MDCCollectionViewCellAccessoryCheckmark) {
+      // Unchecks any currently checked selection.
+      item.accessoryType = MDCCollectionViewCellAccessoryNone;
+      [modifiedItems addObject:item];
+    }
+  }
+
+  NSUInteger handlerIndex = [model indexInItemTypeForIndexPath:indexPath];
+  MailtoHandler* handler =
+      [[_rewriter defaultHandlers] objectAtIndex:handlerIndex];
+  [_rewriter setDefaultHandlerID:[handler appStoreID]];
+
+  [self reconfigureCellsForItems:modifiedItems];
+}
+
+@end