[infra] Assembles the SDK using GN rather than create_sdk.py

sdk/BUILD.gn

 # Copyright (c) 2017, the Dart project authors.  Please see the AUTHORS file
 # for details. All rights reserved. Use of this source code is governed by a
 # BSD-style license that can be found in the LICENSE file.
 
-# The SDK for Fuchsia does not include:
-#  dart2js
-#  dartdoc
-#  ddc
-# and libraries that are browser-specific, since these are not used and require
-# significant time to build.
-# TODO(zra): Assemble the SDK completely with GN, and remove create_sdk.py.
-if (defined(is_fuchsia) && (is_fuchsia || is_fuchsia_host)) {
-  template("copy_tree") {
-    assert(defined(invoker.source), "copy_tree must define 'source'")
-    assert(defined(invoker.dest), "copy_tree must define 'dest'")
-    source = invoker.source
-    dest = invoker.dest
-    action(target_name) {
-      deps = []
-      if (defined(invoker.deps)) {
-        deps += invoker.deps
-      }
+declare_args() {
+  # Build a SDK with less stuff. It excludes dart2js, ddc, web libraries, and
+  # analyzer sources.
+  dart_platform_sdk = false
+}
 
-      common_args = [
-        "--from",
-        rebase_path(source),
-        "--to",
-        rebase_path(dest),
+if (is_fuchsia || is_fuchsia_host) {
+  dart_platform_sdk = true
+}
+
+template("copy_tree") {
+  assert(defined(invoker.source), "copy_tree must define 'source'")
+  assert(defined(invoker.dest), "copy_tree must define 'dest'")
+  source = invoker.source
+  dest = invoker.dest
+  action(target_name) {
+    deps = []
+    if (defined(invoker.deps)) {
+      deps += invoker.deps
+    }
+
+    common_args = [
+      "--from",
+      rebase_path(source),
+      "--to",
+      rebase_path(dest),
+    ]
+    if (defined(invoker.exclude)) {
+      common_args += [
+        "--exclude",
+        invoker.exclude,
       ]
-      if (defined(invoker.exclude)) {
-        common_args += [
-          "--exclude",
-          invoker.exclude,
-        ]
-      }
+    }
 
-      dry_run_args = common_args + [ "--dry-run" ]
-      input_files =
-          exec_script("../tools/copy_tree.py", dry_run_args, "list lines")
-      inputs = input_files
-      relative_files = rebase_path(input_files, rebase_path(source))
+    dry_run_args = common_args + [ "--dry-run" ]
+    input_files =
+        exec_script("../tools/copy_tree.py", dry_run_args, "list lines")
+    inputs = input_files
+    relative_files = rebase_path(input_files, rebase_path(source))
 
-      output_files = []
-      foreach(input, relative_files) {
-        output_files += [ "$dest/$input" ]
-      }
+    output_files = []
+    foreach(input, relative_files) {
+      output_files += [ "$dest/$input" ]
+    }
 
-      outputs = output_files
-      script = "../tools/copy_tree.py"
-      args = common_args
-    }
+    outputs = output_files
+    script = "../tools/copy_tree.py"
+    args = common_args
   }
+}
 
-  copy("copy_dart") {
-    deps = [
-      "../runtime/bin:dart",
+copy("copy_dart") {
+  deps = [
+    "../runtime/bin:dart",
+  ]
+  dart_out = get_label_info("../runtime/bin:dart", "root_out_dir")
+  if (is_win) {
+    sources = [
+      "$dart_out/dart.exe",
     ]
-    dart_out = get_label_info("../runtime/bin:dart", "root_out_dir")
-    dart_name = get_label_info("../runtime/bin:dart", "name")
+  } else if (is_fuchsia || is_fuchsia_host) {
     sources = [
-      "$dart_out/$dart_name",
+      "$dart_out/dart",
     ]
-    outputs = [
-      "$root_out_dir/dart-sdk/bin/dart",
+  } else {
+    sources = [
+      "$dart_out/exe.stripped/dart",
     ]
   }
+  if (is_win) {
+    sources += [ "$dart_out/dart.lib" ]
+  }
+  outputs = [
+    "$root_out_dir/dart-sdk/bin/{{source_file_part}}",
+  ]
+}
 
+if (is_fuchsia_host && is_linux) {
   copy("copy_dylibs") {
     deps = [
       "//third_party/boringssl:crypto",
       "//third_party/boringssl:ssl",
     ]
     crypto_out =
         get_label_info("//third_party/boringssl:crypto", "root_out_dir")
     crypto_name = get_label_info("//third_party/boringssl:crypto", "name")
     ssl_out = get_label_info("//third_party/boringssl:ssl", "root_out_dir")
     ssl_name = get_label_info("//third_party/boringssl:ssl", "name")
     sources = [
       "$crypto_out/lib${crypto_name}.so",
       "$ssl_out/lib${ssl_name}.so",
     ]
     outputs = [
       "$root_out_dir/dart-sdk/bin/{{source_file_part}}",
     ]
   }
-
-  template("copy_sdk_script") {
-    assert(defined(invoker.name), "copy_sdk_script must define 'name'")
-    name = invoker.name
-    copy(target_name) {
-      sources = [
-        "bin/${name}_sdk",
-      ]
-      outputs = [
-        "$root_out_dir/dart-sdk/bin/${name}",
-      ]
+}
+
+template("copy_sdk_script") {
+  assert(defined(invoker.name), "copy_sdk_script must define 'name'")
+  name = invoker.name
+  ext = ""
+  if (is_win) {
+    ext = ".bat"
+  }
+  copy(target_name) {
+    sources = [
+      "bin/${name}_sdk$ext",
+    ]
+    outputs = [
+      "$root_out_dir/dart-sdk/bin/$name$ext",
+    ]
+  }
+}
+
+_sdk_scripts = [
+  "dartanalyzer",
+  "dartfmt",
+  "pub",
+]
+
+if (!dart_platform_sdk) {
+  _sdk_scripts += [
+    "dart2js",
+    "dartdevc",
+  ]
+}
+
+foreach(sdk_script, _sdk_scripts) {
+  copy_sdk_script("copy_${sdk_script}_script") {
+    name = sdk_script
+  }
+}
+
+_scripts = [ "dartdoc" ]
+
+foreach(script, _scripts) {
+  copy("copy_${script}_script") {
+    ext = ""
+    if (is_win) {
+      ext = ".bat"
     }
-  }
-
-  _sdk_scripts = [
+    sources = [
+      "bin/$script$ext",
+    ]
+    outputs = [
+      "$root_out_dir/dart-sdk/bin/{{source_file_part}}",
+    ]
+  }
+}
+
+group("copy_scripts") {
+  deps = []
+  foreach(sdk_script, _sdk_scripts) {
+    deps += [ ":copy_${sdk_script}_script" ]
+  }
+  foreach(script, _scripts) {
+    deps += [ ":copy_${script}_script" ]
+  }
+}
+
+_snapshots = [
+  [
+    "analysis_server",
+    "../utils/analysis_server",
+  ],
+  [
     "dartanalyzer",
+    "../utils/dartanalyzer:generate_dartanalyzer_snapshot",
+  ],
+  [
+    "dartdoc",
+    "../utils/dartdoc",
+  ],
+  [
     "dartfmt",
+    "../utils/dartfmt",
+  ],
+  [
     "pub",
-  ]
-
-  foreach(sdk_script, _sdk_scripts) {
-    copy_sdk_script("copy_${sdk_script}_script") {
-      name = sdk_script
-    }
-  }
-
-  group("copy_scripts") {
-    deps = [
-      ":copy_dartanalyzer_script",
-      ":copy_dartfmt_script",
-      ":copy_pub_script",
-    ]
-  }
-
-  _snapshots = [
+    "../utils/pub",
+  ],
+]
+
+if (!dart_platform_sdk) {
+  _snapshots += [
     [
-      "analysis_server",
-      "../utils/analysis_server",
+      "dart2js",
+      "../utils/compiler:dart2js",
     ],
     [
-      "dartanalyzer",
-      "../utils/dartanalyzer:generate_dartanalyzer_snapshot",
+      "utils_wrapper",
+      "../utils/compiler:utils_wrapper",
     ],
     [
-      "dartfmt",
-      "../utils/dartfmt",
+      "dartdevc",
+      "../utils/dartdevc",
     ],
-    [
-      "pub",
-      "../utils/pub",
-    ],
-  ]
-
+  ]
+}
+
+foreach(snapshot, _snapshots) {
+  copy("copy_${snapshot[0]}_snapshot") {
+    deps = [
+      snapshot[1],
+    ]
+    sources = [
+      "$root_gen_dir/${snapshot[0]}.dart.snapshot",
+    ]
+    outputs = [
+      "$root_out_dir/dart-sdk/bin/snapshots/{{source_file_part}}",
+    ]
+  }
+}
+
+group("copy_snapshots") {
+  deps = []
   foreach(snapshot, _snapshots) {
-    copy("copy_${snapshot[0]}_snapshot") {
-      deps = [
-        snapshot[1],
-      ]
-      sources = [
-        "$root_gen_dir/${snapshot[0]}.dart.snapshot",
-      ]
-      outputs = [
-        "$root_out_dir/dart-sdk/bin/snapshots/{{source_file_part}}",
-      ]
-    }
-  }
-
-  group("copy_snapshots") {
-    deps = [
-      ":copy_analysis_server_snapshot",
-      ":copy_dartanalyzer_snapshot",
-      ":copy_dartfmt_snapshot",
-      ":copy_pub_snapshot",
-    ]
-  }
-
-  copy("copy_analysis_summaries") {
+    deps += [ ":copy_${snapshot[0]}_snapshot" ]
+  }
+}
+
+# Copy analyzer sources
+_analyzer_source_dirs = []
+if (!dart_platform_sdk) {
+  _analyzer_source_dirs += [
+    "analyzer",
+    "analysis_server",
+    "front_end",
+    "kernel",
+  ]
+}
+
+foreach(analyzer_source_dir, _analyzer_source_dirs) {
+  copy_tree("copy_${analyzer_source_dir}_source_dir") {
+    source = "../pkg/$analyzer_source_dir"
+    dest = "$root_out_dir/dart-sdk/lib/$analyzer_source_dir"
+    exclude = "*.svn,doc,*.py,*.gypi,*.sh,.gitignore,packages"
+  }
+}
+
+group("copy_analyzer_sources") {
+  deps = []
+  foreach(analyzer_source_dir, _analyzer_source_dirs) {
+    deps += [ ":copy_${analyzer_source_dir}_source_dir" ]
+  }
+}
+
+copy_tree("copy_dartdoc_templates") {
+  source = "../third_party/pkg/dartdoc/lib/templates"
+  dest = "$root_out_dir/dart-sdk/bin/snapshots/resources/dartdoc/templates"
+}
+
+copy_tree("copy_dartdoc_resources") {
+  source = "../third_party/pkg/dartdoc/lib/resources"
+  dest = "$root_out_dir/dart-sdk/bin/snapshots/resources/dartdoc/resources"
+}
+
+write_file("$root_out_dir/dart-sdk/bin/snapshots/resources/dartdoc/.packages",
+           "dartdoc:.")
+
+group("copy_dartdoc_files") {
+  deps = [
+    ":copy_dartdoc_resources",
+    ":copy_dartdoc_templates",
+  ]
+}
+
+copy("copy_analysis_summaries") {
+  deps = [
+    ":copy_libraries",
+    "../utils/dartanalyzer:generate_summary_spec",
+    "../utils/dartanalyzer:generate_summary_strong",
+  ]
+  sources = [
+    "$root_gen_dir/spec.sum",
+    "$root_gen_dir/strong.sum",
+  ]
+  outputs = [
+    "$root_out_dir/dart-sdk/lib/_internal/{{source_file_part}}",
+  ]
+}
+
+if (!dart_platform_sdk) {
+  copy("copy_dev_compiler_summary") {
     deps = [
       ":copy_libraries",
-      "../utils/dartanalyzer:generate_summary_spec",
-      "../utils/dartanalyzer:generate_summary_strong",
     ]
     sources = [
-      "$root_gen_dir/spec.sum",
-      "$root_gen_dir/strong.sum",
+      "../pkg/dev_compiler/lib/sdk/ddc_sdk.sum",
     ]
     outputs = [
       "$root_out_dir/dart-sdk/lib/_internal/{{source_file_part}}",
     ]
   }
 
-  copy("copy_headers") {
+  copy_tree("copy_dev_compiler_js") {
+    source = "../pkg/dev_compiler/lib/js"
+    dest = "$root_out_dir/dart-sdk/lib/dev_compiler"
+  }
+
+  copy("copy_dev_compiler_require_js") {
+    deps = [
+      ":copy_dev_compiler_js",
+    ]
     sources = [
-      "../runtime/include/dart_api.h",
-      "../runtime/include/dart_mirrors_api.h",
-      "../runtime/include/dart_native_api.h",
-      "../runtime/include/dart_tools_api.h",
+      "../third_party/requirejs/require.js",
     ]
     outputs = [
-      "$root_out_dir/dart-sdk/include/{{source_file_part}}",
-    ]
-  }
-
-  copy("copy_platform_files") {
-    sources = [
-      "lib/dart_client.platform",
-      "lib/dart_server.platform",
-      "lib/dart_shared.platform",
-    ]
-    outputs = [
-      "$root_out_dir/dart-sdk/lib/{{source_file_part}}",
-    ]
-  }
-
-  copy_tree("copy_pub_assets") {
+      "$root_out_dir/dart-sdk/lib/dev_compiler/amd/{{source_file_part}}",
+    ]
+  }
+
+  group("copy_dev_compiler_sdk") {
+    deps = [
+      ":copy_dev_compiler_js",
+      ":copy_dev_compiler_require_js",
+      ":copy_dev_compiler_summary",
+    ]
+  }
+}
+
+copy("copy_headers") {
+  sources = [
+    "../runtime/include/dart_api.h",
+    "../runtime/include/dart_mirrors_api.h",
+    "../runtime/include/dart_native_api.h",
+    "../runtime/include/dart_tools_api.h",
+  ]
+  outputs = [
+    "$root_out_dir/dart-sdk/include/{{source_file_part}}",
+  ]
+}
+
+copy("copy_platform_files") {
+  sources = [
+    "lib/dart_client.platform",
+    "lib/dart_server.platform",
+    "lib/dart_shared.platform",
+  ]
+  outputs = [
+    "$root_out_dir/dart-sdk/lib/{{source_file_part}}",
+  ]
+}
+
+copy_tree("copy_pub_assets") {
+  deps = [
+    ":copy_libraries",
+  ]
+  source = "../third_party/pkg/pub/lib/src/asset"
+  dest = "$root_out_dir/dart-sdk/lib/_internal/pub/asset"
+}
+
+_libraries = [
+  "_internal",
+  "async",
+  "collection",
+  "convert",
+  "core",
+  "developer",
+  "internal",
+  "io",
+  "isolate",
+  "math",
+  "mirrors",
+  "profiler",
+  "typed_data",
+]
+
+if (!dart_platform_sdk) {
+  _libraries += [
+    "_blink",
+    "_chrome",
+    "html",
+    "indexed_db",
+    "js",
+    "js_util",
+    "svg",
+    "web_audio",
+    "web_gl",
+    "web_sql",
+  ]
+}
+
+foreach(library, _libraries) {
+  copy_tree("copy_${library}_library") {
+    source = "lib/$library"
+    dest = "$root_out_dir/dart-sdk/lib/$library"
+    exclude = "*.svn,doc,*.py,*.gypi,*.sh,.gitignore"
+  }
+}
+
+group("copy_libraries") {
+  deps = []
+  foreach(library, _libraries) {
+    deps += [ ":copy_${library}_library" ]
+  }
+}
+
+if (is_win) {
+  copy_tree("copy_7zip") {
     deps = [
       ":copy_libraries",
-    ]
-    source = "../third_party/pkg/pub/lib/src/asset"
-    dest = "$root_out_dir/dart-sdk/lib/_internal/pub/asset"
-  }
-
-  _libraries = [
-    "_internal",
-    "async",
-    "collection",
-    "convert",
-    "core",
-    "developer",
-    "internal",
-    "io",
-    "isolate",
-    "math",
-    "mirrors",
-    "profiler",
-    "typed_data",
-  ]
-
-  foreach(library, _libraries) {
-    copy_tree("copy_${library}_library") {
-      source = "lib/$library"
-      dest = "$root_out_dir/dart-sdk/lib/$library"
-      exclude = "*.svn,doc,*.py,*.gypi,*.sh,.gitignore"
-    }
-  }
-
-  group("copy_libraries") {
-    deps = [
-      ":copy__internal_library",
-      ":copy_async_library",
-      ":copy_collection_library",
-      ":copy_convert_library",
-      ":copy_core_library",
-      ":copy_developer_library",
-      ":copy_internal_library",
-      ":copy_io_library",
-      ":copy_isolate_library",
-      ":copy_math_library",
-      ":copy_mirrors_library",
-      ":copy_profiler_library",
-      ":copy_typed_data_library",
-    ]
-  }
-
-  action("write_version_file") {
-    output = "$root_out_dir/dart-sdk/version"
-    outputs = [
-      output,
-    ]
-    script = "../tools/write_version_file.py"
-    args = [
-      "--output",
-      rebase_path(output),
-    ]
-  }
-
-  action("write_revision_file") {
-    output = "$root_out_dir/dart-sdk/revision"
-    outputs = [
-      output,
-    ]
-    script = "../tools/write_revision_file.py"
-    args = [
-      "--output",
-      rebase_path(output),
-    ]
-  }
-
-  copy("copy_readme") {
-    sources = [
-      "../README.dart-sdk",
-    ]
-    outputs = [
-      "$root_out_dir/dart-sdk/README",
-    ]
-  }
-
-  copy("copy_license") {
-    sources = [
-      "../LICENSE",
-    ]
-    outputs = [
-      "$root_out_dir/dart-sdk/LICENSE",
-    ]
-  }
-
-  copy("copy_api_readme") {
-    sources = [
-      "api_readme.md",
-    ]
-    outputs = [
-      "$root_out_dir/dart-sdk/lib/api_readme.md",
-    ]
-  }
-
-  group("create_sdk") {
-    deps = [
-      ":copy_analysis_summaries",
-      ":copy_api_readme",
-      ":copy_dart",
-      ":copy_headers",
-      ":copy_libraries",
-      ":copy_license",
-      ":copy_platform_files",
       ":copy_pub_assets",
-      ":copy_readme",
-      ":copy_scripts",
-      ":copy_snapshots",
-      ":write_revision_file",
-      ":write_version_file",
-    ]
-    if (is_fuchsia_host && is_linux) {
-      deps += [ ":copy_dylibs" ]
-    }
-  }
-} else {
-  action("create_sdk") {
-    deps = [
-      "../runtime/bin:dart",
-      "../utils/analysis_server",
-      "../utils/compiler:dart2js",
-      "../utils/compiler:utils_wrapper",
-      "../utils/dartanalyzer:generate_dartanalyzer_snapshot",
-      "../utils/dartanalyzer:generate_summary_spec",
-      "../utils/dartanalyzer:generate_summary_strong",
-      "../utils/dartdevc",
-      "../utils/dartdoc",
-      "../utils/dartfmt",
-      "../utils/pub",
-    ]
-
-    sdk_lib_files = exec_script("../tools/list_dart_files.py",
-                                [
-                                  "absolute",
-                                  rebase_path("lib"),
-                                ],
-                                "list lines")
-
-    preamble_files =
-        exec_script("../tools/list_files.py",
-                    [
-                      "absolute",
-                      "",
-                      rebase_path("lib/_internal/js_runtime/lib/preambles"),
-                    ],
-                    "list lines")
-
-    sdk_bin_files = exec_script("../tools/list_files.py",
-                                [
-                                  "absolute",
-                                  "",
-                                  rebase_path("bin"),
-                                ],
-                                "list lines")
-
-    inputs = sdk_lib_files + preamble_files + sdk_bin_files + [
-               "lib/dart_client.platform",
-               "lib/dart_server.platform",
-               "lib/dart_shared.platform",
-               "$root_gen_dir/dart2js.dart.snapshot",
-               "$root_gen_dir/utils_wrapper.dart.snapshot",
-               "$root_gen_dir/pub.dart.snapshot",
-               "$root_gen_dir/dartanalyzer.dart.snapshot",
-               "$root_gen_dir/dartdevc.dart.snapshot",
-               "$root_gen_dir/dartfmt.dart.snapshot",
-               "$root_gen_dir/analysis_server.dart.snapshot",
-               "$root_gen_dir/dartdoc.dart.snapshot",
-               "$root_gen_dir/spec.sum",
-               "$root_gen_dir/strong.sum",
-               "../tools/VERSION",
-             ]
-
-    outputs = [
-      "$root_out_dir/dart-sdk/README",
-    ]
-
-    script = "../tools/create_sdk.py"
-    args = [
-      "--sdk_output_dir",
-      rebase_path("$root_out_dir/dart-sdk"),
-      "--snapshot_location",
-      rebase_path("$root_gen_dir"),
-    ]
-  }
-}
+    ]
+    source = "../third_party/7zip"
+    dest = "$root_out_dir/dart-sdk/lib/_internal/pub/asset/7zip"
+  }
+}
+
+action("write_version_file") {
+  output = "$root_out_dir/dart-sdk/version"
+  outputs = [
+    output,
+  ]
+  script = "../tools/write_version_file.py"
+  args = [
+    "--output",
+    rebase_path(output),
+  ]
+}
+
+action("write_revision_file") {
+  output = "$root_out_dir/dart-sdk/revision"
+  outputs = [
+    output,
+  ]
+  script = "../tools/write_revision_file.py"
+  args = [
+    "--output",
+    rebase_path(output),
+  ]
+}
+
+# Copy libraries.dart to lib/_internal/libraries.dart for backwards
+# compatibility.
+#
+# TODO(sigmund): stop copying libraries.dart. Old versions (<=0.25.1-alpha.4)
+# of the analyzer package do not support the new location of this file. We
+# should be able to remove the old file once we release a newer version of
+# analyzer and popular frameworks have migrated to use it.
+copy("copy_libraries_dart") {
+  deps = [
+    ":copy_libraries",
+  ]
+  sources = [
+    "lib/_internal/sdk_library_metadata/lib/libraries.dart",
+  ]
+  outputs = [
+    "$root_out_dir/dart-sdk/lib/_internal/{{source_file_part}}",
+  ]
+}
+
+copy("copy_readme") {
+  sources = [
+    "../README.dart-sdk",
+  ]
+  outputs = [
+    "$root_out_dir/dart-sdk/README",
+  ]
+}
+
+copy("copy_license") {
+  sources = [
+    "../LICENSE",
+  ]
+  outputs = [
+    "$root_out_dir/dart-sdk/LICENSE",
+  ]
+}
+
+copy("copy_api_readme") {
+  sources = [
+    "api_readme.md",
+  ]
+  outputs = [
+    "$root_out_dir/dart-sdk/lib/api_readme.md",
+  ]
+}
+
+group("create_sdk") {
+  deps = [
+    ":copy_analysis_summaries",
+    ":copy_analyzer_sources",
+    ":copy_api_readme",
+    ":copy_dart",
+    ":copy_dartdoc_files",
+    ":copy_headers",
+    ":copy_libraries",
+    ":copy_libraries_dart",
+    ":copy_license",
+    ":copy_platform_files",
+    ":copy_pub_assets",
+    ":copy_readme",
+    ":copy_scripts",
+    ":copy_snapshots",
+    ":write_revision_file",
+    ":write_version_file",
+  ]
+  if (!dart_platform_sdk) {
+    deps += [ ":copy_dev_compiler_sdk" ]
+  }
+  if (is_win) {
+    deps += [ ":copy_7zip" ]
+  }
+  if (is_fuchsia_host && is_linux) {
+    deps += [ ":copy_dylibs" ]
+  }
+}