add customized printing setting for headless

headless/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chrome_build.gni")
 import("//headless/headless.gni")
 import("//build/util/process_version.gni")
 import("//mojo/public/tools/bindings/mojom.gni")
 import("//printing/features/features.gni")
 import("//testing/test.gni")
 import("//tools/grit/grit_rule.gni")
 import("//tools/grit/repack.gni")
 
 config("headless_implementation") {
   defines = [ "HEADLESS_IMPLEMENTATION" ]
 
   if (headless_use_embedded_resources) {
     defines += [ "HEADLESS_USE_EMBEDDED_RESOURCES" ]
   }
 }
 
 group("headless") {
   deps = [
     "//headless:headless_lib",
   ]
 }
 
+repack_locales("locale_pak") {
+  input_locales = [ "en-US" ]
+
+  if (!is_mac) {
+    output_locales = [ "en-US" ]
+  } else {
+    output_locales = [ "locale" ]
+  }
+
+  source_patterns = [
+    "$root_gen_dir/ui/strings/app_locale_settings_",
+    "$root_gen_dir/ui/strings/ui_strings_",
+  ]
+
+  deps = [
+    "//ui/strings",
+  ]
+
+  output_dir = "$root_out_dir/headless_locales"
+}
+
 repack("pak") {
   sources = [
     "$root_gen_dir/blink/public/resources/blink_image_resources_100_percent.pak",
     "$root_gen_dir/blink/public/resources/blink_resources.pak",
+    "$root_gen_dir/components/components_resources.pak",
     "$root_gen_dir/components/strings/components_strings_en-US.pak",
     "$root_gen_dir/content/app/resources/content_resources_100_percent.pak",
     "$root_gen_dir/content/app/strings/content_strings_en-US.pak",
     "$root_gen_dir/content/browser/devtools/devtools_resources.pak",
     "$root_gen_dir/content/browser/tracing/tracing_resources.pak",
     "$root_gen_dir/content/content_resources.pak",
     "$root_gen_dir/headless/headless_lib_resources.pak",
     "$root_gen_dir/net/net_resources.pak",
     "$root_gen_dir/ui/resources/ui_resources_100_percent.pak",
     "$root_gen_dir/ui/resources/webui_resources.pak",
     "$root_gen_dir/ui/strings/app_locale_settings_en-US.pak",
     "$root_gen_dir/ui/strings/ui_strings_en-US.pak",
   ]
 
   if (is_chrome_branded) {
     sources += [ "${root_gen_dir}/components/strings/components_google_chrome_strings_en-US.pak" ]
   } else {
     sources += [ "${root_gen_dir}/components/strings/components_chromium_strings_en-US.pak" ]
   }
 
   deps = [
     ":resources",
+    "//components/resources:components_resources",
     "//components/strings",
     "//content:resources",
     "//content/app/resources",
     "//content/app/strings",
     "//content/browser/devtools:resources",
     "//content/browser/tracing:resources",
     "//net:net_resources",
     "//third_party/WebKit/public:image_resources",
     "//third_party/WebKit/public:resources",
     "//ui/resources",
@@ skipping 131 matching lines @@
 
   args = [
     "--protocol",
     rebase_path(inputs[0], root_build_dir),
     "--output_dir",
     rebase_path(target_gen_dir) + "/public",
   ]
 }
 
 static_library("headless_lib") {
+  if (enable_basic_printing) {
+    defines = [ "PRINTING_IMPLEMENTATION" ]

[Lei Zhang, 2017/04/27 22:17:46]

This doesn't look right. This is not printing/.

[jzfeng, 2017/05/02 07:50:56]

Done. For some reason, I added this for unittest. But now it is not needed.

+  }
   sources = generated_devtools_api + [
               "app/headless_shell_switches.cc",
               "app/headless_shell_switches.h",
               "lib/browser/headless_browser_context_impl.cc",
               "lib/browser/headless_browser_context_impl.h",
               "lib/browser/headless_browser_context_options.cc",
               "lib/browser/headless_browser_context_options.h",
               "lib/browser/headless_browser_impl.cc",
               "lib/browser/headless_browser_impl.h",
               "lib/browser/headless_browser_impl_mac.mm",
@@ skipping 102 matching lines @@
     ]
   }
 
   public_deps = [
     "//base",
     "//net",
   ]
 
   deps = [
     ":gen_devtools_client_api",
+    ":locale_pak",
     ":tab_socket",
     ":version_header",
     "//components/crash/content/browser",
     "//components/security_state/content",
     "//components/security_state/core",
     "//content/public/app:both",
     "//content/public/browser",
     "//content/public/child:child",
     "//content/public/common",
     "//content/public/common:service_names",
@@ skipping 37 matching lines @@
 }
 
 group("headless_tests") {
   testonly = true
 
   deps = [
     ":headless_browsertests",
     ":headless_example",
     ":headless_unittests",
   ]
+
+  if (enable_basic_printing) {
+    deps += [ ":headless_printing_unittests" ]
+  }
 }
 
 test("headless_unittests") {
   sources = [
     "public/domains/types_unittest.cc",
     "public/util/deterministic_dispatcher_test.cc",
     "public/util/error_reporter_unittest.cc",
     "public/util/expedited_dispatcher_test.cc",
     "public/util/generic_url_request_job_test.cc",
     "public/util/testing/fake_managed_dispatch_url_request_job.cc",
     "public/util/testing/fake_managed_dispatch_url_request_job.h",
   ]
 
   deps = [
     ":headless_lib",
     "//base/test:run_all_unittests",
     "//base/test:test_support",
     "//testing/gmock",
     "//testing/gtest",
   ]
 }
 
+if (enable_basic_printing) {
+  test("headless_printing_unittests") {

[Lei Zhang, 2017/04/27 22:17:46]

I think you just want to add your test to headless_unittests. You shouldn't have
to create a new binary, and configure buildbots to run the new binary, etc.

[jzfeng, 2017/05/02 07:50:56]

Done.

+    sources = [
+      "lib/browser/headless_printing_unittest.cc",
+    ]
+
+    deps = [
+      ":headless_lib",
+      "//base/test:run_all_unittests",
+      "//content/public/common",
+      "//testing/gtest",
+    ]
+  }
+}
+
 mojom("embedder_mojo_for_testing") {
   sources = [
     "lib/embedder_test.mojom",
   ]
 }
 
 grit("headless_browsertest_resources_grit") {
   source = "lib/headless_browsertest_resources.grd"
   outputs = [
     "grit/headless_browsertest_resources.h",
@@ skipping 130 matching lines @@
 
 executable("headless_example") {
   sources = [
     "app/headless_example.cc",
   ]
 
   deps = [
     "//headless:headless_shell_lib",
   ]
 }