Fix PasswordsSettingsTestCase.testCopyPasswordToast

ios/chrome/browser/ui/settings/passwords_settings_egtest.mm

 // Copyright 2017 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "base/callback.h"
 #include "base/mac/foundation_util.h"
 #include "base/memory/ref_counted.h"
 #include "base/strings/utf_string_conversions.h"
 #include "base/time/time.h"
 #include "components/autofill/core/common/password_form.h"
 #include "components/keyed_service/core/service_access_type.h"
 #include "components/password_manager/core/browser/password_store.h"
 #include "components/password_manager/core/common/password_manager_pref_names.h"
 #include "components/prefs/pref_service.h"
 #include "ios/chrome/browser/browser_state/chrome_browser_state.h"
 #include "ios/chrome/browser/passwords/ios_chrome_password_store_factory.h"
 #import "ios/chrome/browser/ui/settings/password_details_collection_view_controller_for_testing.h"
 #import "ios/chrome/browser/ui/settings/reauthentication_module.h"
 #import "ios/chrome/browser/ui/settings/settings_navigation_controller.h"
 #include "ios/chrome/browser/ui/tools_menu/tools_menu_constants.h"
 #import "ios/chrome/browser/ui/util/top_view_controller.h"
 #include "ios/chrome/grit/ios_strings.h"
 #import "ios/chrome/test/app/chrome_test_util.h"
 #include "ios/chrome/test/earl_grey/accessibility_util.h"
 #import "ios/chrome/test/earl_grey/chrome_earl_grey.h"
 #import "ios/chrome/test/earl_grey/chrome_earl_grey_ui.h"
 #import "ios/chrome/test/earl_grey/chrome_matchers.h"
 #import "ios/chrome/test/earl_grey/chrome_test_case.h"
+#import "ios/third_party/material_components_ios/src/components/Snackbar/src/MaterialSnackbar.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "url/gurl.h"
 
 #if !defined(__has_feature) || !__has_feature(objc_arc)
 #error "This file requires ARC support."
 #endif
 
 // This test complements
 // password_details_collection_view_controller_unittest.mm. Very simple
 // integration tests and features which are not currently unittestable should
 // go here, the rest into the unittest.
 // This test only uses the new UI which allows viewing passwords.
 // TODO(crbug.com/159166): Remove the above sentence once the new UI is the
 // default one.
 
 using autofill::PasswordForm;
 using chrome_test_util::ButtonWithAccessibilityLabel;
 using chrome_test_util::ButtonWithAccessibilityLabelId;
 using chrome_test_util::NavigationBarDoneButton;
 
 namespace {
 
+// How many points to scroll at a time when searching for an element. Setting it
+// too low means searching takes too long and the test might time out. Setting
+// it too high could result in scrolling way past the searched element.
+constexpr int kScrollAmount = 150;

[lpromero, 2017/05/04 15:55:41]

No action needed: I didn't know about constexpr.

[vabr (Chromium), 2017/05/04 16:38:20]

I'm also getting used to it. It is part of C++11, but clear and low-level enough
IMO to be useful also in Objective-C++.

+
 // Matcher for the Settings button in the tools menu.
 id<GREYMatcher> SettingsButton() {
   return grey_accessibilityID(kToolsMenuSettingsId);
 }
 
 // Matcher for the Save Passwords cell on the main Settings screen.
 id<GREYMatcher> PasswordsButton() {
   return ButtonWithAccessibilityLabelId(IDS_IOS_SAVE_PASSWORDS);
 }
 
@@ skipping 53 matching lines @@
       layoutConstraintWithAttribute:kGREYLayoutAttributeTop
                           relatedBy:kGREYLayoutRelationGreaterThanOrEqual
                toReferenceAttribute:kGREYLayoutAttributeBottom
                          multiplier:1.0
                            constant:0.0];
 }
 
 // Matcher for the Copy site button in Password Details view.
 id<GREYMatcher> CopySiteButton() {
   return grey_allOf(
+      grey_interactable(),
       ButtonWithAccessibilityLabel(
           [NSString stringWithFormat:@"%@: %@",
                                      l10n_util::GetNSString(
                                          IDS_IOS_SHOW_PASSWORD_VIEW_SITE),
                                      l10n_util::GetNSString(
                                          IDS_IOS_SETTINGS_SITE_COPY_BUTTON)]),
       grey_layout(@[ Below() ], SiteHeader()),
       grey_layout(@[ Above() ], UsernameHeader()),
       grey_layout(@[ Above() ], PasswordHeader()), nullptr);
 }
 
 // Matcher for the Copy username button in Password Details view.
 id<GREYMatcher> CopyUsernameButton() {
   return grey_allOf(
+      grey_interactable(),
       ButtonWithAccessibilityLabel([NSString
           stringWithFormat:@"%@: %@",
                            l10n_util::GetNSString(
                                IDS_IOS_SHOW_PASSWORD_VIEW_USERNAME),
                            l10n_util::GetNSString(
                                IDS_IOS_SETTINGS_USERNAME_COPY_BUTTON)]),
       grey_layout(@[ Below() ], SiteHeader()),
       grey_layout(@[ Below() ], UsernameHeader()),
       grey_layout(@[ Above() ], PasswordHeader()), nullptr);
 }
 
 // Matcher for the Copy password button in Password Details view.
 id<GREYMatcher> CopyPasswordButton() {
   return grey_allOf(
+      grey_interactable(),
       ButtonWithAccessibilityLabel([NSString
           stringWithFormat:@"%@: %@",
                            l10n_util::GetNSString(
                                IDS_IOS_SHOW_PASSWORD_VIEW_PASSWORD),
                            l10n_util::GetNSString(
                                IDS_IOS_SETTINGS_PASSWORD_COPY_BUTTON)]),
       grey_layout(@[ Below() ], SiteHeader()),
       grey_layout(@[ Below() ], UsernameHeader()),
       grey_layout(@[ Below() ], PasswordHeader()), nullptr);
 }
