[ObjC ARC] Converts ios/chrome/browser/ui/print:print to ARC.

ios/chrome/browser/ui/print/print_controller.mm

 // Copyright 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/print/print_controller.h"
 
 #import <MobileCoreServices/UTType.h>
 #import <Webkit/Webkit.h>
 
 #include <memory>
 
 #include "base/callback_helpers.h"
 #import "base/ios/ios_util.h"
-#import "base/ios/weak_nsobject.h"
 #include "base/location.h"
 #include "base/logging.h"
 #include "base/mac/bind_objc_block.h"
 #include "base/mac/foundation_util.h"
-#import "base/mac/scoped_nsobject.h"
 #include "base/memory/ref_counted.h"
 #include "base/metrics/user_metrics.h"
 #include "base/metrics/user_metrics_action.h"
 #include "components/strings/grit/components_strings.h"
 #import "ios/chrome/browser/ui/alert_coordinator/alert_coordinator.h"
 #import "ios/chrome/browser/ui/alert_coordinator/loading_alert_coordinator.h"
 #include "ios/chrome/grit/ios_strings.h"
 #include "ios/web/public/web_thread.h"
 #import "net/base/mac/url_conversions.h"
 #include "net/http/http_response_headers.h"
 #include "net/url_request/url_fetcher.h"
 #include "net/url_request/url_fetcher_delegate.h"
 #include "net/url_request/url_request_context_getter.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 using net::URLFetcher;
 using net::URLFetcherDelegate;
 using net::URLRequestContextGetter;
 
 @interface PrintController ()
 
 // Presents a UIPrintInteractionController with a default completion handler.
 // |isPDF| indicates if |printInteractionController| is being presented to print
 // a PDF.
 + (void)displayPrintInteractionController:
@@ skipping 46 matching lines @@
     DCHECK(view_controller_);
     [owner_ finishedDownloadingPDF:view_controller_];
   }
 
   // The ViewController used to display an error if the download failed.
   void SetViewController(UIViewController* view_controller) {
     view_controller_ = view_controller;
   }
 
  private:
   __unsafe_unretained PrintController* owner_;

[sdefresne, 2017/04/20 13:16:51]

Maybe change all __unsafe_unretained to __weak for more safety.

[stkhapugin, 2017/04/20 13:35:10]

+1, __unsafe_unretained was probably used here to not leave an unmarked ivar,
but __weak wasn't available. In general, __unsafe_unretained is only better for
performance-critical code, which means we probably don't need it at all in any
objective-c code in chrome ios, as most of the performance-critical code is in
C++ 

[gambard, 2017/04/20 13:38:26]

