DCHECK when loading images that do not exist.

ios/chrome/app/startup/setup_debugging.mm

 // Copyright 2016 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "ios/chrome/app/startup/setup_debugging.h"
 
+#include <objc/runtime.h>
+
 #include "base/logging.h"
+#include "base/strings/sys_string_conversions.h"
 #include "components/crash/core/common/objc_zombie.h"
 
 #if !defined(__has_feature) || !__has_feature(objc_arc)
 #error "This file requires ARC support."
 #endif
 
+namespace {
+
+#ifndef NDEBUG
+
+// Swizzles [UIImage imageNamed:] to trigger a DCHECK if an invalid image is

[lpromero, 2017/05/29 13:31:12]

There are other methods for loading images. For example:
https://cs.corp.google.com/piper///depot/google3/googlemac/iPhone/Shared/SSOA...

[jif, 2017/05/31 13:20:51]

Correct!
See https://bugs.chromium.org/p/chromium/issues/detail?id=721258

+// attempted to be loaded.
+void swizzleUIImageImageNamed() {
+  // Retained by the swizzle block.
+  NSMutableSet* whiteList = [NSMutableSet set];
+
+  // TODO(crbug.com/720337): Add missing image.
+  [whiteList addObject:@"card_close_button_pressed_incognito"];
+  // TODO(crbug.com/720355): Add missing image.
+  [whiteList addObject:@"find_close_pressed_incognito"];
+  // TODO(crbug.com/720338): Add missing images.
+  [whiteList addObject:@"glif-mic-to-dots-large_37"];
+  [whiteList addObject:@"glif-google-to-dots_28"];
+

[pkl (ping after 24h if needed), 2017/05/11 22:28:41]

When I run locally in debugger, I'm getting many DCHECKs for images such as
these:
ptr_new_tab 
omnibox_background
keyboard_button 
custom_row_voice
custom_row_voice_pressed
...

Are we supposed to keep adding to this whiteList?

+  // The original implementation of [UIImage imageNamed:].
+  // Called by the new implementation.
+  static IMP originalImp;
+  IMP* originalImpPtr = &originalImp;
+
+  id swizzleBlock = ^(id self, NSString* imageName) {
+    // Call the original [UIImage imageNamed:] method.
+    IMP imp = *originalImpPtr;
+    Class aClass = objc_getClass("UIImage");
+    UIImage* image = imp(aClass, @selector(imageNamed:), imageName);
+
+    if (![whiteList containsObject:imageName]) {
+      DCHECK(image) << "Missing image: " << base::SysNSStringToUTF8(imageName);
+    }
+    return image;
+  };
+
+  Method method = class_getClassMethod([UIImage class], @selector(imageNamed:));
+  DCHECK(method);
+
+  IMP blockImp = imp_implementationWithBlock(swizzleBlock);
+  originalImp = method_setImplementation(method, blockImp);
+}
+
+#endif
+
+}  // namespace
+
 @implementation SetupDebugging
 
 + (void)setUpDebuggingOptions {
 // Enable the zombie treadmill on simulator builds.
 // TODO(crbug.com/663390): Consider enabling this on device builds too.
 #if TARGET_IPHONE_SIMULATOR
   DCHECK(ObjcEvilDoers::ZombieEnable(true, 10000));
 #endif
+
+// Enable the detection of missing image assets.
+#ifndef NDEBUG
+  swizzleUIImageImageNamed();
+#endif
 }
 
 @end