@@ skipping 21 matching lines @@
 }
 
 @end
 
 // Various tests for the Save Passwords section of the settings.
 @interface PasswordsSettingsTestCase : ChromeTestCase
 @end
 
 @implementation PasswordsSettingsTestCase
 
+- (void)tearDown {
+  // Snackbars triggered by tests stay up for a limited time even if the
+  // settings get closed. Ensure that they are closed to avoid interference with
+  // other tests.
+  [MDCSnackbarManager
+      dismissAndCallCompletionBlocksWithCategory:@"PasswordsSnackbarCategory"];
+  [super tearDown];
+}
+
 // Return pref for saving passwords back to the passed value and restores the
 // experimental flag for viewing passwords.
 - (void)passwordsTearDown:(BOOL)defaultPasswordManagementSetting
                          :(NSString*)oldExperiment {
   ios::ChromeBrowserState* browserState =
       chrome_test_util::GetOriginalBrowserState();
   PrefService* preferences = browserState->GetPrefs();
   preferences->SetBoolean(
       password_manager::prefs::kPasswordManagerSavingEnabled,
       defaultPasswordManagementSetting);
@@ skipping 129 matching lines @@
   chrome_test_util::VerifyAccessibilityForCurrentScreen();
   [self tapBackArrow];
 
   [self tapBackArrow];
   [self tapDone];
   [self clearPasswordStore];
 }
 
 // Checks that attempts to copy a password provide appropriate feedback,
 // both when reauthentication succeeds and when it fails.