Done.

   __unsafe_unretained UIViewController* view_controller_;
   DISALLOW_COPY_AND_ASSIGN(PrintPDFFetcherDelegate);
 };
 }  // namespace
 
 @implementation PrintController {
   // URLFetcher to download the PDF pointed to by the WKWebView.
   std::unique_ptr<URLFetcher> _fetcher;
 
   // A delegate to bridge between PrintController and the URLFetcher callback.
   std::unique_ptr<PrintPDFFetcherDelegate> _fetcherDelegate;
 
   // Context getter required by the URLFetcher.
   scoped_refptr<URLRequestContextGetter> _requestContextGetter;
 
   // A dialog which indicates that the print preview is being prepared. It
   // offers a cancel button which will cancel the download. It is created when
   // downloading begins and is released when downloading ends (either due to
   // cancellation or completion).
-  base::scoped_nsobject<LoadingAlertCoordinator> _PDFDownloadingDialog;
+  LoadingAlertCoordinator* _PDFDownloadingDialog;
 
   // A dialog which indicates that the print preview failed.
-  base::scoped_nsobject<AlertCoordinator> _PDFDownloadingErrorDialog;
+  AlertCoordinator* _PDFDownloadingErrorDialog;
 }
 
 #pragma mark - Class methods.
 
 + (void)displayPrintInteractionController:
             (UIPrintInteractionController*)printInteractionController
                                    forPDF:(BOOL)isPDF {
   void (^completionHandler)(UIPrintInteractionController*, BOOL, NSError*) = ^(
       UIPrintInteractionController* printInteractionController, BOOL completed,
       NSError* error) {
     if (error)
       DLOG(ERROR) << "Air printing error: " << error.description;
 
     // When printing a NSData object given to the
     // UIPrintInteractionController's |printingItem| object, a PDF file
     // representing the NSData object is created in the app's tmp directory
     // by the OS and never deleted. So, this workaround deletes PDF files in
     // tmp now that printing is done. When iOS9 is deprecated, this can
     // be removed since PDFs will no longer need to be downloaded to print,
     // and |printingItem| will no longer be used.
     if (!base::ios::IsRunningOnIOS10OrLater() && isPDF) {
       web::WebThread::PostBlockingPoolTask(
-          FROM_HERE, base::BindBlock(^{
+          FROM_HERE, base::BindBlockArc(^{
             NSFileManager* manager = [NSFileManager defaultManager];
             NSString* tempDir = NSTemporaryDirectory();
             NSError* tempDirError = nil;
 
             // Iterate over files in tmp directory.
             for (NSString* file in
                  [manager contentsOfDirectoryAtPath:tempDir
                                               error:&tempDirError]) {
               // If the file is a PDF file, delete it.
               if ([[file pathExtension] isEqualToString:@"pdf"]) {
@@ skipping 70 matching lines @@
           [self downloadPDFFileWithURL:net::GURLWithNSURL(URL)
                         viewController:viewController];
         }
         CFRelease(MIMEType);
       }
       CFRelease(UTI);
     }
   }
 
   if (!isPDFURL) {
-    base::scoped_nsobject<UIPrintPageRenderer> renderer(
-        [[UIPrintPageRenderer alloc] init]);
+    UIPrintPageRenderer* renderer = [[UIPrintPageRenderer alloc] init];
     [renderer addPrintFormatter:[view viewPrintFormatter]
           startingAtPageAtIndex:0];
     printInteractionController.printPageRenderer = renderer;
     [PrintController
         displayPrintInteractionController:printInteractionController
                                    forPDF:NO];
   }
 }
 
 - (void)dismissAnimated:(BOOL)animated {
   _fetcher.reset();
   [self dismissPDFDownloadingDialog];
   [_PDFDownloadingErrorDialog stop];
-  _PDFDownloadingErrorDialog.reset();
+  _PDFDownloadingErrorDialog = nil;
   [[UIPrintInteractionController sharedPrintController]
       dismissAnimated:animated];
 }
 
 #pragma mark - Private Methods
 
 - (void)showPDFDownloadingDialog:(UIViewController*)viewController {
   if (_PDFDownloadingDialog)
     return;
 
   NSString* title = l10n_util::GetNSString(IDS_IOS_PRINT_PDF_PREPARATION);
 
-  base::WeakNSObject<PrintController> weakSelf(self);
+  __weak PrintController* weakSelf = self;
   ProceduralBlock cancelHandler = ^{
-    base::scoped_nsobject<PrintController> strongSelf([weakSelf retain]);
+    PrintController* strongSelf = weakSelf;
     if (strongSelf)
-      strongSelf.get()->_fetcher.reset();
+      strongSelf->_fetcher.reset();
   };
 
-  _PDFDownloadingDialog.reset([[LoadingAlertCoordinator alloc]
+  _PDFDownloadingDialog = [[LoadingAlertCoordinator alloc]
       initWithBaseViewController:viewController
                            title:title
-                   cancelHandler:cancelHandler]);
+                   cancelHandler:cancelHandler];
 
   dispatch_after(
       dispatch_time(DISPATCH_TIME_NOW, kPDFDownloadDialogDelay * NSEC_PER_SEC),
       dispatch_get_main_queue(), ^{
-        base::scoped_nsobject<PrintController> strongSelf([weakSelf retain]);
+        PrintController* strongSelf = weakSelf;
         if (!strongSelf)
           return;
-        [strongSelf.get()->_PDFDownloadingDialog start];
+        [strongSelf->_PDFDownloadingDialog start];
       });
 }
 
 - (void)dismissPDFDownloadingDialog {
   [_PDFDownloadingDialog stop];
-  _PDFDownloadingDialog.reset();
+  _PDFDownloadingDialog = nil;
 }
 
 - (void)showPDFDownloadErrorWithURL:(const GURL)URL
                      viewController:(UIViewController*)viewController {
   NSString* title = l10n_util::GetNSString(IDS_IOS_PRINT_PDF_ERROR_TITLE);
   NSString* message = l10n_util::GetNSString(IDS_IOS_PRINT_PDF_ERROR_SUBTITLE);
 
-  _PDFDownloadingErrorDialog.reset([[AlertCoordinator alloc]
-      initWithBaseViewController:viewController
-                           title:title
-                         message:message]);
+  _PDFDownloadingErrorDialog =
+      [[AlertCoordinator alloc] initWithBaseViewController:viewController
+                                                     title:title
+                                                   message:message];
 
-  base::WeakNSObject<PrintController> weakSelf(self);
+  __weak PrintController* weakSelf = self;
 
   [_PDFDownloadingErrorDialog
       addItemWithTitle:l10n_util::GetNSString(IDS_IOS_PRINT_PDF_TRY_AGAIN)
                 action:^{
                   [weakSelf downloadPDFFileWithURL:URL
                                     viewController:viewController];
                 }
                  style:UIAlertActionStyleDefault];
 
   [_PDFDownloadingErrorDialog
@@ skipping 10 matching lines @@
   _fetcherDelegate->SetViewController(viewController);
   _fetcher = URLFetcher::Create(URL, URLFetcher::GET, _fetcherDelegate.get());
   _fetcher->SetRequestContext(_requestContextGetter.get());
   _fetcher->Start();
   [self showPDFDownloadingDialog:viewController];
 }
 
 - (void)finishedDownloadingPDF:(UIViewController*)viewController {
   [self dismissPDFDownloadingDialog];
   DCHECK(_fetcher);
-  base::ScopedClosureRunner fetcherResetter(base::BindBlock(^{
+  base::ScopedClosureRunner fetcherResetter(base::BindBlockArc(^{
     _fetcher.reset();
   }));
   int responseCode = _fetcher->GetResponseCode();
   std::string response;
   std::string MIMEType;
   // If the request is not successful or does not match a PDF
   // MIME type, show an error.
   if (!_fetcher->GetStatus().is_success() || responseCode != 200 ||
       !_fetcher->GetResponseAsString(&response) ||
       !_fetcher->GetResponseHeaders()->GetMimeType(&MIMEType) ||
@@ skipping 11 matching lines @@
     return;
   }
   UIPrintInteractionController* printInteractionController =
       [UIPrintInteractionController sharedPrintController];
   printInteractionController.printingItem = data;
   [PrintController displayPrintInteractionController:printInteractionController
                                               forPDF:YES];
 }
 
 @end