[Bindings] Create and use V8 context snapshots

gin/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//testing/test.gni")
 import("//v8/gni/v8.gni")
 
 component("gin") {
   sources = [
     "arguments.cc",
@@ skipping 59 matching lines @@
   ]
 
   if (v8_use_external_startup_data) {
     data = [
       "$root_out_dir/natives_blob.bin",
       "$root_out_dir/snapshot_blob.bin",
     ]
   }
 
   defines = [ "GIN_IMPLEMENTATION" ]
-
   public_deps = [
     "//base",
     "//v8",
   ]
+
   deps = [
     "//base/third_party/dynamic_annotations",
   ]
 
   if (is_mac) {
     libs = [ "CoreFoundation.framework" ]
   }
 
   configs += [ "//v8:external_startup_data" ]
 }
 
 executable("gin_shell") {
   sources = [
     "shell/gin_main.cc",
   ]
 
   deps = [
     ":gin",
     "//base",
     "//base:i18n",
     "//build/config:exe_and_shlib_deps",
     "//build/win:default_exe_manifest",
     "//v8",
   ]
 
   configs += [ "//v8:external_startup_data" ]
 }
 
+group("blink_v8_snapshot") {
+  public_deps = [
+    ":generate_blink_v8_snapshot",
+  ]
+}
+
+action("generate_blink_v8_snapshot") {
+  script = "run.py"
+  output_file = "$root_out_dir/blink_v8_snapshot.bin"
+  output_path = rebase_path(output_file, root_build_dir)
+
+  args = [
+    "./" + rebase_path(
+            get_label_info(":blink_v8_snapshot_generator($host_toolchain)",
+                           "root_out_dir") + "/blink_v8_snapshot_generator",
+            root_build_dir),
+    "--output_file=$output_path",
+  ]
+
+  outputs = [
+    output_file,
+  ]
+
+  deps = [
+    ":blink_v8_snapshot_generator($host_toolchain)",
+  ]
+}
+
+# This config disables a link time optimization "ICF", which may merge different
+# functions into one if the function signatures and body of them are identical.

[Yuki, 2017/06/20 14:20:10]

s/signatures/signature/

[peria, 2017/06/21 07:19:15]

Done.

+config("disable_icf") {
+  visibility = [ ":*" ]  # Only targets in this file can depend on this.
+  if (is_win) {
+    ldflags = [ "/OPT:NOICF" ]
+  } else if (is_posix && !is_mac) {

[Yuki, 2017/06/20 14:20:10]

nit: It would be better to depend on toolchain rather than platform.
If we're using GNU ld or its compatibles, then "-Wl,--icf=none" should be valid.
 Whether it's POSIX platform or not doesn't matter much.  Same for is_win.

I don't know much about this area.  Please consult with a build expert.

[peria, 2017/06/23 02:22:05]

Trying...

[peria, 2017/06/27 09:52:36]

ldflags seems to be set depend on platforms, and it is difficult to
change it with other flags correctly.

+    ldflags = [ "-Wl,--icf=none" ]
+  }
+}
+
+executable("blink_v8_snapshot_generator") {
+  sources = [
+    "shell/blink_v8_snapshot_generator_main.cc",

[Yuki, 2017/06/20 14:20:10]

This program highly depends on Blink (and it actually directly calls a Blink
API), why is this program part of gin/shell/?  Should this be placed somewhere
else?

For example, we have //tools/blink_rename_merge_helper/ directory.

[peria, 2017/06/23 02:22:05]

I think //tools is a place for developer tools, which CAN be used in
developments, and not a part of build flow.
This program depends on V8 and Blink. It is required to build Chromium, but is
not a part of Chromium binary itself.
So I feel gin/ is a good place to have this program. (and jochen@ suggested to
use gin/.)

[peria, 2017/06/27 09:52:36]

moved to tools/blink_v8_snapshot

+  ]
+
+  deps = [
+    ":gin",
+    "//mojo/edk/system:system",
+    "//third_party/WebKit/public:blink",
+    "//v8",
+  ]
+
+  # Link time optimization "ICF" breaks 1:1 mappings of the external references
+  # for V8 snapshot. So, we disable it while taking a V8 snapshot.
+  configs += [
+    "//v8:external_startup_data",
+    ":disable_icf",
+  ]
+}
+
 source_set("gin_test") {
   testonly = true
   sources = [
     "test/file.cc",
     "test/file.h",
     "test/file_runner.cc",
     "test/file_runner.h",
     "test/gc.cc",
     "test/gc.h",
     "test/gtest.cc",
@@ skipping 49 matching lines @@
     "shell/hello_world.js",
     "test/file_unittests.js",
     "test/gtest_unittests.js",
     "../OWNERS",
   ]
 
   data_deps = [
     ":gin_shell",
   ]
 }