-// TODO(crbug.com/718043): Re-enable test.
-- (void)DISABLED_testCopyPasswordToast {
+- (void)testCopyPasswordToast {
   [self scopedEnablePasswordManagementAndViewingUI];
 
   // Saving a form is needed for using the "password details" view.
   [self saveExamplePasswordForm];
 
   [self openPasswordSettings];
 
   [[EarlGrey selectElementWithMatcher:Entry(@"https://example.com, user")]
       performAction:grey_tap()];
 
   // Get the PasswordDetailsCollectionViewController and replace the
   // reauthentication module with a fake one to avoid being blocked with a
   // reauth prompt.
   MockReauthenticationModule* mock_reauthentication_module =
       [[MockReauthenticationModule alloc] init];
   SettingsNavigationController* settings_navigation_controller =
       base::mac::ObjCCastStrict<SettingsNavigationController>(
           top_view_controller::TopPresentedViewController());
   PasswordDetailsCollectionViewController*
       password_details_collection_view_controller =
           base::mac::ObjCCastStrict<PasswordDetailsCollectionViewController>(
               settings_navigation_controller.topViewController);
   [password_details_collection_view_controller
       setReauthenticationModule:mock_reauthentication_module];
 
   // Check the snackbar in case of successful reauthentication.
   mock_reauthentication_module.shouldSucceed = YES;
-  [[EarlGrey selectElementWithMatcher:CopyPasswordButton()]
+  [[[EarlGrey selectElementWithMatcher:CopyPasswordButton()]
+         usingSearchAction:grey_scrollInDirection(kGREYDirectionDown,
+                                                  kScrollAmount)
+      onElementWithMatcher:grey_accessibilityID(
+                               @"PasswordDetailsCollectionViewController")]
       performAction:grey_tap()];
   [[GREYUIThreadExecutor sharedInstance] drainUntilIdle];
   NSString* snackbarLabel =
       l10n_util::GetNSString(IDS_IOS_SETTINGS_PASSWORD_WAS_COPIED_MESSAGE);
+  // The tap checks the existence of the snackbar and also closes it.
   [[EarlGrey selectElementWithMatcher:grey_accessibilityLabel(snackbarLabel)]
-      assertWithMatcher:grey_notNil()];
+      performAction:grey_tap()];
+  // Wait until the fade-out animation completes.
+  [[GREYUIThreadExecutor sharedInstance] drainUntilIdle];
 
   // Check the snackbar in case of failed reauthentication.
   mock_reauthentication_module.shouldSucceed = NO;
-  [[EarlGrey selectElementWithMatcher:CopyPasswordButton()]
+  [[[EarlGrey selectElementWithMatcher:CopyPasswordButton()]
+         usingSearchAction:grey_scrollInDirection(kGREYDirectionDown,
+                                                  kScrollAmount)
+      onElementWithMatcher:grey_accessibilityID(
+                               @"PasswordDetailsCollectionViewController")]
       performAction:grey_tap()];
   [[GREYUIThreadExecutor sharedInstance] drainUntilIdle];
   snackbarLabel =
       l10n_util::GetNSString(IDS_IOS_SETTINGS_PASSWORD_WAS_NOT_COPIED_MESSAGE);
+  // The tap checks the existence of the snackbar and also closes it.
   [[EarlGrey selectElementWithMatcher:grey_accessibilityLabel(snackbarLabel)]
-      assertWithMatcher:grey_notNil()];
+      performAction:grey_tap()];
+  // Wait until the fade-out animation completes.
+  [[GREYUIThreadExecutor sharedInstance] drainUntilIdle];
 
   [self tapBackArrow];
   [self tapBackArrow];
   [self tapDone];
   [self clearPasswordStore];
 }
 
 // Checks that attempts to copy a username provide appropriate feedback.
 - (void)testCopyUsernameToast {
   [self scopedEnablePasswordManagementAndViewingUI];
 
   // Saving a form is needed for using the "password details" view.
   [self saveExamplePasswordForm];
 
   [self openPasswordSettings];
 
   [[EarlGrey selectElementWithMatcher:Entry(@"https://example.com, user")]
       performAction:grey_tap()];
 
   // Check the snackbar.
-  [[EarlGrey selectElementWithMatcher:CopyUsernameButton()]
+  [[[EarlGrey selectElementWithMatcher:CopyUsernameButton()]
+         usingSearchAction:grey_scrollInDirection(kGREYDirectionDown,
+                                                  kScrollAmount)
+      onElementWithMatcher:grey_accessibilityID(
+                               @"PasswordDetailsCollectionViewController")]
       performAction:grey_tap()];
   [[GREYUIThreadExecutor sharedInstance] drainUntilIdle];
   NSString* snackbarLabel =
       l10n_util::GetNSString(IDS_IOS_SETTINGS_USERNAME_WAS_COPIED_MESSAGE);
+  // The tap checks the existence of the snackbar and also closes it.
   [[EarlGrey selectElementWithMatcher:grey_accessibilityLabel(snackbarLabel)]
-      assertWithMatcher:grey_notNil()];
+      performAction:grey_tap()];
+  // Wait until the fade-out animation completes.
+  [[GREYUIThreadExecutor sharedInstance] drainUntilIdle];
 
   [self tapBackArrow];
   [self tapBackArrow];
   [self tapDone];
   [self clearPasswordStore];
 }
 
 // Checks that attempts to copy a site URL provide appropriate feedback.
 - (void)testCopySiteToast {
   [self scopedEnablePasswordManagementAndViewingUI];
 
   // Saving a form is needed for using the "password details" view.
   [self saveExamplePasswordForm];
 
   [self openPasswordSettings];
 
   [[EarlGrey selectElementWithMatcher:Entry(@"https://example.com, user")]
       performAction:grey_tap()];
 
   // Check the snackbar.
-  [[EarlGrey selectElementWithMatcher:CopySiteButton()]
+  [[[EarlGrey selectElementWithMatcher:CopySiteButton()]
+         usingSearchAction:grey_scrollInDirection(kGREYDirectionDown,
+                                                  kScrollAmount)
+      onElementWithMatcher:grey_accessibilityID(
+                               @"PasswordDetailsCollectionViewController")]
       performAction:grey_tap()];
   [[GREYUIThreadExecutor sharedInstance] drainUntilIdle];
   NSString* snackbarLabel =
       l10n_util::GetNSString(IDS_IOS_SETTINGS_SITE_WAS_COPIED_MESSAGE);
+  // The tap checks the existence of the snackbar and also closes it.
   [[EarlGrey selectElementWithMatcher:grey_accessibilityLabel(snackbarLabel)]
-      assertWithMatcher:grey_notNil()];
+      performAction:grey_tap()];
+  // Wait until the fade-out animation completes.
+  [[GREYUIThreadExecutor sharedInstance] drainUntilIdle];
 
   [self tapBackArrow];
   [self tapBackArrow];
   [self tapDone];
   [self clearPasswordStore];
 }
 
 @end