[ObjC ARC] Converts ios/chrome/browser/ui/dialogs:dialogs_internal to ARC.

ios/chrome/browser/ui/dialogs/dialog_presenter.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/ui/dialogs/dialog_presenter.h"
 
 #include <deque>
 #include <map>
 
 #import "base/ios/block_types.h"
-#import "base/ios/weak_nsobject.h"
 #include "base/logging.h"
 #import "base/mac/scoped_nsobject.h"
 #include "base/strings/sys_string_conversions.h"
 #include "components/strings/grit/components_strings.h"
 #import "ios/chrome/browser/ui/alert_coordinator/action_sheet_coordinator.h"
 #import "ios/chrome/browser/ui/alert_coordinator/alert_coordinator.h"
 #import "ios/chrome/browser/ui/alert_coordinator/input_alert_coordinator.h"
 #import "ios/chrome/browser/ui/dialogs/javascript_dialog_blocking_util.h"
 #import "ios/chrome/browser/ui/dialogs/nsurl_protection_space_util.h"
 #include "ios/chrome/browser/ui/ui_util.h"
 #include "ios/chrome/grit/ios_strings.h"
 #include "ios/web/public/web_state/web_state.h"
 #include "ui/base/l10n/l10n_util.h"
 #include "url/gurl.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 // Externed accessibility identifier.
 NSString* const kJavaScriptDialogTextFieldAccessibiltyIdentifier =
     @"JavaScriptDialogTextFieldAccessibiltyIdentifier";
 
 namespace {
 // The hostname to use for JavaScript alerts when there is no valid hostname in
 // the URL passed to |+localizedTitleForJavaScriptAlertFromPage:type:|.
 const char kAboutNullHostname[] = "about:null";
 }  // namespace
 
 @interface DialogPresenter () {
-  // Backing objects for properties of the same name.
-  base::WeakNSProtocol<id<DialogPresenterDelegate>> _delegate;
-  base::WeakNSObject<UIViewController> _viewController;
   // Queue of WebStates which correspond to the keys in
   // |_dialogCoordinatorsForWebStates|.
   std::deque<web::WebState*> _queuedWebStates;
   // A map associating queued webStates with their coordinators.
   std::map<web::WebState*, base::scoped_nsobject<AlertCoordinator>>
       _dialogCoordinatorsForWebStates;
-  web::WebState* _presentedDialogWebState;
-  base::scoped_nsobject<AlertCoordinator> _presentedDialogCoordinator;
-  base::scoped_nsobject<ActionSheetCoordinator>
-      _blockingConfirmationCoordinator;
 }
 
 // The delegate passed on initialization.
-@property(nonatomic, readonly) id<DialogPresenterDelegate> delegate;
+@property(weak, nonatomic, readonly) id<DialogPresenterDelegate> delegate;
 
 // The presenting view controller passed on initialization.
-@property(nonatomic, readonly) UIViewController* viewController;
+@property(weak, nonatomic, readonly) UIViewController* viewController;
 
 // Whether a modal dialog is currently being shown.
 @property(nonatomic, readonly, getter=isShowingDialog) BOOL showingDialog;
 
 // The webState for |presentedDialog|.
 @property(nonatomic) web::WebState* presentedDialogWebState;
 
 // The dialog that's currently being shown, if any.
-@property(nonatomic, retain) AlertCoordinator* presentedDialogCoordinator;
+@property(nonatomic, strong) AlertCoordinator* presentedDialogCoordinator;
 
 // The JavaScript dialog blocking confirmation action sheet being shown, if any.
-@property(nonatomic, retain) AlertCoordinator* blockingConfirmationCoordinator;
+@property(nonatomic, strong) AlertCoordinator* blockingConfirmationCoordinator;
 
 // Adds |context| and |coordinator| to the queue.  If a dialog is not already
 // being shown, |coordinator| will be presented.  Otherwise, |coordinator| will
 // be displayed once the previously shown dialog is dismissed.
 - (void)addDialogCoordinator:(AlertCoordinator*)coordinator
                  forWebState:(web::WebState*)webState;
 
 // Shows the dialog associated with the next context in |contextQueue|.
 - (void)showNextDialog;
 
@@ skipping 19 matching lines @@
                                  webState:(web::WebState*)webState;
 
 // The block to use for the JavaScript dialog blocking option for |coordinator|.
 - (ProceduralBlock)blockingActionForCoordinator:(AlertCoordinator*)coordinator;
 
 @end
 
 @implementation DialogPresenter
 
 @synthesize active = _active;
