Add updater state for Mac.

components/update_client/updater_state_mac.mm

+// Copyright 2017 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import <Foundation/Foundation.h>
+#import <OpenDirectory/OpenDirectory.h>

[Sorin Jianu, 2017/05/04 19:53:59]

Usually, an empty line is inserted between 6 and 7.

[borisv, 2017/05/04 22:19:27]

Done.

+#include "base/files/file_path.h"
+#include "base/files/file_util.h"
+#include "base/mac/foundation_util.h"
+#include "base/strings/sys_string_conversions.h"
+#include "base/version.h"
+#include "components/update_client/updater_state.h"
+
+namespace update_client {
+
+namespace {
+const base::FilePath::CharType kKeystonePlist[] = FILE_PATH_LITERAL(

[Sorin Jianu, 2017/05/04 19:53:59]

Namespace formatting: please include an empty line between 16 and 17.

[borisv, 2017/05/04 22:19:27]

Done.

+    "Google/GoogleSoftwareUpdate/GoogleSoftwareUpdate.bundle/"
+    "Contents/Info.plist");
+
+// Gets a value from the updater settings. Returns a retained object.
+// T should be a toll-free Foundation framework type. See Apple's
+// documentation for tooll-free bridging.

[Sorin Jianu, 2017/05/04 19:53:59]

toll

[borisv, 2017/05/04 22:19:27]

Done.

+template<class T>
+T* CopyUpdaterSettingsValue(NSString* value_name) {
+  CFStringRef app_id = CFSTR("com.google.Keystone.Agent");
+  CFPropertyListRef plist =
+      CFPreferencesCopyAppValue(base::mac::NSToCFCast(value_name), app_id);
+  if (!plist) return nil;
+  return base::mac::ObjCCastStrict<T>(static_cast<id>(plist));
+}
+
+base::Version GetVersionFromPlist(const base::FilePath& info_plist) {
+  @autoreleasepool {
+    NSData* data =
+        [NSData dataWithContentsOfFile:
+            base::mac::FilePathToNSString(info_plist)];
+    if ([data length] == 0) {
+      return base::Version();
+    }
+    NSDictionary* all_keys = base::mac::ObjCCastStrict<NSDictionary>(
+        [NSPropertyListSerialization propertyListWithData:data
+            options:NSPropertyListImmutable
+             format:nil
+              error:nil]);
+    if (all_keys == nil) {
+      return base::Version();
+    }
+    CFStringRef version =
+        base::mac::GetValueFromDictionary<CFStringRef>(
+            base::mac::NSToCFCast(all_keys),
+            kCFBundleVersionKey);
+    if (version == NULL) {
+      return base::Version();
+    }
+    return base::Version(base::SysCFStringRefToUTF8(version));
+  }
+}
+
+}  // namespace
+
+std::string UpdaterState::GetUpdaterName() {
+  return std::string("Keystone");
+}
+
+base::Version UpdaterState::GetUpdaterVersion(bool /*is_machine*/) {
+  // System Keystone trumps user one, so check this one first
+  base::FilePath local_library;
+  bool success = base::mac::GetLocalDirectory(NSLibraryDirectory,
+                                              &local_library);
+  DCHECK(success);
+  base::FilePath system_bundle_plist = local_library.Append(kKeystonePlist);
+  base::Version systemKeystone = GetVersionFromPlist(system_bundle_plist);
+  if (systemKeystone.IsValid()) {
+    return systemKeystone;
+  }
+
+  base::FilePath user_bundle_plist =
+      base::mac::GetUserLibraryPath().Append(kKeystonePlist);
+  return GetVersionFromPlist(user_bundle_plist);
+}
+
+base::Time UpdaterState::GetUpdaterLastStartedAU(bool /*is_machine*/) {
+  return GetUpdaterTimeValue("lastCheckStartDate");
+}
+
+base::Time UpdaterState::GetUpdaterLastChecked(bool /*is_machine*/) {
+  return GetUpdaterTimeValue("lastServerCheckDate");
+}
+
+bool UpdaterState::IsAutoupdateCheckEnabled() {
+  // Auto-update check period override (in seconds).
+  // Applies only to older versions of Keystone.
+  NSNumber* timeInterval = CopyUpdaterSettingsValue<NSNumber>(@"checkInterval");
+  if (timeInterval == nil) return true;
+  int value = [timeInterval intValue];
+  [timeInterval release];
+
+  return 0 < value && value < (24 * 60 * 60);
+}
+
+base::Time UpdaterState::GetUpdaterTimeValue(const char* value_name) {
+  NSString *value = [[NSString alloc] initWithUTF8String:value_name];
+  NSDate* date = CopyUpdaterSettingsValue<NSDate>(value);
+  base::Time result =
+      base::Time::FromCFAbsoluteTime([date timeIntervalSinceReferenceDate]);
+  [date release];
+
+  return result;
+}
+
+int UpdaterState::GetUpdatePolicy() {
+  return -1;  // Keystone does not support update policies.
+}
+
+bool UpdaterState::IsJoinedToDomain() {
+  @autoreleasepool {
+    ODSession* session = [ODSession defaultSession];
+    if (session == nil) {
+      DLOG(WARNING) << "ODSession defult session is nil.";
+      return false;
+    }
+
+    NSError* error = nil;
+    ODNode* node = [ODNode nodeWithSession:session
+                                      type:kODNodeTypeAuthentication
+                                     error:&error];
+    if (node == nil) {
+      DLOG(WARNING) << "ODSession cannot obtain the authentication node: "
+          << base::mac::NSToCFCast(error);
+      return false;
+    }
+
+    ODQuery* query = [ODQuery queryWithNode:node
+                             forRecordTypes:kODRecordTypeUsers
+                                  attribute:kODAttributeTypeRecordName
+                                  matchType:kODMatchEqualTo
+                                queryValues:NSUserName()
+                           returnAttributes:kODAttributeTypeAllAttributes
+                             maximumResults:0
+                                      error:&error];
+    if (query == nil) {
+      DLOG(WARNING) << "ODSession cannot create user query: "
+          << base::mac::NSToCFCast(error);
+      return false;
+    }
+
+    NSArray* results = [query resultsAllowingPartial:NO error:&error];
+    if (!results) {
+      DLOG(WARNING) << "ODSession cannot obtain current user node: "
+          << base::mac::NSToCFCast(error);
+      return false;
+    }
+    if (results.count != 1) {
+      DLOG(WARNING) << @"ODSession unexpected number of nodes: "
+          << results.count;
+    }
+    for (id element in results) {
+      ODRecord* record = base::mac::ObjCCastStrict<ODRecord>(element);
+      NSArray* attributes =
+          [record valuesForAttribute:kODAttributeTypeMetaRecordName
+                               error:NULL];
+      for (id attribute in attributes) {
+        NSString *attributeValue =
+            base::mac::ObjCCastStrict<NSString>(attribute);
+        // Example: "uid=johnsmith,ou=People,dc=chromium,dc=org
+        NSRange dc = [attributeValue rangeOfString:@"(^|,)\\s*dc="
+                                           options:NSRegularExpressionSearch];
+        if (dc.length > 0) {
+          return true;
+        }
+      }
+    }
+  }
+  return false;
+}
+
+}  // namespace update_client