[subresource_filter] Mac UI updated and xib replaced with code based layout.

chrome/browser/ui/cocoa/content_settings/content_setting_bubble_cocoa.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/content_settings/content_setting_bubble_cocoa.h"
 
 #include <stddef.h>
 
 #include "base/command_line.h"
 #include "base/logging.h"
 #include "base/macros.h"
 #include "base/memory/ptr_util.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/strings/utf_string_conversions.h"
 #include "chrome/browser/plugins/plugin_finder.h"
 #include "chrome/browser/plugins/plugin_metadata.h"
 #import "chrome/browser/ui/cocoa/info_bubble_view.h"
+#import "chrome/browser/ui/cocoa/info_bubble_window.h"

[shivanisha, 2017/05/03 18:10:35]

removed this unused include

 #import "chrome/browser/ui/cocoa/l10n_util.h"
+#import "chrome/browser/ui/cocoa/location_bar/content_setting_decoration.h"
+#import "chrome/browser/ui/cocoa/subresource_filter/subresource_filter_bubble_controller.h"
 #include "chrome/browser/ui/content_settings/content_setting_bubble_model.h"
 #include "chrome/browser/ui/content_settings/content_setting_media_menu_model.h"
-#import "chrome/browser/ui/cocoa/location_bar/content_setting_decoration.h"
 #include "chrome/grit/generated_resources.h"
 #include "components/content_settings/core/browser/host_content_settings_map.h"
 #include "content/public/browser/navigation_handle.h"
 #include "content/public/browser/plugin_service.h"
 #include "content/public/browser/web_contents_observer.h"
 #include "skia/ext/skia_utils_mac.h"
 #import "third_party/google_toolbox_for_mac/src/AppKit/GTMUILocalizerAndLayoutTweaker.h"
 #import "ui/base/cocoa/controls/hyperlink_button_cell.h"
+#import "ui/base/cocoa/window_size_constants.h"

[Robert Sesek, 2017/05/02 21:51:47]

Unused

[shivanisha, 2017/05/03 18:10:35]

removed

 #include "ui/base/l10n/l10n_util.h"
 
 using content::PluginService;
 
 namespace {
 
 // Height of one link in the popup list.
 const int kLinkHeight = 16;
 
 // Space between two popup links.
@@ skipping 158 matching lines @@
     // close up shop.
     [controller_ closeBubble:nil];
   }
 
  private:
   ContentSettingBubbleController* controller_;  // weak
 
   DISALLOW_COPY_AND_ASSIGN(ContentSettingBubbleWebContentsObserverBridge);
 };
 
-@interface ContentSettingBubbleController(Private)
+@interface ContentSettingBubbleController (Protected)
 - (id)initWithModel:(ContentSettingBubbleModel*)settingsBubbleModel
         webContents:(content::WebContents*)webContents
        parentWindow:(NSWindow*)parentWindow
          decoration:(ContentSettingDecoration*)decoration
          anchoredAt:(NSPoint)anchoredAt;
-- (NSString*)getNibPathForModel:(ContentSettingBubbleModel*)model;
++ (NSString*)getNibPathForModel:(ContentSettingBubbleModel*)model;
++ (ContentSettingBubbleController*)getControllerForModel:
+    (ContentSettingBubbleModel*)model;
 - (NSButton*)hyperlinkButtonWithFrame:(NSRect)frame
                                 title:(NSString*)title
                                  icon:(NSImage*)icon
                        referenceFrame:(NSRect)referenceFrame;
 - (void)initializeBlockedPluginsList;
 - (void)initializeTitle;
 - (void)initializeMessage;
+- (void)initalizeManageCheckbox;
 - (void)initializeRadioGroup;
 - (void)initializeItemList;
 - (void)initializeGeoLists;
 - (void)initializeMediaMenus;
 - (void)initializeMIDISysExLists;
 - (void)sizeToFitLoadButton;