+@synthesize delegate = _delegate;
+@synthesize viewController = _viewController;
+@synthesize presentedDialogCoordinator = _presentedDialogCoordinator;
+@synthesize blockingConfirmationCoordinator = _blockingConfirmationCoordinator;
+@synthesize presentedDialogWebState = _presentedDialogWebState;
 
 - (instancetype)initWithDelegate:(id<DialogPresenterDelegate>)delegate
         presentingViewController:(UIViewController*)viewController {
   if ((self = [super init])) {
     DCHECK(delegate);
     DCHECK(viewController);
-    _delegate.reset(delegate);
-    _viewController.reset(viewController);
+    _delegate = delegate;
+    _viewController = viewController;
   }
   return self;
 }
 
 #pragma mark - Accessors
 
 - (void)setActive:(BOOL)active {
   if (_active != active) {
     _active = active;
     [self tryToPresent];
   }
 }
 
-- (id<DialogPresenterDelegate>)delegate {
-  return _delegate;
-}
-
-- (UIViewController*)viewController {
-  return _viewController;
-}
-
 - (BOOL)isShowingDialog {
   DCHECK_EQ(self.presentedDialogWebState != nullptr,
             self.presentedDialogCoordinator != nil);
   return self.presentedDialogCoordinator != nil;
 }
 
