Enable ThinLTO and LLD for POSIX LTO by default on Linux.

build/toolchain/toolchain.gni

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # Toolchain-related configuration that may be needed outside the context of the
 # toolchain() rules themselves.
 
 import("//build_overrides/build.gni")
 import("//build/config/chrome_build.gni")
 
 declare_args() {
   # Enable Link Time Optimization in optimized builds (output programs run
   # faster, but linking is up to 5-20x slower).
   # Note: use target_os == "linux" rather than is_linux so that it does not
   # apply to host_toolchain when target_os="android".
   allow_posix_link_time_opt = target_os == "linux" && !is_chromeos &&
                               target_cpu == "x64" && is_official_build
 
-  # Set to true to use lld, the LLVM linker. This flag may be used on Windows
-  # with the shipped LLVM toolchain, or on Linux with a self-built top-of-tree
-  # LLVM toolchain (see llvm_force_head_revision in
-  # build/config/compiler/BUILD.gn).
-  use_lld = is_win && host_os != "win"
-
-  # If used with allow_posix_link_time_opt, it enables the experimental support
-  # of ThinLTO that links 3x-10x faster but (as of now) does not have all the
-  # important optimizations such us devirtualization implemented. See also
-  # http://blog.llvm.org/2016/06/thinlto-scalable-and-incremental-lto.html
-  use_thin_lto = false
-
   # If this is set to true, or if LLVM_FORCE_HEAD_REVISION is set to 1
   # in the environment, we use the revision in the llvm repo to determine
   # the CLANG_REVISION to use, instead of the version hard-coded into
   # //tools/clang/scripts/update.py. This should only be used in
   # conjunction with setting LLVM_FORCE_HEAD_REVISION in the
   # environment when `gclient runhooks` is run as well.
   llvm_force_head_revision = false
 
   # Compile with Xcode version of clang instead of hermetic version shipped
   # with the build. Used on iOS to ship official builds (as they are built
   # with the version of clang shipped with Xcode).
   use_xcode_clang = is_ios && is_official_build
 }
 
 # The path to the hermetic install of Xcode. Only relevant when
 # use_system_xcode = false.
 hermetic_xcode_path =
     rebase_path("//build/${target_os}_files/Xcode.app", "", root_build_dir)
 
 declare_args() {
   if (is_clang) {
     # Clang compiler version. Clang files are placed at version-dependent paths.
     clang_version = "5.0.0"
   }
+
+  # Set to true to use lld, the LLVM linker. This flag may be used on Windows
+  # or Linux.
+  use_lld = (is_win && host_os != "win") ||
+            (allow_posix_link_time_opt && target_os == "linux" &&
+             !is_chromeos && target_cpu == "x64")
+
+  # If used with allow_posix_link_time_opt, it enables the support of ThinLTO
+  # that links 3x-10x faster. See also
+  # http://blog.llvm.org/2016/06/thinlto-scalable-and-incremental-lto.html
+  use_thin_lto = allow_posix_link_time_opt && target_os == "linux" &&
+                 !is_chromeos && target_cpu == "x64"
 }
 
 # Check target_os here instead of is_ios as this file is loaded for secondary
 # toolchain (host toolchain in particular) but the argument is the same for
 # all toolchains.
 assert(!use_xcode_clang || target_os == "ios",
        "Using Xcode's clang is only supported in iOS builds")
 
 # Subdirectory within root_out_dir for shared library files.
 # TODO(agrieve): GYP sets this to "lib" for Linux & Android, but this won't work
@@ skipping 41 matching lines @@
   _tool_wrapper_path =
       rebase_path("//build/toolchain/win/tool_wrapper.py", root_build_dir)
 
   stamp_command = "$python_path $_tool_wrapper_path stamp {{output}}"
   copy_command =
       "$python_path $_tool_wrapper_path recursive-mirror {{source}} {{output}}"
 } else {
   stamp_command = "touch {{output}}"
   copy_command = "ln -f {{source}} {{output}} 2>/dev/null || (rm -rf {{output}} && cp -af {{source}} {{output}})"
 }