-- (void)initManageDoneButtons;
 - (void)removeInfoButton;
 - (void)popupLinkClicked:(id)sender;
 - (void)clearGeolocationForCurrentHost:(id)sender;
 - (void)clearMIDISysExForCurrentHost:(id)sender;
 @end
 
 @implementation ContentSettingBubbleController
 
 + (ContentSettingBubbleController*)
 showForModel:(ContentSettingBubbleModel*)contentSettingBubbleModel
  webContents:(content::WebContents*)webContents
 parentWindow:(NSWindow*)parentWindow
   decoration:(ContentSettingDecoration*)decoration
   anchoredAt:(NSPoint)anchor {
-  // Autoreleases itself on bubble close.
-  return [[ContentSettingBubbleController alloc]
-      initWithModel:contentSettingBubbleModel
-        webContents:webContents
-       parentWindow:parentWindow
-         decoration:decoration
-         anchoredAt:anchor];
+  ContentSettingBubbleController* controller =
+      [self getControllerForModel:contentSettingBubbleModel];
+
+  DCHECK(controller);
+
+  return [controller initWithModel:contentSettingBubbleModel
+                       webContents:webContents
+                      parentWindow:parentWindow
+                        decoration:decoration
+                        anchoredAt:anchor];
 }
 
 struct ContentTypeToNibPath {
   ContentSettingsType type;
   NSString* path;
 };
 
 const ContentTypeToNibPath kNibPaths[] = {
     {CONTENT_SETTINGS_TYPE_COOKIES, @"ContentBlockedCookies"},
     {CONTENT_SETTINGS_TYPE_IMAGES, @"ContentBlockedSimple"},
@@ skipping 11 matching lines @@
         webContents:(content::WebContents*)webContents
        parentWindow:(NSWindow*)parentWindow
          decoration:(ContentSettingDecoration*)decoration
          anchoredAt:(NSPoint)anchoredAt {
   // This method takes ownership of |contentSettingBubbleModel| in all cases.
   std::unique_ptr<ContentSettingBubbleModel> model(contentSettingBubbleModel);
   DCHECK(model.get());
   observerBridge_.reset(
     new ContentSettingBubbleWebContentsObserverBridge(webContents, self));
 
-  NSString* nibPath = [self getNibPathForModel:model.get()];
+  NSString* nibPath =
+      [ContentSettingBubbleController getNibPathForModel:model.get()];
 
   DCHECK_NE(0u, [nibPath length]);
 
   if ((self = [super initWithWindowNibPath:nibPath
                               parentWindow:parentWindow
                                 anchoredAt:anchoredAt])) {
     contentSettingBubbleModel_ = std::move(model);
     decoration_ = decoration;
     [self showWindow:nil];
   }
   return self;
 }
 
-- (NSString*)getNibPathForModel:(ContentSettingBubbleModel*)model {
+- (id)initWithModel:(ContentSettingBubbleModel*)contentSettingBubbleModel
+        webContents:(content::WebContents*)webContents
+             window:(NSWindow*)window
+       parentWindow:(NSWindow*)parentWindow
+         decoration:(ContentSettingDecoration*)decoration
+         anchoredAt:(NSPoint)anchoredAt {
+  // This method takes ownership of |contentSettingBubbleModel| in all cases.
+  std::unique_ptr<ContentSettingBubbleModel> model(contentSettingBubbleModel);
+  DCHECK(model.get());
+  observerBridge_.reset(
+      new ContentSettingBubbleWebContentsObserverBridge(webContents, self));
+
+  contentSettingBubbleModel_ = std::move(model);
+
+  if ((self = [super initWithWindow:window
+                       parentWindow:parentWindow
+                         anchoredAt:anchoredAt])) {
+    decoration_ = decoration;
+    [self showWindow:nil];
+    NSRect newWindowFrame =
+        [window frameRectForContentRect:NSMakeRect(196, 376, 316, 134)];

[Robert Sesek, 2017/05/02 21:51:47]

Why is this done here?

[shivanisha, 2017/05/03 18:10:35]

Ah, remnant of earlier patch. Thanks, removed.

+
+    [window setFrame:newWindowFrame
+             display:YES
+             animate:[[self window] isVisible]];
+  }
+  return self;
+}
+
++ (NSString*)getNibPathForModel:(ContentSettingBubbleModel*)model {
   NSString* nibPath = @"";
 
   ContentSettingSimpleBubbleModel* simple_bubble = model->AsSimpleBubbleModel();
   if (simple_bubble) {
     ContentSettingsType settingsType = simple_bubble->content_type();
 
     for (const ContentTypeToNibPath& type_to_path : kNibPaths) {
       if (settingsType == type_to_path.type) {
         nibPath = type_to_path.path;
         break;
       }
     }
   }
 
   if (model->AsMediaStreamBubbleModel())
     nibPath = @"ContentBlockedMedia";
 
-  if (model->AsSubresourceFilterBubbleModel())
-    nibPath = @"ContentSubresourceFilter";
-
   if (model->AsDownloadsBubbleModel())
     nibPath = @"ContentBlockedDownloads";
   return nibPath;
 }
 
++ (ContentSettingBubbleController*)getControllerForModel:

[Robert Sesek, 2017/05/02 21:51:47]

naming: call this allocControllerForModel: to make it explicit that this is
returning a strong reference

[shivanisha, 2017/05/03 18:10:35]

done

+    (ContentSettingBubbleModel*)model {
+  // Check if the view is expressed in xib file or not.
+  NSString* nibPath = [self getNibPathForModel:model];
+
+  // Autoreleases itself on bubble close.
+
+  if ([nibPath length] > 0u)
+    return [ContentSettingBubbleController alloc];
+
+  if (model->AsSubresourceFilterBubbleModel())
+    return [SubresourceFilterBubbleController alloc];
+
+  return nil;
+}
+
 - (void)initializeTitle {
   if (!titleLabel_)
     return;
 
   NSString* label = base::SysUTF16ToNSString(
       contentSettingBubbleModel_->bubble_content().title);
   [titleLabel_ setStringValue:label];
 
   // Layout title post-localization.
   CGFloat deltaY = [GTMUILocalizerAndLayoutTweaker
@@ skipping 17 matching lines @@
   CGFloat deltaY = [GTMUILocalizerAndLayoutTweaker
       sizeToFitFixedWidthTextField:messageLabel_];
   NSRect windowFrame = [[self window] frame];
   windowFrame.size.height += deltaY;
   [[self window] setFrame:windowFrame display:NO];
   NSRect messageFrame = [messageLabel_ frame];
   messageFrame.origin.y -= deltaY;
   [messageLabel_ setFrame:messageFrame];
 }
 
+- (void)initalizeManageCheckbox {

[Robert Sesek, 2017/05/02 21:51:47]

spelling: initialize

[shivanisha, 2017/05/03 18:10:35]

done. Also moved this to the subclass

+  if (!manageCheckbox_)
+    return;
+
+  NSString* label = base::SysUTF16ToNSString(
+      contentSettingBubbleModel_->bubble_content().manage_text);
+  [manageCheckbox_ setTitle:label];
+
+  CGFloat deltaY =
+      [GTMUILocalizerAndLayoutTweaker sizeToFitView:manageCheckbox_].height;
+  NSRect windowFrame = [[self window] frame];
+  windowFrame.size.height += deltaY;
+  [[self window] setFrame:windowFrame display:NO];
+  NSRect manageCheckboxFrame = [manageCheckbox_ frame];
+  manageCheckboxFrame.origin.y -= deltaY;
+  [manageCheckbox_ setFrame:manageCheckboxFrame];
+}
+
 - (void)initializeRadioGroup {
   // NOTE! Tags in the xib files must match the order of the radio buttons
   // passed in the radio_group and be 1-based, not 0-based.
   const ContentSettingBubbleModel::BubbleContent& bubble_content =
       contentSettingBubbleModel_->bubble_content();
   const ContentSettingBubbleModel::RadioGroup& radio_group =
       bubble_content.radio_group;
 
   // Xcode 5.1 Interface Builder doesn't allow a font property to be set for
   // NSMatrix. The implementation of GTMUILocalizerAndLayoutTweaker assumes that
@@ skipping 394 matching lines @@
       2 * NSMinX([loadButton_ frame]);
   if (NSWidth(windowFrame) < widthNeeded) {
     windowFrame.size.width = widthNeeded;
     [[self window] setFrame:windowFrame display:NO];
   }
 }
 
 - (void)initManageDoneButtons {
   const ContentSettingBubbleModel::BubbleContent& content =
       contentSettingBubbleModel_->bubble_content();
-  [manageButton_ setTitle:base::SysUTF16ToNSString(content.manage_text)];
-  [GTMUILocalizerAndLayoutTweaker sizeToFitView:[manageButton_ superview]];
+
+  CGFloat requiredWidthForManageButton = 0.0;
+  if (manageButton_) {
+    [manageButton_ setTitle:base::SysUTF16ToNSString(content.manage_text)];
+    [GTMUILocalizerAndLayoutTweaker sizeToFitView:[manageButton_ superview]];
+    requiredWidthForManageButton =
+        NSMaxX([manageButton_ frame]) + kManageDonePadding;
+  }
+
+  if (!manageButton_ && !doneButton_)
+    return;
+
+  NSString* doneLabel = base::SysUTF16ToNSString(content.done_button_text);
+  if ([doneLabel length] > 0u)
+    [doneButton_ setTitle:doneLabel];
 
   CGFloat actualWidth = NSWidth([[[self window] contentView] frame]);
-  CGFloat requiredWidth = NSMaxX([manageButton_ frame]) + kManageDonePadding +
-      NSWidth([[doneButton_ superview] frame]) - NSMinX([doneButton_ frame]);
+  CGFloat requiredWidth = requiredWidthForManageButton +
+                          NSWidth([[doneButton_ superview] frame]) -
+                          NSMinX([doneButton_ frame]);
   if (requiredWidth <= actualWidth || !doneButton_ || !manageButton_)
     return;
 
   // Resize window, autoresizing takes care of the rest.
   NSSize size = NSMakeSize(requiredWidth - actualWidth, 0);
   size = [[[self window] contentView] convertSize:size toView:nil];
   NSRect frame = [[self window] frame];
   frame.origin.x -= size.width;
   frame.size.width += size.width;
   [[self window] setFrame:frame display:NO];
 }
 
 - (void)awakeFromNib {
   [super awakeFromNib];
 
   ContentSettingSimpleBubbleModel* simple_bubble =
       contentSettingBubbleModel_->AsSimpleBubbleModel();
 
   [[self bubble] setArrowLocation:info_bubble::kTopTrailing];
 
   // Adapt window size to bottom buttons. Do this before all other layouting.
   if ((simple_bubble && !simple_bubble->bubble_content().manage_text.empty()) ||
-      contentSettingBubbleModel_->AsDownloadsBubbleModel())
+      contentSettingBubbleModel_->AsDownloadsBubbleModel() ||
+      contentSettingBubbleModel_->AsSubresourceFilterBubbleModel())

[Robert Sesek, 2017/05/02 21:51:47]

nit: add braces since the condition is multi-line

[shivanisha, 2017/05/03 18:10:35]

done

     [self initManageDoneButtons];
 
   [self initializeTitle];
   [self initializeMessage];
+  [self initalizeManageCheckbox];
 
   // Note that the per-content-type methods and |initializeRadioGroup| below
   // must be kept in the correct order, as they make interdependent adjustments
   // of the bubble's height.
   if (simple_bubble &&
       simple_bubble->content_type() == CONTENT_SETTINGS_TYPE_PLUGINS) {
     if (!simple_bubble->bubble_content().custom_link.empty())
       [self sizeToFitLoadButton];
 
     [self initializeBlockedPluginsList];
@@ skipping 80 matching lines @@
 
 - (IBAction)manageBlocking:(id)sender {
   contentSettingBubbleModel_->OnManageLinkClicked();
 }
 
 - (IBAction)closeBubble:(id)sender {
   contentSettingBubbleModel_->OnDoneClicked();
   [self close];
 }
 
+- (IBAction)manageCheckboxChecked:(id)sender {
+  bool is_checked = [sender state] == NSOnState;

[Robert Sesek, 2017/05/02 21:51:47]

naming: isChecked (use camelCase in ObjC methods)

[shivanisha, 2017/05/03 18:10:35]

done

+  contentSettingBubbleModel_->OnManageCheckboxChecked(is_checked);
+}
+
 - (IBAction)mediaMenuChanged:(id)sender {
   NSPopUpButton* button = static_cast<NSPopUpButton*>(sender);
   auto it = mediaMenus_.find(sender);
   DCHECK(it != mediaMenus_.end());
   NSInteger index = [[button selectedItem] tag];
 
   SetTitleForPopUpButton(
       button, base::SysUTF16ToNSString(it->second->model->GetLabelAt(index)));
 
   it->second->model->ExecuteCommand(index, 0);
 }
 
 - (content_setting_bubble::MediaMenuPartsMap*)mediaMenus {
   return &mediaMenus_;
 }
 
 - (LocationBarDecoration*)decorationForBubble {
   return decoration_;
 }
 
 @end  // ContentSettingBubbleController