-- (web::WebState*)presentedDialogWebState {
-  return _presentedDialogWebState;
-}
-
-- (void)setPresentedDialogWebState:(web::WebState*)presentedDialogWebState {
-  _presentedDialogWebState = presentedDialogWebState;
-}
-
-- (AlertCoordinator*)presentedDialogCoordinator {
-  return _presentedDialogCoordinator;
-}
-
-- (void)setPresentedDialogCoordinator:
-    (AlertCoordinator*)presentedDialogCoordinator {
-  _presentedDialogCoordinator.reset([presentedDialogCoordinator retain]);
-}
-
-- (ActionSheetCoordinator*)blockingConfirmationCoordinator {
-  return _blockingConfirmationCoordinator;
-}
-
-- (void)setBlockingConfirmationCoordinator:
-    (ActionSheetCoordinator*)blockingConfirmationActionSheetCoordinator {
-  _blockingConfirmationCoordinator.reset(
-      [blockingConfirmationActionSheetCoordinator retain]);
-}
-
 #pragma mark - Public
 
 - (void)runJavaScriptAlertPanelWithMessage:(NSString*)message
                                 requestURL:(const GURL&)requestURL
                                   webState:(web::WebState*)webState
                          completionHandler:(void (^)(void))completionHandler {
   NSString* title =
       [DialogPresenter localizedTitleForJavaScriptAlertFromPage:requestURL];
-  AlertCoordinator* alertCoordinator = [[[AlertCoordinator alloc]
-      initWithBaseViewController:self.viewController
-                           title:title
-                         message:message] autorelease];
+  AlertCoordinator* alertCoordinator =
+      [[AlertCoordinator alloc] initWithBaseViewController:self.viewController
+                                                     title:title
+                                                   message:message];
 
   // Handler.
-  base::WeakNSObject<DialogPresenter> weakSelf(self);
-  base::WeakNSObject<AlertCoordinator> weakCoordinator(alertCoordinator);
+  __weak DialogPresenter* weakSelf = self;
+  __weak AlertCoordinator* weakCoordinator = alertCoordinator;
   ProceduralBlock OKHandler = ^{
     if (completionHandler)
       completionHandler();
     [weakSelf buttonWasTappedForCoordinator:weakCoordinator];
   };
 
   // Add button.
   [alertCoordinator addItemWithTitle:l10n_util::GetNSString(IDS_OK)
                               action:OKHandler
                                style:UIAlertActionStyleDefault];
 
   // Add cancel handler.
   alertCoordinator.cancelAction = completionHandler;
   alertCoordinator.noInteractionAction = completionHandler;
 
   // Blocking option setup.
   [self setUpBlockingOptionForCoordinator:alertCoordinator webState:webState];
 
   [self addDialogCoordinator:alertCoordinator forWebState:webState];
 }
 
 - (void)runJavaScriptConfirmPanelWithMessage:(NSString*)message
                                   requestURL:(const GURL&)requestURL
                                     webState:(web::WebState*)webState
                            completionHandler:
                                (void (^)(BOOL isConfirmed))completionHandler {
   NSString* title =
       [DialogPresenter localizedTitleForJavaScriptAlertFromPage:requestURL];
-  AlertCoordinator* alertCoordinator = [[[AlertCoordinator alloc]
-      initWithBaseViewController:self.viewController
-                           title:title
-                         message:message] autorelease];
+  AlertCoordinator* alertCoordinator =
+      [[AlertCoordinator alloc] initWithBaseViewController:self.viewController
+                                                     title:title
+                                                   message:message];
 
   // Actions.
   ProceduralBlock confirmAction = ^{
     if (completionHandler)
       completionHandler(YES);
   };
 
   ProceduralBlock cancelAction = ^{
     if (completionHandler)
       completionHandler(NO);
@@ skipping 13 matching lines @@
 }
 
 - (void)runJavaScriptTextInputPanelWithPrompt:(NSString*)message
                                   defaultText:(NSString*)defaultText
                                    requestURL:(const GURL&)requestURL
                                      webState:(web::WebState*)webState
                             completionHandler:
                                 (void (^)(NSString* input))completionHandler {
   NSString* title =
       [DialogPresenter localizedTitleForJavaScriptAlertFromPage:requestURL];
-  InputAlertCoordinator* alertCoordinator = [[[InputAlertCoordinator alloc]
+  InputAlertCoordinator* alertCoordinator = [[InputAlertCoordinator alloc]
       initWithBaseViewController:self.viewController
                            title:title
-                         message:message] autorelease];
+                         message:message];
 
   // Actions.
-  base::WeakNSObject<InputAlertCoordinator> weakCoordinator(alertCoordinator);
+  __weak InputAlertCoordinator* weakCoordinator = alertCoordinator;
   ProceduralBlock confirmAction = ^{
     if (completionHandler) {
       NSString* textInput = [weakCoordinator textFields].firstObject.text;
       completionHandler(textInput ? textInput : @"");
     }
   };
 
   ProceduralBlock cancelAction = ^{
     if (completionHandler)
       completionHandler(nil);
@@ skipping 23 matching lines @@
 - (void)runAuthDialogForProtectionSpace:(NSURLProtectionSpace*)protectionSpace
                      proposedCredential:(NSURLCredential*)credential
                                webState:(web::WebState*)webState
                       completionHandler:(void (^)(NSString* user,
                                                   NSString* password))handler {
   NSString* title = l10n_util::GetNSStringWithFixup(IDS_LOGIN_DIALOG_TITLE);
   NSString* message =
       ios_internal::nsurlprotectionspace_util::MessageForHTTPAuth(
           protectionSpace);
 
-  InputAlertCoordinator* alertCoordinator = [[[InputAlertCoordinator alloc]
+  InputAlertCoordinator* alertCoordinator = [[InputAlertCoordinator alloc]
       initWithBaseViewController:self.viewController
                            title:title
-                         message:message] autorelease];
+                         message:message];
 
   // Actions.
-  base::WeakNSObject<InputAlertCoordinator> weakCoordinator(alertCoordinator);
+  __weak InputAlertCoordinator* weakCoordinator = alertCoordinator;
   ProceduralBlock confirmAction = ^{
     if (handler) {
       NSString* username = [[weakCoordinator textFields] objectAtIndex:0].text;
       NSString* password = [[weakCoordinator textFields] objectAtIndex:1].text;
       handler(username, password);
     }
   };
 
   ProceduralBlock cancelAction = ^{
     if (handler)
@@ skipping 72 matching lines @@
 #pragma mark - Private methods.
 
 - (void)addDialogCoordinator:(AlertCoordinator*)coordinator
                  forWebState:(web::WebState*)webState {
   DCHECK(coordinator);
   DCHECK(webState);
   DCHECK_NE(webState, self.presentedDialogWebState);
   DCHECK(!_dialogCoordinatorsForWebStates[webState]);
   _queuedWebStates.push_back(webState);
   _dialogCoordinatorsForWebStates[webState] =
-      base::scoped_nsobject<AlertCoordinator>([coordinator retain]);
+      base::scoped_nsobject<AlertCoordinator>(coordinator);
 
   if (self.active && !self.showingDialog && !self.delegate.presenting)
     [self showNextDialog];
 }
 
 - (void)showNextDialog {
   DCHECK(self.active);
   DCHECK(!self.showingDialog);
   DCHECK(!_queuedWebStates.empty());
   // Update properties and remove context and the dialog from queue.
@@ skipping 16 matching lines @@
   self.blockingConfirmationCoordinator = nil;
   if (!_queuedWebStates.empty() && !self.delegate.presenting)
     [self showNextDialog];
 }
 
 - (void)setUpAlertCoordinator:(AlertCoordinator*)alertCoordinator
                 confirmAction:(ProceduralBlock)confirmAction
                  cancelAction:(ProceduralBlock)cancelAction
                       OKLabel:(NSString*)label {
   // Handlers.
-  base::WeakNSObject<DialogPresenter> weakSelf(self);
-  base::WeakNSObject<AlertCoordinator> weakCoordinator(alertCoordinator);
+  __weak DialogPresenter* weakSelf = self;
+  __weak AlertCoordinator* weakCoordinator = alertCoordinator;
 
   ProceduralBlock confirmHandler = ^{
     if (confirmAction)
       confirmAction();
     [weakSelf buttonWasTappedForCoordinator:weakCoordinator];
   };
 
   ProceduralBlock cancelHandler = ^{
     if (cancelAction)
       cancelAction();
@@ skipping 12 matching lines @@
   alertCoordinator.cancelAction = cancelAction;
   alertCoordinator.noInteractionAction = cancelAction;
 }
 
 - (void)setUpBlockingOptionForCoordinator:(AlertCoordinator*)alertCoordinator
                                  webState:(web::WebState*)webState {
   DCHECK(alertCoordinator);
   DCHECK(webState);
 
   // Set up the start action.
-  base::WeakNSObject<DialogPresenter> weakSelf(self);
-  base::WeakNSObject<AlertCoordinator> weakCoordinator(alertCoordinator);
   ProceduralBlock originalStartAction = alertCoordinator.startAction;
   alertCoordinator.startAction = ^{
     if (originalStartAction)
       originalStartAction();
     JavaScriptDialogWasShown(webState);
   };
 
   // Early return if a blocking option should not be added.
   if (!ShouldShowDialogBlockingOption(webState))
     return;
 
   ProceduralBlock blockingAction =
       [self blockingActionForCoordinator:alertCoordinator];
   NSString* blockingOptionTitle =
       l10n_util::GetNSString(IDS_IOS_JAVA_SCRIPT_DIALOG_BLOCKING_BUTTON_TEXT);
   [alertCoordinator addItemWithTitle:blockingOptionTitle
                               action:blockingAction
                                style:UIAlertActionStyleDefault];
 }
 
 - (ProceduralBlock)blockingActionForCoordinator:(AlertCoordinator*)coordinator {
-  base::WeakNSObject<DialogPresenter> weakSelf(self);
-  base::WeakNSObject<AlertCoordinator> weakCoordinator(coordinator);
-  base::WeakNSObject<UIViewController> weakBaseViewController(
-      coordinator.baseViewController);
+  __weak DialogPresenter* weakSelf = self;
+  __weak AlertCoordinator* weakCoordinator = coordinator;
+  __weak UIViewController* weakBaseViewController =
+      coordinator.baseViewController;
   ProceduralBlock cancelAction = coordinator.cancelAction;
-  return [[^{
+  return [^{
     // Create the confirmation coordinator.  Use an action sheet on iPhone and
     // an alert on iPhone.
     NSString* confirmMessage =
         l10n_util::GetNSString(IDS_JAVASCRIPT_MESSAGEBOX_SUPPRESS_OPTION);
     AlertCoordinator* confirmationCoordinator =
-        IsIPadIdiom()
-            ? [[[AlertCoordinator alloc]
-                  initWithBaseViewController:weakBaseViewController
-                                       title:nil
-                                     message:confirmMessage] autorelease]
-            : [[[ActionSheetCoordinator alloc]
-                  initWithBaseViewController:weakBaseViewController
-                                       title:nil
-                                     message:confirmMessage
-                                        rect:CGRectZero
-                                        view:nil] autorelease];
+        IsIPadIdiom() ? [[AlertCoordinator alloc]
+                            initWithBaseViewController:weakBaseViewController
+                                                 title:nil
+                                               message:confirmMessage]
+                      : [[ActionSheetCoordinator alloc]
+                            initWithBaseViewController:weakBaseViewController
+                                                 title:nil
+                                               message:confirmMessage
+                                                  rect:CGRectZero
+                                                  view:nil];
     // Set up button actions.
     ProceduralBlock confirmHandler = ^{
       if (cancelAction)
         cancelAction();
-      base::scoped_nsobject<DialogPresenter> strongSelf([weakSelf retain]);
+      DialogPresenter* strongSelf = weakSelf;
       if (!strongSelf)
         return;
       DialogBlockingOptionSelected([strongSelf presentedDialogWebState]);
       [strongSelf buttonWasTappedForCoordinator:weakCoordinator];
     };
     ProceduralBlock cancelHandler = ^{
       if (cancelAction)
         cancelAction();
       [weakSelf buttonWasTappedForCoordinator:weakCoordinator];
     };
     NSString* blockingOptionTitle =
         l10n_util::GetNSString(IDS_IOS_JAVA_SCRIPT_DIALOG_BLOCKING_BUTTON_TEXT);
     [confirmationCoordinator addItemWithTitle:blockingOptionTitle
                                        action:confirmHandler
                                         style:UIAlertActionStyleDestructive];
     [confirmationCoordinator addItemWithTitle:l10n_util::GetNSString(IDS_CANCEL)
                                        action:cancelHandler
                                         style:UIAlertActionStyleCancel];
     [weakSelf setBlockingConfirmationCoordinator:confirmationCoordinator];
     [[weakSelf blockingConfirmationCoordinator] start];
-  } copy] autorelease];
+  } copy];
 }
 
 @end