Adds mailto: URL support to app launching.

ios/chrome/browser/web/mailto_url_rewriter.mm

+// Copyright 2017 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/chrome/browser/web/mailto_url_rewriter.h"
+
+#import "base/logging.h"
+#import "ios/chrome/browser/web/mailto_handler.h"
+#import "ios/chrome/browser/web/mailto_handler_gmail.h"
+#import "ios/chrome/browser/web/mailto_handler_system_mail.h"
+
+#import <UIKit/UIKit.h>
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+namespace {
+// The key for NSUserDefaults to store the Mail client selected to handle
+// mailto: URL scheme.
+NSString* const kMailtoDefaultHandlerKey = @"MailtoHandlerDefault";
+}  // namespace
+
+@interface MailtoURLRewriter ()
+
+// Dictionary keyed by the App Store ID of the Mail client and the value is
+// the MailtoHandler object that can rewrite a mailto: URL.
+@property(nonatomic, strong)
+    NSMutableDictionary<NSString*, MailtoHandler*>* handlers;
+
+// Private method to add |handlerApp| to the list of know Mail client apps.
+- (void)addMailtoApp:(MailtoHandler*)handlerApp;
+
+// Custom logic to handle the migration from Google Native App Launcher options
+// to this simplified mailto: URL only system. This must be called after
+// -addMailtoApp: has been called to add all the known Mail client apps.
+- (void)convertLegacyOptions;
+
+@end
+
+@implementation MailtoURLRewriter
+@synthesize handlers = _handlers;
+
++ (NSString*)systemMailApp {
+  // This is the App Store ID for Apple Mail app.
+  // See https://itunes.apple.com/us/app/mail/id1108187098?mt=8
+  return @"1108187098";
+}
+
+- (instancetype)init {
+  self = [super init];
+  if (self) {
+    _handlers = [NSMutableDictionary dictionary];
+  }
+  return self;
+}
+
+- (instancetype)initWithStandardHandlers {
+  self = [self init];
+  if (self) {
+    [self addMailtoApp:[[MailtoHandlerSystemMail alloc] init]];
+    [self addMailtoApp:[[MailtoHandlerGmail alloc] init]];
+    [self convertLegacyOptions];
+  }
+  return self;
+}
+
+- (NSArray<MailtoHandler*>*)defaultHandlers {
+  return [_handlers allValues];
+}
+
+- (NSString*)defaultHandlerID {
+  NSString* value = [[NSUserDefaults standardUserDefaults]
+      stringForKey:kMailtoDefaultHandlerKey];
+  return value ? value : [[self class] systemMailApp];
+}
+
+- (void)setDefaultHandlerID:(NSString*)appStoreID {
+  DCHECK([appStoreID length]);
+  [[NSUserDefaults standardUserDefaults] setObject:appStoreID
+                                            forKey:kMailtoDefaultHandlerKey];
+}
+
+- (NSString*)rewriteMailtoURL:(const GURL&)gURL {
+  NSString* value = [self defaultHandlerID];
+  if ([value length]) {
+    MailtoHandler* handler = _handlers[value];
+    if (handler) {
+      return [handler rewriteMailtoURL:gURL];
+    }
+  }
+  return nil;
+}
+
+#pragma mark - Private
+
+- (void)addMailtoApp:(MailtoHandler*)handlerApp {
+  if ([handlerApp isAvailable])
+    [_handlers setObject:handlerApp forKey:[handlerApp appStoreID]];
+}
+
+- (void)convertLegacyOptions {

[jif, 2017/05/04 14:08:47]

Add a TODO saying that we need to remove this method (associated with a... M62
bug?).

[pkl (ping after 24h if needed), 2017/05/04 22:25:59]

Done, but in the forward declaration earlier.

+  NSString* const kGmailAppStoreID = @"422689480";
+  MailtoHandler* gmailHandler = _handlers[kGmailAppStoreID];
+  if (!gmailHandler)
+    return;
+  NSUserDefaults* defaults = [NSUserDefaults standardUserDefaults];
+
+  // If Gmail app is not installed or otherwise unavailable, do not make it the
+  // default mailto: handler app.
+  if (![gmailHandler isAvailable])
+    [defaults removeObjectForKey:kMailtoDefaultHandlerKey];
+
+  NSString* const kLegacyShouldAutoOpenKey = @"ShouldAutoOpenLinks_422689480";

[jif, 2017/05/04 14:08:47]

Add comment just in case somebody wonders where this constant comes from:
// Key was generated by |shouldAutoOpenLinksKey| in
google_native_app_metadata.mm.

Doesn't matter if |google_native_app_metadata.mm| is deleted, it would still be
useful for code archaeologists.

[pkl (ping after 24h if needed), 2017/05/04 22:25:59]

Done.

+  NSNumber* legacyValue = [defaults objectForKey:kLegacyShouldAutoOpenKey];
+  // User previously did not have a selection made for opening mailto: links
+  // with Gmail, upgrade will set Gmail app to be the default mailto: handler.
+  if (!legacyValue) {
+    [defaults setObject:kGmailAppStoreID forKey:kMailtoDefaultHandlerKey];
+  } else {
+    switch ([legacyValue intValue]) {
+      case 0:

[jif, 2017/05/04 14:08:47]

add comment:
// kAutoOpenLinksNotSet

[pkl (ping after 24h if needed), 2017/05/04 22:25:59]

Done.

+      case 2:

[jif, 2017/05/04 14:08:47]

// kAutoOpenLinksYes

[pkl (ping after 24h if needed), 2017/05/04 22:25:59]

Done.

+        [defaults setObject:kGmailAppStoreID forKey:kMailtoDefaultHandlerKey];
+        break;
+      case 1:

[jif, 2017/05/04 14:08:47]

// kAutoOpenLinksNo

[pkl (ping after 24h if needed), 2017/05/04 22:25:59]

Done.

+        [defaults removeObjectForKey:kMailtoDefaultHandlerKey];
+        break;
+      default:
+        NOTREACHED();
+        break;
+    }
+    [defaults removeObjectForKey:kLegacyShouldAutoOpenKey];
+  }
+}
+
+@end