GN: Tighten up test target visibility + refactorings

webrtc/modules/remote_bitrate_estimator/BUILD.gn

 # Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("../../webrtc.gni")
 
@@ skipping 109 matching lines @@
       "../congestion_controller",
       "../pacing",
       "../rtp_rtcp",
       "//testing/gmock",
       "//testing/gtest",
     ]
   }
 
   rtc_source_set("remote_bitrate_estimator_perf_tests") {
     testonly = true
+
+    # Skip restricting visibility on mobile platforms since the tests on those
+    # gets additional generated targets which would require many lines here to
+    # cover (which would be confusing to read and hard to maintain).
+    if (!is_android && !is_ios) {
+      visibility = [ "//webrtc:webrtc_perf_tests" ]
+    }
     sources = [
       "remote_bitrate_estimators_test.cc",
     ]
     deps = [
       ":bwe_simulator_lib",
       ":remote_bitrate_estimator",
       "../../base:rtc_base_approved",
       "../../test:test_support",
     ]
     if (!build_with_chromium && is_clang) {
       # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
       suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
     }
   }
 
   rtc_source_set("remote_bitrate_estimator_unittests") {
     testonly = true
+
+    # Skip restricting visibility on mobile platforms since the tests on those
+    # gets additional generated targets which would require many lines here to
+    # cover (which would be confusing to read and hard to maintain).
+    if (!is_android && !is_ios) {
+      visibility = [ "//webrtc/modules:modules_unittests" ]
+    }
     sources = [
       "aimd_rate_control_unittest.cc",
-      "include/mock/mock_remote_bitrate_observer.h",
       "inter_arrival_unittest.cc",
       "overuse_detector_unittest.cc",
       "remote_bitrate_estimator_abs_send_time_unittest.cc",
       "remote_bitrate_estimator_single_stream_unittest.cc",
       "remote_bitrate_estimator_unittest_helper.cc",
       "remote_bitrate_estimator_unittest_helper.h",
       "remote_estimator_proxy_unittest.cc",
       "send_time_history_unittest.cc",
       "test/bwe_test_framework_unittest.cc",
       "test/bwe_unittest.cc",
       "test/estimators/nada_unittest.cc",
       "test/metric_recorder_unittest.cc",
     ]
     deps = [
       ":bwe_simulator_lib",
+      ":mock_remote_bitrate_observer",
       ":remote_bitrate_estimator",
       "../..:webrtc_common",
       "../../base:rtc_base",
       "../../base:rtc_base_approved",
       "../../system_wrappers:system_wrappers",
       "../../test:field_trial",
       "../../test:test_support",
       "../pacing:pacing",
       "../rtp_rtcp:rtp_rtcp",
       "//testing/gmock",
     ]
     if (is_win) {
       cflags = [
         # TODO(kjellander): bugs.webrtc.org/261: Fix this warning.
         "/wd4373",  # virtual function override.
       ]
     }
     if (!build_with_chromium && is_clang) {
       # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
       suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
     }
   }
 
+  rtc_source_set("mock_remote_bitrate_observer") {
+    testonly = true
+    sources = [
+      "include/mock/mock_remote_bitrate_observer.h",
+    ]
+    deps = [
+      ":remote_bitrate_estimator",
+      "../../test:test_support",
+    ]
+  }
+
   rtc_test("bwe_simulations_tests") {
     testonly = true
 
     sources = [
       "bwe_simulations.cc",
     ]
     deps = [
       ":bwe_simulator_lib",
       ":remote_bitrate_estimator",
       "../..:webrtc_common",
@@ skipping 10 matching lines @@
     }
 
     if (is_win) {
       cflags = [
         # TODO(kjellander): bugs.webrtc.org/261: Fix this warning.
         "/wd4373",  # virtual function override.
       ]
     }
   }
 }