Fix missing headers in brotli

third_party/brotli/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//testing/libfuzzer/fuzzer_test.gni")
 
 if (is_win) {
   import("//build/config/win/visual_studio_version.gni")
 }
 
 config("includes") {
   include_dirs = [ "include" ]
 }
 
+source_set("headers") {
+  sources = [
+    "include/brotli/decode.h",
+    "include/brotli/encode.h",
+    "include/brotli/port.h",
+    "include/brotli/types.h",
+  ]
+}
+
 static_library("common") {
   sources = [
     "common/constants.h",
     "common/dictionary.c",
     "common/dictionary.h",
     "common/version.h",
   ]
   public_configs = [ ":includes" ]
+  deps = [
+    ":headers",
+  ]
 }
 
 static_library("dec") {
   sources = [
     "dec/bit_reader.c",
     "dec/bit_reader.h",
     "dec/context.h",
     "dec/decode.c",
     "dec/huffman.c",
     "dec/huffman.h",
     "dec/port.h",
     "dec/prefix.h",
     "dec/state.c",
     "dec/state.h",
     "dec/transform.h",
   ]
   public_configs = [ ":includes" ]
 
+  public_deps = [
+    ":headers",
+  ]
+
   deps = [
     ":common",
   ]
 
   configs -= [ "//build/config/compiler:chromium_code" ]
   configs += [ "//build/config/compiler:no_chromium_code" ]
 
   # Since we are never debug brotli, freeze the optimizations to -O2.
   configs -= [ "//build/config/compiler:default_optimization" ]
   configs += [ "//build/config/compiler:optimize_max" ]
@@ skipping 55 matching lines @@
       "enc/utf8_util.c",
       "enc/utf8_util.h",
       "enc/write_bits.h",
       "tools/bro.c",
     ]
     public_configs = [ ":includes" ]
 
     deps = [
       ":common",
       ":dec",
+      ":headers",
       "//build/config/sanitizers:deps",
       "//build/win:default_exe_manifest",
     ]
 
     if (is_win && visual_studio_version == "2015") {
       # Disabling "result of 32-bit shift implicitly converted to 64 bits",
       # caused by code like: foo |= (1 << i);   // warning 4334
       cflags = [ "/wd4334" ]
     }
 
     # Always build release since this is a build tool.
     if (is_debug) {
       configs -= [ "//build/config:debug" ]
       configs += [ "//build/config:release" ]
     }
   }
 }
 
 fuzzer_test("brotli_fuzzer") {
   sources = [
     "fuzz/decode_fuzzer.cc",
   ]
   deps = [
     ":dec",
   ]
   libfuzzer_options = [ "max_len=1280" ]
 }